Excel-ийн ажлын хуудсанд сонгосон нүднүүдийг Outlook имэйлээр хурдан илгээх 2 арга

Заримдаа та Excel-ийн ажлын хуудсан дахь сонгосон нүднүүдийг Outlook имэйл рүү хурдан оруулаад энэ имэйлийг илгээхийг хүсч магадгүй юм. Энэхүү нийтлэл нь танд 2 аргыг санал болгох хүслийг авч үзэх болно.

Миний өмнөх нийтлэл “Excel-ийн ажлын хуудсыг Outlook имэйлээр илгээх 2 хурдан арга”Нь Excel-ийн бүхэл хуудсыг имэйлээр хэрхэн яаж илгээхийг зааж өгсөн. Гэсэн хэдий ч, заримдаа та сонгосон нүднүүдийг зөвхөн ажлын хуудсандаа имэйлээр илгээхийг хүсдэг. Энэхүү шаардлагын дагуу бид танд 2 аргыг танилцуулах болно. Та өөрийн сонголтоор аль нэгийг нь сонгож болно.

Арга 1: Сонгосон нүднүүдийг гараар имэйлээр хуулах

1. Эхлэхийн тулд эх Excel файлыг нээгээд зөв Excel ажлын хуудсанд хандана уу.
2. Дараа нь Outlook имэйлээр илгээхийг хүссэн нүднүүдээ сонгоно уу.
3. Дараа нь сонгосон нүднүүдийг хуулахын тулд "Ctrl + C" товчны товчлолыг дарна уу.
4. Үүний дараа Outlook програмаа ажиллуулна уу.
5. Дараа нь, "Нүүр хуудас" тууз дээрх "Шинэ имэйл" товчийг дарж шинэ Outlook имэйл үүсгээрэй.
6. Дараа нь шинэ мессеж цонхонд зурвасын үндсэн хэсэг дээр дарна уу.
7. Дараа нь "Ctrl + V" товчлуурыг дарж өмнө нь хуулж авсан сонгосон Excel нүднүүдийг буулгана уу.
8. Эцэст нь хэлэхэд та имэйлээ ердийн байдлаар бичээд "Илгээх" товчийг дарж илгээх боломжтой.

Арга 2: Сонгосон эсүүдийг VBA-р имэйлээр илгээх

1. Хамгийн эхэнд эх сурвалж Excel-ийн ажлын номыг нээ.
2. Дараа нь “Alt + F11” товчлуурыг дарж Excel VBA засварлагч руу орно уу.
3. Шинэ цонхонд "Оруулах"> "Модуль" дээр дарж шинэ модуль оруулна уу.
4. Дараа нь Microsoft Outlook объектыг идэвхжүүлэх хэрэгтэй. “Tools” > “References” дээр дарна уу. Гарч ирэх харилцах цонхноос “Microsoft Outlook Object Library”-г олж тэмдэглэнэ үү.
5. Дараа нь дараахь VBA кодыг энэ модуль руу хуулна уу.

Sub SendSelectedCells_inOutlookEmail()
    Dim objSelection As Excel.Range
    Dim objTempWorkbook As Excel.Workbook
    Dim objTempWorksheet As Excel.Worksheet
    Dim strTempHTMLFile As String
    Dim objTempHTMLFile As Object
    Dim objFileSystem As Object
    Dim objTextStream As Object
    Dim objOutlookApp As Outlook.Application
    Dim objNewEmail As Outlook.MailItem
 
    'Copy the selection
    Set objSelection = Selection
    Selection.Copy
 
    'Paste the copied selected ranges into a temp worksheet
    Set objTempWorkbook = Excel.Application.Workbooks.Add(1)
    Set objTempWorksheet = objTempWorkbook.Sheets(1)
 
    'Keep the values, column widths and formats in pasting
    With objTempWorksheet.Cells(1)
         .PasteSpecial xlPasteValues
         .PasteSpecial xlPasteColumnWidths
         .PasteSpecial xlPasteFormats
    End With
 
    'Save the temp worksheet as a HTML file
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempHTMLFile = objFileSystem.GetSpecialFolder(2).Path & "\Temp for Excel" & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".htm"
    Set objTempHTMLFile = objTempWorkbook.PublishObjects.Add(xlSourceRange, strTempHTMLFile, objTempWorksheet.Name, objTempWorksheet.UsedRange.Address)
    objTempHTMLFile.Publish (True)
 
    'Create a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objNewEmail = objOutlookApp.CreateItem(olMailItem)
 
    'Read the HTML file data and insert into the email body
    Set objTextStream = objFileSystem.OpenTextFile(strTempHTMLFile)
    objNewEmail.HTMLBody = objTextStream.ReadAll
    objNewEmail.Display
    'You can specify the new email recipients, subjects here using the following lines:
    'objNewEmail.To = "johnsmith@datanumen.com"
    'objNewEmail.Subject = "DataNumen Products"
    'objNewEmail.Send --> directly send out this email
 
    objTextStream.Close
    objTempWorkbook.Close (False)
    objFileSystem.DeleteFile (strTempHTMLFile)
End Sub

6. Эцэст нь та хичээгээд үзээрэй.

• Нэгдүгээрт, тодорхой нүднүүдийг ердийн байдлаар сонгоно уу.
• Дараа нь шинэ макро руу буцаж очоод F5 товчийг дарна уу.
• Нэгэн зэрэг Outlook-ийн шинэ имэйл гарч ирэх бөгөөд үүнд сонгосон нүднүүдийг дараахь дэлгэцийн агшин шиг имэйлийн биед оруулсан болохыг харж болно.

PST файл нь Excel файлтай адил эмзэг байдаг

Бидний мэдэж байгаагаар Excel файл болон Word баримт бичиг нь гэмтэх хандлагатай байдаг. Үнэндээ энэ нь таны Outlook шуудангийн хайрцагт байгаа бүх зүйлийг агуулсан PST файлын хувьд ч мөн адил юм. Тиймээс таны PST өгөгдлийг хамгаалах нь хэцүү ажил юм. Хамгийн үр дүнтэй арга хэмжээнүүдийн нэг бол файлыг тогтмол нөөцлөх явдал юм. Нэмж дурдахад, яаралтай аврахын тулд та туршлагатай хэрэгсэл бэлтгэх хэрэгтэй, тухайлбал DataNumen Outlook Repairболомжтой Outlook-г сэргээх хөлс урсгахгүйгээр өгөгдөл.

Зохиогчийн танилцуулга:

Ширли Жан бол мэдээлэл сэргээх мэргэжилтэн юм DataNumen, Үүнд мэдээлэл сэргээх технологиор дэлхийд тэргүүлэгч, Inc. mdf-ийг засах програм хангамжийн бүтээгдэхүүнийг засах хэтийн төлөв. Дэлгэрэнгүй мэдээллийг авна уу WWW.datanumen.com