Kaip greitai ištraukti visus gavėjus iš kelių „Outlook“ pranešimų (.msg) failų

Kai kurie vartotojai norėtų greitai ištraukti visus gavėjus iš kelių „Outlook“ pranešimų failų, išsaugotų iš „Outlook“ el. laiškų. Dabar šis post pažvelgs į tai, kad pasidalintų greitu požiūriu.

Norėdami išimti gavėjus iš vieno „Outlook“ pranešimo failo, galite tiesiog dukart spustelėti, kad jį atidarytumėte, tada nukopijuokite gavėjus atidarytame pranešimo lange. Tačiau jei jums reikia tvarkyti „Outlook“ pranešimų failų paketą, rankinis metodas nėra pakankamai efektyvus. Taigi, galite ieškoti daug efektyvesnio būdo. Čia mes jums pristatysime tokį. Skaitykite toliau, kad gautumėte išsamią informaciją.

Išskleiskite visus gavėjus iš kelių „Outlook“ pranešimų (.msg) failų

1. Dėl astart, gaukite prieigą prie Outlook VBA redaktoriaus pagal „Kaip paleisti VBA kodą „Outlook“.".
2. Tada nukopijuokite ir įklijuokite šį VBA kodą į tuščią modulį.

Dim strRecipients As String

Sub ExtractRecipientsFromOutlookMSGFiles()
    Dim objShell, objWindowsFolder As Object
 
    strRecipients = ""
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       Call ProcessWindowsFolders(objWindowsFolder.self.Path & "\")
       'Display a Message
       MsgBox "Recipients: " & vbCrLf & strRecipients, vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessWindowsFolders(strFolderPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFile As Object
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.Recipient
    Dim objSubfolder As Object

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strFolderPath)
 
    For Each objFile In objFolder.Files
        If objFileSystem.GetExtensionName(objFile) = "msg" Then
           Set objItem = Session.OpenSharedItem(objFile.Path)

           If TypeName(objItem) = "MailItem" Then
              Set objMail = objItem
              'Extract recipients' email addresses
              For Each objRecipient In objMail.Recipients
                  strRecipients = strRecipients & objRecipient.Address & vbCr
              Next
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubfolder In objFolder.SubFolders
           If ((objSubfolder.Attributes And 2) = 0) And ((objSubfolder.Attributes And 4) = 0) Then
               Call ProcessWindowsFolders(objSubfolder.Path)
           End If
       Next
    End If
End Sub

3. Tada perkelkite žymeklį į pirmąją paprogramę.
4. Tada spustelėkite mygtuką „Vykdyti“ arba paspauskite klavišą „F5“.
5. Tada iššokančiajame dialogo lange pasirinkite „Windows“ aplanką, kuriame yra šaltinio „Outlook“ pranešimų (.msg) failai.
6. Pasirinkę spustelėkite „Gerai“, kad makrokomandos būtų toliau paleistos.
7. Kai makrokomanda bus baigta, bus rodomas pranešimas, kuriame bus nurodyti visi išskleisti gavėjų el. pašto adresai, kaip parodyta toliau esančioje ekrano kopijoje.

Apsaugokite savo „Outlook“ duomenis nuo pavojaus

Žinoma, „Outlook“ duomenys yra linkę į korupciją. Taigi „Outlook“ duomenų apsauga yra gana sudėtinga užduotis. Tam reikia atkakliai daryti reguliarias „Outlook“ duomenų atsargines kopijas. Taip pat, jei įmanoma, protinga ir rekomenduojama parengti patyrusį ir profesionalų Outlook PST remontas įrankis, pvz DataNumen Outlook Repair, kad galėtumėte nedelsiant ir laiku išgelbėti „Outlook“ sugadinimo atveju.

Autoriaus įvadas:

Shirley Zhang yra duomenų atkūrimo ekspertė DataNumen, Inc., kuri yra pasaulyje duomenų atkūrimo technologijų lyderė, įskaitant atsigauti Sql Server ir „Outlook“ taisymo programinės įrangos produktai. Norėdami gauti daugiau informacijos, apsilankykite WWW.datanumen.com