Kaip greitai eksportuoti visus hipersaitus keliuose „Outlook“ el. laiškuose į „Excel“.

Kai reikia išgauti visas hipersaitus viename ar keliuose el. laiškuose, kvaila juos kopijuoti po vieną. Šiame įraše sužinosite, kaip greitai eksportuoti visas hipersaitus daugelyje el. laiškų į „Excel“.

Dėl tam tikrų priežasčių, pvz., registruojant hipersaitus visuose jūsų išsiųstuose el. laiškuose, turėsite išskleisti hipersaitus. Be jokių abejonių, nepatartina jų išgauti ir nukopijuoti rankiniu būdu. Turite ilgėtis daug protingesnio požiūrio, pavyzdžiui, naudoti VBA. Čia mes pasidalinsime su tokia VBA kodo dalimi, kuri gali eksportuoti visus daugelio el. laiškų hipersaitus į „Excel“ paprastu paspaudimu.

Eksportuokite visus hipersaitus keliuose el. laiškuose į „Excel“.

1. Norėdami pradėti, paleiskite „Outlook“ programą kaip įprasta.
2. Tada „Outlook“ lange turite paspausti „Alt + F11“ klavišus.
3. Iš karto gausite prieigą prie Outlook VBA redaktoriaus.
4. Vėliau reikia įjungti „Microsoft Word“ objektų biblioteką ir „Microsoft Excel“ objektų biblioteką. Spustelėkite „Įrankiai“ > „Nuorodos“ ir įjunkite jas iššokančiajame dialogo lange.
5. Tada turite atidaryti nenaudojamą modulį, kuriame turite nukopijuoti žemiau esantį VBA kodą į šį modulį.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllHyperlinksInMultipleEmailsToExcel()
    Dim objSelection As Selection
    Dim objMail As MailItem
    Dim objMailDocument As Document
    Dim objHyperlink As Hyperlink
    Dim i As Long
 
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
 
    If Not (objSelection Is Nothing) Then
 
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
       objExcelApp.Visible = True
       objExcelWorkbook.Activate
 
       With objExcelWorksheet
            .Cells(1, 1) = "No."
            .Cells(1, 2) = "Displaying Text"
            .Cells(1, 3) = "Address"
            .Cells(1, 4) = "Source Mail"
      End With
 
      On Error Resume Next
      i = 0
      For Each objMail In objSelection
          objMail.Display
          Set objMailDocument = objMail.GetInspector.WordEditor
          If objMailDocument.Hyperlinks.Count > 0 Then
             For Each objHyperlink In objMailDocument.Hyperlinks
                 If InStr(objHyperlink.Address, "www.") > 0 Then
                    i = i + 1
                    Call ExportToExcel(i, objMail, objHyperlink)
                 End If
             Next
          End If
          objMail.Close olDiscard
      Next
 
      objExcelWorksheet.Columns("A:D").AutoFit
    End If
End Sub

Sub ExportToExcel(n As Long, objCurrentMail As MailItem, objCurrentHyperlink As Hyperlink)
    Dim nLastRow As Integer
 
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
    objExcelWorksheet.Range("A" & nLastRow) = n
    objExcelWorksheet.Range("B" & nLastRow) = objCurrentHyperlink.TextToDisplay
    objExcelWorksheet.Range("C" & nLastRow) = objCurrentHyperlink.Address
    objExcelWorksheet.Range("D" & nLastRow) = objCurrentMail.Subject
End Sub

6. Po to galite išeiti iš dabartinio VBA redaktoriaus lango.
7. Vėliau pasiekite „Outlook Options“, kad tinkintumėte greitosios prieigos įrankių juostą, kad pridėtumėte naujai pridėtą makrokomandą prie greitosios prieigos įrankių juostos.
8. Galiausiai galite nufotografuoti:

• Pirmiausia el. pašto sąraše pasirinkite el. laiškus, kurių hipersaitus norite išskleisti.
• Tada greitosios prieigos įrankių juostoje spustelėkite makrokomandos mygtuką.
• Kai makrokomanda bus baigta, gausite „Excel“ failą, kaip ir toliau pateiktame paveikslėlyje:

Išspręskite netikėtas „Outlook“ problemas

„Outlook“ problemos gali kilti retkarčiais be jokių ženklų. Tačiau kalbant apie mažas klaidas, „Outlook“ gali būti atkurta paprastu paleidimu iš naujo arba... pašto dėžutės taisymo įrankis. Tačiau jei susidursite su rimtomis bėdomis, vidinės priemonės nepadės. Šiuo metu jūsų paskutinė išeitis tikrai yra patikimesnis ir patikimesnis įrankis, pvz DataNumen Outlook Repair.

Autoriaus įvadas:

Shirley Zhang yra duomenų atkūrimo ekspertė DataNumen, Inc., kuri yra pasaulyje duomenų atkūrimo technologijų lyderė, įskaitant sugadintas mdf ir „Outlook“ taisymo programinės įrangos produktai. Norėdami gauti daugiau informacijos, apsilankykite WWW.datanumen.com