Kaip greitai pridėti konkrečius „Word“ dokumento puslapius prie „Outlook“ el

MS Word turi tiesioginę funkciją, padedančią vartotojams siųsti dabartinį Word dokumentą kaip el. pašto priedą. Tačiau kartais galite tikėtis, kad prie „Outlook“ el. laiško pridėsite konkrečius „Word“ dokumento puslapius. Dabar šiame straipsnyje bus pateiktas metodas.

Norėdami išsiųsti visą „Word“ dokumentą kaip el. pašto priedą „MS Word“ programoje, galite tiesiog eiti į „Failas“ meniu ir pereiti į skirtuką „Išsaugoti ir siųsti“, po kurio rasite mygtuką „Siųsti kaip priedą“. Tačiau kartais tai, ką norite išsiųsti, gali būti tik konkretūs dokumento puslapiai. Esant tokiai situacijai, galite naudoti toliau pateiktą metodą.

Pridėkite konkrečius Word dokumento puslapius prie el

1. Pirmiausia turėtumėte atidaryti šaltinio Word dokumentą, kurio konkrečius puslapius norite siųsti el.
2. Tada, patekę į MS Word langą, turite paspausti klavišus „Alt + F11“.
3. Tada gausite prieigą prie VBA redaktoriaus MS Word.
4. Po to turite įjungti „Microsoft Outlook“ objektų biblioteką. Norėdami tai padaryti, spustelėkite „Įrankiai“ > „Nuoroda“.
5. Vėliau turėtumėte nukopijuoti šį VBA kodą į modulį, kuris nenaudojamas.

Sub AttachSpecificPagesToOutlookEmail()
    Dim strDocumentName As String
    Dim objSelectedPages As Word.Range
    Dim objTempDocument As Word.Document
    Dim objTempRange As Word.Range
    Dim i As Long
    Dim strTempDocument As String
    Dim objOutlookApp As Outlook.Application
    Dim objMail As Outlook.MailItem
 
    strDocumentName = Left(ActiveDocument.Name, InStr(ActiveDocument.Name, ".") - 1)
 
    'Copy the contents from Page 2 to 4
    'You can change the page as per your own needs
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=2
    Set objSelectedPages = Selection.Range
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=4
    objSelectedPages.End = Selection.Bookmarks("\Page").Range.End
    objSelectedPages.Select
    objSelectedPages.Copy
 
    'Paste the copied contents into a new Word Document
    Set objTempDocument = Word.Application.Documents.Add
    objTempDocument.Activate
    Set objTempRange = objTempDocument.Range(0, 0)
    objTempRange.PasteAndFormat (wdFormatOriginalFormatting)

    For i = objTempDocument.Paragraphs.Count To 1 Step -1
        If Len(objTempDocument.Paragraphs(i).Range) = 1 Then
           objTempDocument.Paragraphs(i).Range.Delete
        Else
           Exit For
        End If
    Next i
 
    'Save this document
    strTempDocument = "E:\" & strDocumentName & " (Excerpt).doc"
    objTempDocument.SaveAs2 strTempDocument, wdFormatDocument
 
    'Attach the new document to a new Outlook email
    On Error Resume Next
    Set objOutlookApp = GetObject(, "Outlook.Application")
    If objOutlookApp Is Nothing Then
       Set objOutlookApp = CreateObject("Outlook.Application")
    End If
 
    Set objMail = objOutlookApp.CreateItem(olMailItem)
    objMail.Attachments.Add (strTempDocument)
    objMail.Display
 
    objTempDocument.Close False
    Kill strTempDocument
End Sub

6. Galiausiai galite paleisti šią makrokomandą. Tiesiog paspauskite klavišo F5 mygtuką arba įrankių juostoje bakstelėkite piktogramą „Vykdyti“.
7. Pasibaigus makrokomandai, bus rodomas naujas „Outlook“ el. laiškas, pridėtas su šaltinio „Word“ dokumento ištrauka, pvz., toliau pateikta ekrano kopija:

Ištraukite maksimalų duomenų kiekį iš sugadinto „Outlook“ failo

Jei „Outlook“ naudojote dešimtmečius, galėjote susidurti su įvairiomis „Outlook“ problemomis, įskaitant iššokančius vidinius klaidų pranešimus, staigius gedimus ir rimtus failų pažeidimus. Dėl to, kad scanpst, integruotas taisymo įrankis, gali išspręsti tik mažas problemas, geriau turėti išorinį galingą taisymo įrankį, tarkime, DataNumen Outlook Repair. Jis gali ištraukti maksimalius duomenis iš sugadinto Outlook duomenų failo.

Autoriaus įvadas:

Shirley Zhang yra duomenų atkūrimo ekspertė DataNumen, Inc., kuri yra pasaulyje duomenų atkūrimo technologijų lyderė, įskaitant sql taisymas ir „Outlook“ taisymo programinės įrangos produktai. Norėdami gauti daugiau informacijos, apsilankykite WWW.datanumen.com