Kaip greitai eksportuoti visų „Outlook“ kontaktų grupės narių informaciją į „Excel“.

Pagal numatytuosius nustatymus kontaktų grupėje galite matyti tik narių vardus ir el. pašto adresus. Jei norite gauti kitą informaciją apie narius, galite pasinaudoti šiame straipsnyje aprašytu būdu.

Dukart spustelėję kontaktų grupę, kad ją atidarytumėte, jos lange matysite tik grupės narių vardus ir el. pašto adresus. Negalite gauti kitos narių informacijos, pvz., įmonės, pareigų pavadinimo, telefono numerio ar įmonės adreso ir kt. Apskritai, norėdami gauti šią informaciją, turite neautomatiniu būdu surasti kontaktus, atitinkančius narius savo kontaktų aplanke. Tai per daug varginanti. Čia parodysime dalį VBA kodo, kuris gali greitai eksportuoti šią informaciją į „Excel“ darbaknygę.

Eksportuokite visų kontaktų grupės narių informaciją į „Excel“.

1. Norėdami pradėti, paleiskite „Outlook“ programą.
2. Tada pagrindiniame „Outlook“ lange turėtumėte paspausti sparčiuosius klavišus „Alt + F11“.
3. Tada naujame lange „Microsoft Visual Basic for Applications“ turite atidaryti nenaudojamą modulį arba tiesiogiai įterpti naują modulį.
4. Tada nukopijuokite ir įklijuokite šį VBA kodą į šį modulį.

Sub ExportMemberContactDetailsToExcel()
    Dim objContactGroup As Outlook.DistListItem
    Dim objGroupMember As Outlook.recipient
    Dim objContacts As Outlook.Items
    Dim objFoundContact As Outlook.ContactItem
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim i As Integer
    Dim nRow As Integer
    Dim strFilename As String
 
    Set objContactGroup = Application.ActiveExplorer.Selection(1)
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkBook = objExcelApp.Workbooks.Add
    Set objExcelWorkSheet = objExcelWorkBook.Worksheets(1)
 
    'Set the seven column headers
    With objExcelWorkSheet
         .Cells(1, 1) = "Name"
         .Cells(1, 2) = "Email Address"
         .Cells(1, 3) = "Company"
         .Cells(1, 4) = "Job Title"
         .Cells(1, 5) = "Phone Number"
         .Cells(1, 6) = "Mailing Address"
         .Cells(1, 7) = "Birthday"
    End With
 
    Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items.Restrict("[Email1Address]>''")
 
    nRow = 2
    For i = 1 To objContactGroup.MemberCount
        Set objGroupMember = objContactGroup.GetMember(i)
 
        strFilter = "[Email1Address] = '" & objGroupMember.Address & "'"
        Set objFoundContact = objContacts.Find(strFilter)
 
        If Not (objFoundContact Is Nothing) Then
           'Input the Contact Details
           With objExcelWorkSheet
                .Cells(nRow, 1) = objFoundContact.FullName
                .Cells(nRow, 2) = objFoundContact.Email1Address
                .Cells(nRow, 3) = objFoundContact.CompanyName
                .Cells(nRow, 4) = objFoundContact.JobTitle
                .Cells(nRow, 5) = objFoundContact.BusinessTelephoneNumber
                .Cells(nRow, 6) = objFoundContact.MailingAddress
             If objFoundContact.Birthday = #1/1/4501# Then
                .Cells(nRow, 7) = ""
             Else
                .Cells(nRow, 7) = objFoundContact.Birthday
             End If
           End With
       Else
           With objExcelWorkSheet
               .Cells(nRow, 1) = objGroupMember.Name
               .Cells(nRow, 2) = objGroupMember.Address
           End With
       End If
       nRow = nRow + 1
    Next
 
    'Fit the columns
    objExcelWorkSheet.Columns("A:G").AutoFit
 
    'Change the Path as per where you want to save the new Excel file
    strFilename = "E:\" & objContactGroup.DLName & " Member Contact Details.xlsx"
    'Save the Excel workbook
    objExcelWorkBook.Close True, strFilename
 
    MsgBox ("Complete!")
End Sub

5. Po to, norėdami patogiai patikrinti, galite pridėti naują VBA projektą prie greitosios prieigos įrankių juostos arba juostos.
6. Vėliau nustatykite „Outlook“ makrokomandos saugos lygį į žemą.
7. Galų gale galite pabandyti.

• Pirmiausia pasirinkite kontaktų grupę.
• Tada paspauskite makrokomandos mygtuką greitosios prieigos įrankių juostoje arba juostelėje.
• Nedelsiant paleis makrokomandą.
• Kai jis baigsis, gausite raginimą „Baigti!
• Po to galite pereiti į iš anksto nustatytą paskirties vietinį aplanką, kuriame galite rasti naują „Excel“ failą.
• Atidarykite jį ir pamatysite grupės narių kontaktinius duomenis, pvz., šią ekrano kopiją:

Nepanikuokite susidūrę su „Outlook“ problemomis

Niekas nenori priimti jokių „Outlook“ problemų, neatsižvelgiant į iššokantį klaidos pranešimą ar sugadintas Outlook informacijos rinkmena. Todėl vartotojai bus linkę panikuoti susidūrę su „Outlook“ problemomis. Jei tokiu atveju norite išlikti ramūs, turėtumėte turėti du būtiniausius dalykus. Vienas iš jų yra dabartinės „Outlook“ duomenų atsarginės kopijos. Kitas yra galinga „Outlook“ taisymo programinė įranga, pvz DataNumen Outlook Repair.

Autoriaus įvadas:

Shirley Zhang yra duomenų atkūrimo ekspertė DataNumen, Inc., kuri yra pasaulyje duomenų atkūrimo technologijų lyderė, įskaitant sql atkūrimas ir „Outlook“ taisymo programinės įrangos produktai. Norėdami gauti daugiau informacijos, apsilankykite WWW.datanumen.com