Kaip greitai pridėti paskutinį modifikuotą failą „Windows“ aplanke prie „Outlook“ el

Kartais gali tekti greitai surasti ir pridėti paskutinį modifikuotą failą konkrečiame „Windows“ aplanke prie „Outlook“ el. Tokiu atveju galite naudoti šiame straipsnyje aprašytą metodą.

Kai kurie vartotojai nori, kad „Outlook“ programa greitai rastų ir prie el. laiško pridėtų paskutinį modifikuotą failą „Windows“ aplanke, pvz., naujausią sukurtą, pakeistą ar išsaugotą failą. Tačiau „Outlook“ nesiūlo tokios tiesioginės ir vietinės funkcijos. Todėl toliau pateiksime VBA kodo fragmentą, kuris gali tai lengvai įgyvendinti.

Pridėkite paskutinį modifikuotą failą „Windows“ aplanke prie el

1. Pačioje pradžioje turėtumėte paleisti „Outlook“ programą.
2. Tada, kai pateksite į pagrindinį "Outlook" langą, galite paspausti "Alt + F11" klavišų mygtukus.
3. Tada sėkmingai pasieksite „Outlook VBA“ redaktoriaus langą.
4. Vėliau turėtumėte rasti ir atidaryti modulį, kuris nenaudojamas.
5. Tada nukopijuokite ir įklijuokite šį VBA kodą į šį modulio langą.

Sub AttachLastModifiedSpecificFile()
    Dim objShell As Object
    Dim objSelectedFolder As Object
    Dim objFileSystem As Object
    Dim strSourceFolderPath As String
    Dim objSourceFolder As Object
    Dim objFile As Object
    Dim dLastModifiedDate As Date
    Dim strLastModifiedFilePath As String
    Dim objMail As Outlook.MailItem
 
    On Error GoTo ErrorHandler
    'Select a local source folder
    Set objShell = CreateObject("Shell.Application")
    Set objSelectedFolder = objShell.BrowseForFolder(0, "Select the source folder", 0, "")
    strSourceFolderPath = objSelectedFolder.self.Path
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objSourceFolder = objFileSystem.GetFolder(strSourceFolderPath)
 
    If objSourceFolder.Files.Count > 0 Then
       For Each objFile In objSourceFolder.Files
           'Find the last modified file within "xlsx" file type in the selected Windows folder
           If (objFile.DateLastModified > dLastModifiedDate) And (objFileSystem.GetExtensionName(objFile) = "xlsx") Then
              'You can add or change criteria, such as
              'Left(objFile.Name, 4) = "Test" ---> file whose name begins with "Test"
              '(objFile / 1024) / 1024 > 2 --> File exceeds 2 MB
              'Note: Use "And" to connect more than one criteria
              strLastModifiedFilePath = objFile.Path
              dLastModifiedDate = objFile.DateLastModified
           End If
       Next
 
       If strLastModifiedFilePath <> "" Then
          'Confirm attaching it to the current outlook email
          strMsg = "The last modified file in the " & Chr(34) & strSourceFolderPath & Chr(34) & " is: " & vbCrLf & vbCrLf & "File: " & strLastModifiedFilePath & vbCrLf & "Date: " & dLastModifiedDate & vbCrLf & vbCrLf & "Do you want to attach it?"
          nPrompt = MsgBox(strMsg, vbQuestion + vbYesNo, "Confirm Attaching Last Modified File")
 
          If nPrompt = vbYes Then
             Set objMail = Outlook.Application.ActiveInspector.CurrentItem
             objMail.Attachments.Add strLastModifiedFilePath
         End If
      Else
         MsgBox "No file in the selected folder can meet your predefined criteria!", vbExclamation + vbOKOnly
      End If
    Else
      MsgBox "No file exists in the selected Windows folder!", vbExclamation + vbOKOnly
    End If
 
ErrorHandler:
    Exit Sub
End Sub

6. Po to galite išeiti iš dabartinio VBA rengyklės lango ir pridėti naują makrokomandą prie greitosios prieigos įrankių juostos arba pranešimų lango juostos.
7. Vėliau turėsite pakeisti „Outlook“ makrokomandos saugos lygį į žemą.
8. Galų gale galite pabandyti.

• Pirma, kaip įprasta, sukurkite ir sukurkite naują „Outlook“ el.
• Tada greitosios prieigos įrankių juostoje paspauskite makrokomandos mygtuką, kaip parodyta toliau pateiktame paveikslėlyje:
• Tada turėsite pasirinkti šaltinio „Windows“ aplanką ir paspausti „Gerai“.
• Jei pasirinktame „Windows“ aplanke yra toks failas, gausite raginimą, pavyzdžiui, šią ekrano kopiją:
• Kai paspausite „Taip“, šis failas bus pridėtas iš karto.

Kuo greičiau išspręskite „Outlook“ problemas

Kiekvieną kartą, kai susiduriate su „Outlook“ problemomis, rekomenduojama jas kuo greičiau išspręsti. Esant tokiai situacijai, geriau pasiruošti tvirtą Outlook taisymas priemonė iš anksto, pvz DataNumen Outlook Repair. Jis gali ištaisyti PST klaidas ir veiksmingai išgelbėti „Outlook“ duomenis.

Autoriaus įvadas:

Shirley Zhang yra duomenų atkūrimo ekspertė DataNumen, Inc., kuri yra pasaulyje duomenų atkūrimo technologijų lyderė, įskaitant sugadintas mdf ir „Outlook“ taisymo programinės įrangos produktai. Norėdami gauti daugiau informacijos, apsilankykite WWW.datanumen.com