Kaip grupiniu būdu pažymėti visus el. laiškus kaip perskaitytus visuose „Outlook“ aplankuose naudojant VBA

Keli vartotojai trokšta sprendimo, kaip paketu pažymėti visus el. laiškus kaip perskaitytus visuose „Outlook“ aplankuose. Šiame straipsnyje mes jums pristatysime tokį metodą.  

Kaip visi žinome, visus aplanke esančius laiškus lengva pažymėti kaip skaitytus. Tiesiog pasirinkite ir dešiniuoju pelės mygtuku spustelėkite aplanką, tada kontekstiniame meniu pasirinkite parinktį „Pažymėti viską kaip skaitytą“. Tačiau jei yra keli aplankai, kuriuose yra neskaitytų el. laiškų, aukščiau nurodytomis priemonėmis turite atlikti aplankus po vieną. Tai per daug varginanti. Taigi, čia mes pasidalinsime jums daug efektyvesniu būdu, kuris leis jums tai realizuoti masiškai.

Pažymėkite visus el. laiškus kaip perskaitytus visuose „Outlook“ aplankuose

1. Į start su, paleiskite programą „Outlook“.
2. Tada paspauskite „Alt + F11“, kad pasiektumėte „Outlook VBA“ rengyklę.
3. Tada lange „Microsoft Visual Basic for Applications“ nukopijuokite toliau pateiktą kodą į nenaudojamą modulį.

Sub MarkAllItemsAsRead()
    Dim objStores As Outlook.Stores
    Dim objStore As Outlook.Store
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    'Process all Outlook files
    Set objStores = Outlook.Application.Session.Stores
  
    For Each objStore In objStores
        Set objOutlookFile = objStore.GetRootFolder
 
        For Each objFolder In objOutlookFile.Folders
            'Process mail folders
            If objFolder.DefaultItemType = olMailItem Then
               Call ProcessFolders(objFolder)
            End If
        Next
    Next
End Sub

Sub ProcessFolders(ByVal objCurFolder As Outlook.Folder)
    Dim objUnreadItems As Outlook.Items
    Dim i As Integer
    Dim objItem As Object
    Dim objSubFolder As Outlook.Folder
 
    Set objUnreadItems = objCurFolder.Items.Restrict("[Unread]=True")
 
    'Mark all unread emails as read
    For i = 1 To objUnreadItems.Count
        Set objItem = objUnreadItems.Item(i)
        objItem.UnRead = False
        objItem.Save
    Next
 
    'Process subfolders recursively
    If objCurFolder.Folders.Count > 0 Then
       For Each objSubFolder In objCurFolder.Folders
           Call ProcessFolders(objSubFolder)
       Next
    End If
End Sub

4. Po to perkelkite žymeklį į pirmąją paprogramę.
5. Tada paspauskite mygtuką „F5“ arba įrankių juostoje spustelėkite „Vykdyti“ piktogramą.
6. Galiausiai, baigę makrokomandą, galite grįžti į el. pašto aplankų sąrašą.
7. Ten pamatysite, kad visi neskaityti el. laiškai pažymėti kaip skaityti, kaip parodyta ekrano kopijoje.

Pabėgkite nuo apgailėtino „Outlook“ duomenų praradimo

Vartotojai galėjo pripažinti faktą, kad Word dokumentus ir Excel darbaknyges galima lengvai sugadinti. Tiesą sakant, panašiai kaip šie failai, „Outlook“ duomenų failas taip pat gali būti pažeistas. Taigi, jei nenorite to patirti, turėtumėte imtis tam tikrų veiksmų. Tai turėtų apimti atsargumo priemones, pvz., reguliarias atsargines kopijas ir visų kenkėjiškų programų ar virusų blokavimą, taip pat kai kurias pagalbos priemones, pvz., žinoti, kaip paleisti gautųjų taisymo įrankį, scanpst ir išlaikyti galingą išorinį taisymo įrankį, pvz DataNumen Outlook Repair.

Autoriaus įvadas:

Shirley Zhang yra duomenų atkūrimo ekspertė DataNumen, Inc., kuri yra pasaulyje duomenų atkūrimo technologijų lyderė, įskaitant remontuoti mdf ir „Outlook“ taisymo programinės įrangos produktai. Norėdami gauti daugiau informacijos, apsilankykite WWW.datanumen.com