Kaip automatiškai naudoti skirtingas šriftų spalvas atsakant ir persiunčiant el. laiškus naudojant „Outlook VBA“.

Pagal numatytuosius nustatymus negalite leisti programai „Outlook“ automatiškai naudoti skirtingų šriftų spalvų atsakant ir persiunčiant el. Todėl, jei turite tokį reikalavimą, galite perskaityti šį post išmokti protingo požiūrio.

„Outlook“ leidžia nurodyti tik šriftą, naudojamą atsakant ir persiunčiant el. laiškus. Galite eiti į „Failas“ > „Parinktys“. Tada „Outlook“ parinktyse eikite į skirtuką „Paštas“ ir spustelėkite mygtuką „Raštinės reikmenys ir šriftai…“. Kitame lange galite pamatyti mygtuką „Šriftas“, esantį „Atsakymas arba pranešimų persiuntimas“. Spustelėkite jį ir galėsite nustatyti konkrečią šrifto spalvą atsakydami į el. laiškus ir juos persiųsdami.

Tačiau daugelis vartotojų tikisi naudoti skirtingas šrifto spalvas atsakydami į el. laiškus arba juos persiųsdami. Nors „Outlook“ tam neteikia jokių tiesioginių funkcijų, ją vis tiek galima realizuoti naudojant VBA kodą. Dabar skaitykite toliau, kad gautumėte tokią VBA kodo dalį.

Automatiškai naudokite skirtingas šriftų spalvas atsakydami į el. laiškus ir juos persiųsdami

1. Dėl astart, paleiskite „Outlook“ programą.
2. Tada suaktyvinkite VBA redaktorių, nurodydami „Kaip paleisti VBA kodą „Outlook“.".
3. Toliau, vadovaujantis „Kaip pridėti objekto library Nuoroda VBA“, pridėkite nuorodą į „MS Word Object Library “.
4. Vėliau nukopijuokite šį kodą į „ThisOutlookSession“ projektą.

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Dim objReply As Outlook.MailItem
    Dim objReplyDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReply = objMail.Reply
    objReply.Display
    Set objReplyDoc = objReply.GetInspector.WordEditor
    objReplyDoc.Range(0, 0).Select
    Set objDocSelection = objReplyDoc.Application.Selection
    'Use "Pink" font in "Reply"
    objDocSelection.Font.ColorIndex = wdPink
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objReplyAll As Outlook.MailItem
    Dim objReplyAllDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReplyAll = objMail.ReplyAll
    objReplyAll.Display
    Set objReplyAllDoc = objReplyAll.GetInspector.WordEditor
    objReplyAllDoc.Range(0, 0).Select
    Set objDocSelection = objReplyAllDoc.Application.Selection
    'Use "Green" font in "Reply All"
    objDocSelection.Font.ColorIndex = wdGreen
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Dim objForward As Outlook.MailItem
    Dim objForwardDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objForward = objMail.Forward
    objForward.Display
    Set objForwardDoc = objForward.GetInspector.WordEditor
    objForwardDoc.Range(0, 0).Select
    Set objDocSelection = objForwardDoc.Application.Selection
    'Use "Blue" font in Forward
    objDocSelection.Font.ColorIndex = wdBlue
End Sub

5. Po to atstart Outlook, kad suaktyvintumėte šią makrokomandą.
6. Pagaliau galite pabandyti.

• Pasirinkite arba atidarykite el. laišką.
• Tada spustelėkite mygtuką „Atsakyti“. Atsakydami į el. laišką galite įvesti kai kuriuos žodžius tekste. Šrifto spalva turi būti rausva.
• Arba spustelėkite mygtuką „Atsakyti visiems“. Naujame laiške „atsakyti visiems“ tekste įveskite žodžius. Šrifto spalva tikrai žalia.
• Panašiai spustelėkite mygtuką „Persiųsti“. Persiuntimo laiške nauji žodžiai bus rodomi mėlyna spalva.

Pasinaudokite patikima programine įranga

Tuo atveju Outlook korupcijaMost vartotojai linkę naudoti „Outlook“ atkūrimo programinę įrangą. Rinkoje yra daug tokių programų. Ir kai kurie iš jų yra net nemokami. Nepaisant to, turėtumėte saugotis tų, kurie yra iš nežinomų šaltinių, nes jie gali pabloginti dabartinę situaciją. Turėtumėte pasinaudoti patikimu ir patyrusiu įrankiu, pvz DataNumen Outlook Repair.

Autoriaus įvadas:

Shirley Zhang yra duomenų atkūrimo ekspertė DataNumen, Inc., kuri yra pasaulyje duomenų atkūrimo technologijų lyderė, įskaitant sugadintas sql ir „Outlook“ taisymo programinės įrangos produktai. Norėdami gauti daugiau informacijos, apsilankykite WWW.datanumen.com