Kaip paketu atidaryti visus hipersaitus su konkrečiu domenu „Outlook“ el

Peržiūrėdami „Outlook“ el. laišką, kurio turinyje yra daug hipersaitų, kartais galbūt norėsite greitai atidaryti hipersaitus su konkrečiu domenu. Čia pasidalinsime metodu, kaip masiškai atidaryti tokius hipersaitus.

Jei viename el. laiške yra keli hipersaitai, galite tikėtis patikrinti kai kuriuos iš jų, o ne visus. Pvz., Jūs norite tik paketiniu būdu atidaryti hipersaitus su konkrečiu domenu. Apskritai, norėdami juos atidaryti, turite spustelėti po vieną. Tai labai varginanti. Todėl toliau mes išmokysime jus patogesnio būdo.

Pakeiskite atidarykite visus hipersaitus su konkrečiu domenu el

1. Dėl astart, pasiekite „Outlook VBA“ redaktorių pagal „Kaip paleisti VBA kodą „Outlook“.".
2. Tada lange „Microsoft Visual Basic for Applications“ įgalinkite nuorodą į „MS Word Object Library“ su nuoroda į „Kaip pridėti objekto library Nuoroda VBA".
3. Tada nukopijuokite šį VBA kodą į nenaudojamą modulį arba projektą.

Sub BatchOpenHyperlinksWithSpecificDomain()
    Dim objMail As MailItem
    Dim objMailDocument As Word.Document
    Dim objHyperlink As Word.Hyperlink
    Dim objDictionary As Object
    Dim i As Integer
    Dim varHyperlinks As Variant
    Dim varHyperlink As Variant
    Dim objInternetExplorer As Object
 
    'Get the source email
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objMail = ActiveInspector.CurrentItem
           Case olExplorer
                Set objMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
    Set objMailDocument = objMail.GetInspector.WordEditor
    For Each objHyperlink In objMailDocument.Hyperlinks
        If InStr(1, objHyperlink.Address, "www.datanumen.com") > 0 Then
           'Add Hyperlinks to Dictionary
           If objDictionary.Exists(objHyperlink.Address) = False Then
              objDictionary.Add objHyperlink.Address, 1
           End If
        End If
    Next
 
    'Batch Open Hyperlinks on different tabs in same Internet Explorer window
    Set objInternetExplorer = CreateObject("InternetExplorer.Application")
    varHyperlinks = objDictionary.Keys
    For i = LBound(varHyperlinks) To UBound(varHyperlinks)
        varHyperlink = varHyperlinks(i)
 
        If i = 0 Then
           objInternetExplorer.Visible = True
           objInternetExplorer.navigate varHyperlink
        Else
           objInternetExplorer.navigate varHyperlink, CLng(2048)
        End If
    Next
End Sub

4. Tada pridėkite šią makrokomandą prie greitosios prieigos įrankių juostos arba juostos.
5. Galiausiai, norėdami išbandyti, atlikite toliau nurodytus veiksmus.

• Pirmiausia pasirinkite arba atidarykite „Outlook“ el.
• Tada spustelėkite makrokomandos mygtuką.
• Iš karto el. laiške esantys hipersaitai su iš anksto nustatytu domenu bus atidaromi paketu „Internet Explorer“, kaip parodyta šiame paveikslėlyje:

Atsikratykite erzinančios Outlook korupcijos

Nors „Outlook“ yra jautri klaidoms ir korupcijai, iš tikrųjų, jei tik saugotės visų pavojų, galite lengvai nuo jų išvengti. Pavyzdžiui, turite reguliariai kurti „Outlook“ duomenų atsargines kopijas. Be to, turėtumėte saugotis įtartinų el. laiškų, kuriuose gali būti virusų. Paskutinis, bet ne mažiau svarbus dalykas – geriau pasiruošti „Outlook“ taisymas naudingumas, pvz DataNumen Outlook Repair. Jis gali padėti jums sugadinus „Outlook“.

Autoriaus įvadas:

Shirley Zhang yra duomenų atkūrimo ekspertė DataNumen, Inc., kuri yra pasaulyje duomenų atkūrimo technologijų lyderė, įskaitant sugadintas SQL Server ir „Outlook“ taisymo programinės įrangos produktai. Norėdami gauti daugiau informacijos, apsilankykite WWW.datanumen.com