Бүх дарцаглагдсан Outlook имэйлийн жагсаалтыг Excel рүү экспортлох 2 хурдан арга

Хэрэв та бүх дарцагласан имэйлийн жагсаалтыг Outlook шуудангийн хайрцгаас Excel рүү экспортлохыг хүсвэл энэ нийтлэлд хуваалцсан 2 аргын аль нэгийг ашиглаж болно.

Жишээлбэл, бүх дарцагласан имэйлийг цаг тухайд нь шийдвэрлэх эсвэл өөр хэн нэгэнтэй хуваалцахын тулд та тэдгээрийг Excel-ийн ажлын хуудас руу экспортлох боломжтой гэж найдаж болно. Энд бид үүнийг хэрэгжүүлэх 2 аргыг танилцуулах болно. Эхнийх нь дарцагласан имэйлийг олсны дараа стандарт "Импорт, экспорт" функцийг ашигладаг. Үнэнийг хэлэхэд энэ нь жаахан уйтгартай юм. Тиймээс, сүүлийн хувилбарт бид танд VBA ашиглах илүү тохиромжтой аргыг заах болно.

Арга 1: Бүх олдсон дарцагласан имэйлийг гараар экспортлох

1. Юуны өмнө, имэйлийн жагсаалтын дээрх хайлтын талбар дээр дарна уу.
2. Дараа нь "Хайлт" таб дээрх "Хамрах хүрээ" бүлгийн "Бүх захидлын зүйл" дээр дарна уу.
3. Дараа нь "Тодорхойлох" бүлгийн "Дарцагласан" товчийг дарна уу.
4. Жагсаалтад тэмдэглэгдсэн бүх имэйлийн дараа нэг имэйл сонгоод "Ctrl + A" товчийг дарж бүгдийг нь сонгоно уу.
5. Дараа нь "Ctrl + Shift + V" товчийг дарна уу.
6. Шинэ харилцах цонхонд Outlook файлын доор шинэ хавтас үүсгэнэ үү.
7. Дараа нь шинээр үүсгэсэн фолдерыг сонгоод "OK" дээр дарснаар бүх олсон дарцагласан имэйлийг шинэ хавтас руу зөөнө.
8. Дараа нь "Файл"> "Нээх"> "Импорт" дээр дарна уу.
9. Гарч ирэх харилцах цонхноос "Файлд экспортлох" > "Дараах" > ​​"Microsoft Excel 97-2003" > "Дараах" гэснийг сонгоно уу.
10. Шинэ дэлгэц дээр зөв хавтсыг сонгоод "Дараах" дээр дарна уу.
11. Дараа нь "Экспорт"-ыг дуусгахын тулд шидтэнгүүдийг дагана уу.
12. Та дараах дэлгэцийн агшинд харуулсан шинэ Excel файлыг авах болно.

Арга 2: Бүх дарцагласан имэйлийн жагсаалтыг VBA-аар экспортлох

1. Outlook дээр "Alt + F11" товчийг дарж VBA засварлагчийг ажиллуулна уу.
2. Дараа нь "MS Excel Object"-ийг ""-ийн дагуу идэвхжүүлнэ.VBA дээр объектын номын сангийн лавлагааг хэрхэн нэмэх вэ".
3. Дараа нь доорхи VBA кодыг модульд хуулж ав.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllFlaggedEmailsToExcel()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
  
    'Select a source PST file
    Set objOutlookFile = Outlook.Application.Session.PickFolder
 
    If Not (objOutlookFile Is Nothing) Then
       'Create a new Excel file
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
       objExcelApp.Visible = True
 
       With objExcelWorksheet
           .Cells(1, 1) = "Subject"
           .Cells(1, 1).Font.Bold = True
           .Cells(1, 2) = "Start Date"
           .Cells(1, 2).Font.Bold = True
           .Cells(1, 3) = "Due Date"
           .Cells(1, 3).Font.Bold = True
           .Cells(1, 4) = "From"
           .Cells(1, 4).Font.Bold = True
           .Cells(1, 5) = "To"
           .Cells(1, 5).Font.Bold = True
      End With
 
      For Each objFolder In objOutlookFile.Folders
          If objFolder.DefaultItemType = olMailItem Then
             Call ProcessMailFolders(objFolder)
          End If
      Next
 
      objExcelWorksheet.Columns("A:E").AutoFit

      MsgBox "Completed!", vbInformation + vbOKOnly, "Export Emails"
    End If
End Sub

Sub ProcessMailFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim objFlaggedMail As Outlook.MailItem
    Dim nLastRow As Integer
    Dim objSubfolder As Outlook.Folder
 
    For i = 1 To objCurrentFolder.Items.Count
        If objCurrentFolder.Items(i).Class = olMail Then
           'Export the information of each flagged email to Excel
           Set objMail = objCurrentFolder.Items(i)
           If objMail.IsMarkedAsTask = True And objMail.FlagStatus <> olFlagComplete Then
              Set objFlaggedMail = objMail
 
              With objExcelWorksheet
                   nLastRow = .Range("A" & .Rows.Count).End(xlUp).Row + 1
                   .Range("A" & nLastRow) = objFlaggedMail.Subject
                   .Range("B" & nLastRow) = objFlaggedMail.TaskStartDate
                   .Range("C" & nLastRow) = objFlaggedMail.TaskDueDate
                   .Range("D" & nLastRow) = objFlaggedMail.SenderName
                   .Range("E" & nLastRow) = objFlaggedMail.To
              End With
          End If
        End If
    Next i
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessMailFolders(objSubfolder)
       Next
    End If
End Sub

4. Эцэст нь курсорыг "ExportAllFlaggedEmailsToExcel" дэд программд тавиад "F5" товчийг дарна уу.
5. Дараа нь шинэ харилцах цонхонд Outlook файлыг сонгоно уу.
6. "Дууссан" гэсэн хүсэлтийг авах үед та доорх зураг шиг шинэ Excel файлыг авах болно.

Өөрийн хэтийн төлөвийг авлигаас хамгаалаарай

Outlook нь алдаа, эвдрэлд өртөмтгий тул бидний хувьд Outlook өгөгдлөө хамгаалах нь маш хүнд ажил юм. Хамгийн үр дүнтэй бөгөөд практик арга бол эргэлзээгүй Outlook-д зориулсан өгөгдлийн тогтмол нөөцлөлт хийх явдал юм. Үүнээс гадна бидэнд хүчирхэг, найдвартай Outlook засварлах хэрэгсэл хэрэгтэй, тухайлбал DataNumen Outlook Repair. Хэрэв энэ нь хэрэг болно ирсэн хайрцаг засах хэрэгсэл ямар ч нөлөө үзүүлэхгүй.

Зохиогчийн танилцуулга:

Ширли Жан бол мэдээлэл сэргээх мэргэжилтэн юм DataNumen, Үүнд мэдээлэл сэргээх технологиор дэлхийд тэргүүлэгч, Inc. засах SQL Server програм хангамжийн бүтээгдэхүүнийг засах хэтийн төлөв. Дэлгэрэнгүй мэдээллийг авна уу WWW.datanumen.com