Outlook дээрх хуанлийн хуучирсан зүйлсээс хавсралтыг хэрхэн багцаар устгах вэ

Хэрэв та Outlook дээрх хуучирсан уулзалт, уулзалтын хавсралтыг устгахыг хүсвэл энэ нийтлэлийг уншиж болно. Үүнийг нэг дор хэрхэн хэрэгжүүлэх талаар бид танд танилцуулах болно.

Outlook файлын хэмжээг багасгахын тулд хуучин зүйлсийг цэвэрлэхийг зөвлөж байна. Үүнийг дотооддоо суулгасан "Автоархив" функцээр ойлгож, хуучин зүйлсийг тогтмол хугацаанд автоматаар устгах боломжтой. Гэсэн хэдий ч, зарим хэрэглэгчид хуучин зүйлсийн хавсралтуудыг өөрсдөдөө нөлөөлөхгүйгээр устгахыг хүсдэг. Дараах зүйлд бид хуанлийн хуучин зүйлсээс хавсралтыг бөөнөөр нь устгахыг танд заах болно.

Хуучирсан хуанлийн зүйлсээс хавсралтуудыг багцаар нь устгах

1. Эхлэхийн тулд "Alt + F11" товчийг ашиглан Outlook VBA засварлагч руу нэвтэрнэ үү.
2. Дараа нь "Microsoft Visual Basic for Applications" цонхонд VBA кодыг модуль болгон хуулна.

Sub BatchDeleteAttachmentsOfOldCalendarItems()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    'Change to your own Outlook file
    Set objOutlookFile = Outlook.Application.Session.Folders("John Smith")
 
    For Each objFolder In objOutlookFile.Folders
        If objFolder.DefaultItemType = olAppointmentItem Then
           Call LoopCalendars(objFolder)
        End If
    Next
End Sub

Sub LoopCalendars(ByVal objCalendar As Outlook.Folder)
    Dim i, n As Long
    Dim objCalendarItem As Outlook.AppointmentItem
    Dim nDateDiff As Integer
    Dim objAttachments As Outlook.Attachments
    Dim objSubCalendar As Outlook.Folder
 
    For i = objCalendar.Items.Count To 1 Step -1
        Set objCalendarItem = objCalendar.Items(i)
 
        'Remove attachments from items that are more than 2 months old
        'Change the datediff as per your needs
        nDateDiff = DateDiff("m", objCalendarItem.End, Now) '=> "m" refers to month; "d" for day; "y" for year
        If nDateDiff > 2 Then
           Set objAttachments = objCalendarItem.Attachments
           If objAttachments.Count > 0 Then
              For n = objAttachments.Count To 1 Step -1
                  objAttachments(n).Delete
              Next
           End If
           objCalendarItem.Save
        End If
    Next

    'Process all subfolders recursively
    If objCalendar.Folders.Count > 0 Then
       For Each objSubCalendar In objCalendar.Folders
           Call LoopCalendars(objSubCalendar)
       Next
    End If
End Sub

3. Дараа нь "BatchDeleteAttachmentsOfOldCalendarItems" макро дээр дарна уу.
4. Эцэст нь энэ макро ажиллуулахын тулд "F5" товчийг дарна уу.
5. Макро дууссаны дараа та Outlook-ийн бүх хуанлигаа шалгаж болно.
6. Outlook нь 2 сараас дээш настай хуанлийн бүх хавсралтыг устгасан байх ёстой.

Эвдэрсэн Outlook файлуудыг даван туулах

Та Outlook-ийн авлигатай тулгарч байсан уу? Та үүнийг ихэвчлэн яаж устгадаг вэ? Ихэнх тохиолдолд та эхлээд ирсэн имэйлийг засах хэрэгслийг туршиж үзэх болно - Сканнердах. Гэхдээ PST-ийн ноцтой гэмтэл гарсан тохиолдолд суулгасан хэрэгсэл танд тусалж чадахгүй. Тиймээс, илүү туршлагатай, гайхалтай гуравдагч талын хэрэгслийг ойролцоо байлгахыг зөвлөж байна DataNumen Outlook Repair.

Зохиогчийн танилцуулга:

Ширли Жан бол мэдээлэл сэргээх мэргэжилтэн юм DataNumen, Үүнд мэдээлэл сэргээх технологиор дэлхийд тэргүүлэгч, Inc. квадрат засвар програм хангамжийн бүтээгдэхүүнийг засах хэтийн төлөв. Дэлгэрэнгүй мэдээллийг авна уу WWW.datanumen.com