Kaip efektyviai pridėti pastabų prie „Outlook“ el. laiškų naudojant VBA ir „UserForm“.

Kartais galite tikėtis redaguoti arba pridėti pastabų el. laiškuose programoje „Outlook“. Šiame straipsnyje bus pristatytas efektyvus būdas pasiekti šią funkciją.

Nuo4 paprasti būdai, kaip įterpti pastabą į „Outlook“ pranešimus“, galite išmokti įterpti pastabas į el. laiškus naudodami „Outlook“ vietines funkcijas, pvz., naudoti pasirinktines vėliavėles, įvesti pastabą temoje arba turinyje arba pridėti esamus pastabų elementus prie šio el. Tačiau visi jie yra tik išeitis. Čia mes išmokysime daug efektyvesnio metodo. Naudodami jį galėsite pridėti pastabų prie el. laiškų ir redaguoti arba ištrinti esamus užrašus.

Pridėkite pastabų prie „Outlook“ el. laiškų

1. Norėdami pradėti, pasiekite VBA redaktorių paspausdami „Alt + F11“ programoje „Outlook“.
2. Tada spustelėkite „Įterpti“ > „Vartotojo forma“.
3. Tada naujoje vartotojo formoje sukurkite teksto laukelį, panašų į paveikslėlį žemiau.
4. Tada pakeiskite teksto laukelio pavadinimą į „txtNotes“, kaip ir ekrano kopijoje.
5. Po to formoje sukurkite du komandų mygtukus.
6. Tada pasirinkite „CommandButton 1“. Pakeiskite jo pavadinimą į „btnOK“, o jo pavadinimą pakeiskite į „Gerai“.
7. Tada pakeiskite „CommandVutton 2“ pavadinimą į „btnCancel“, o „Antraštę“ – į „Atšaukti“.
8. Tada pasirinkite visą vartotojo formą ir pakeiskite jos pavadinimą „Pavadinimas“ į „frmAddNote“, o „Antraštė“ – į „Įveskite pastabą“.
9. Tada dešiniuoju pelės mygtuku spustelėkite „fromAddNote“ ir pasirinkite „View Code“.
10. Naujame ekrane nukopijuokite į jį šį kodą.

Private Sub btnOK_Click()
    Dim strNote As String
    Dim objMail As Outlook.MailItem
    Dim objNote As Outlook.NoteItem
 
    strNote = txtNotes.Text
 
    Set objMail = Application.ActiveExplorer.Selection.Item(1)
    Set objNote = Application.CreateItem(olNoteItem)
 
    objNote.Body = strNote
    objNote.Save
    objMail.Attachments.Add objNote
    objMail.Save
    objNote.Delete
    Unload Me
End Sub

Private Sub btnCancel_Click()
    Unload Me
End Sub

11. Vėliau į nenaudojamą modulį įdėkite toliau pateiktą VBA kodą.

Sub AddNote()
    frmAddNote.Show
End Sub

12. Galiausiai eikite į „Failas“ > „Parinktys“ > „Tinkinti juostelę“, kad pridėtumėte šią makrokomandą prie juostos.
13. Dabar galite pabandyti. Pasirinkite el. laišką ir spustelėkite naują mygtuką „Pridėti pastabą“ juostelėje.
14. Iššokančiajame dialogo lange galite įvesti pastabą ir spustelėti „Gerai“.
15. Iš karto prie pasirinkto el. pašto bus pridėta nauja pastaba.

Redaguokite arba ištrinkite esamas „Outlook“ el. laiškų pastabas

Kartais galbūt norėsite redaguoti arba ištrinti bet kokias esamas pastabas el. laiške. Galite atlikti toliau nurodytus veiksmus.

1. Pirmiausia sukurkite kitą vartotojo formą ir pavadinkite ją „frmEditNote“ ir pakeiskite jos antraštę į „Redaguoti pastabą“.
2. Tada į formą įterpkite naują teksto laukelį ir pakeiskite jo pavadinimą į „txtNotes“.
3. Tada pridėkite du komandų mygtukus - „Gerai“ ir „Atšaukti“.
4. Po to dešiniuoju pelės mygtuku spustelėkite „frmEditNote“ ir pasirinkite „View Code“.
5. Naujame „frmEditNote“ kodo puslapyje įdėkite šį kodą.

Private Sub UserForm_Initialize()
    Dim objAttachNote As Outlook.Attachment
    Dim objTempNote As Outlook.NoteItem

    Set objAttachNote = ActiveExplorer.AttachmentSelection.Item(1)
    Set objMail = objAttachNote.Parent
 
    If Right(objAttachNote.FileName, 3) = "msg" Then
       strTempFolder = Environ("Temp")
       strFilePath = strTempFolder & "\" & objAttachNote.FileName
       objAttachNote.SaveAsFile strFilePath
    End If
 
    Set objTempNote = Session.OpenSharedItem(strFilePath)
    txtNotes.Text = objTempNote.Body

    objTempNote.Close olDiscard
End Sub

Private Sub btnOK_Click()
    Dim strNote As String
    Dim objMail As Outlook.MailItem
    Dim objAttachNote As Outlook.Attachment
    Dim objNewNote As Outlook.NoteItem
 
    strNote = txtNotes.Text
 
    Set objNewNote = Application.CreateItem(olNoteItem)
    Set objMail = Application.ActiveExplorer.Selection.Item(1)
    Set objAttachNote = ActiveExplorer.AttachmentSelection.Item(1)
    objAttachNote.Delete

    objNewNote.Body = strNote
    objNewNote.Save
    objMail.Attachments.Add objNewNote
    objMail.Save
    objNewNote.Delete
    Unload Me
End Sub

Private Sub btnCancel_Click()
    Unload Me
End Sub

6. Po to atidarykite modulį ir nukopijuokite į jį VBA kodą.

Sub EditNote()
    frmEditNote.Show
End Sub

Sub DeleteNotes()
    Dim objSelectedAttachments As Outlook.AttachmentSelection
    Dim objAttachment As Outlook.Attachment
    Dim objMail As Outlook.MailItem
 
    Set objSelectedAttachments = Application.ActiveExplorer.AttachmentSelection
 
    For Each objAttachment In objSelectedAttachments
        If Right(objAttachment.FileName, 3) = "msg" Then
           objAttachment.Delete
        End If
    Next
 
    Set objMail = Application.ActiveExplorer.Selection.Item(1)
    objMail.Save
End Sub

7. Galiausiai prie juostos galite pridėti makrokomandas „EditNote“ ir „DeleteNotes“.
8. Galiausiai, spustelėję „Gerai“ ir grįžę į pagrindinį langą, galite pabandyti redaguoti pastabą.

• Pasirinkite pastabą ir spustelėkite mygtuką „Redaguoti pastabą“.
• Tada pasirodys naujas dialogo langas, kuriame galėsite redaguoti pasirinktą užrašą.
• Po redagavimo spustelėkite „Gerai“. Pastaba bus atnaujinta.

9. Be to, galite pabandyti ištrinti visas pastabas.

• Pasirinkite užrašą, kurį norite ištrinti.
• Juostelėje spustelėkite mygtuką „Ištrinti pastabas“.
• Ši pastaba bus ištrinta iš karto.

Apsaugokite „Outlook“ nuo duomenų praradimo

Ar ieškote galingo sprendimo blokuoti „Outlook“ duomenų praradimą? Tiesą sakant, jei reguliariai kuriate „Outlook“ duomenų atsargines kopijas, galite lengvai išvengti PST duomenų praradimo. Pavyzdžiui, net jei PST bus sugadintas, vis tiek galite lengvai susigrąžinti PST duomenis iš atsarginės PST failo kopijos kaip vėjas.

Autoriaus įvadas:

Shirley Zhang yra duomenų atkūrimo ekspertė DataNumen, Inc., kuri yra pasaulyje duomenų atkūrimo technologijų lyderė, įskaitant atkurti sql ir „Outlook“ taisymo programinės įrangos produktai. Norėdami gauti daugiau informacijos, apsilankykite WWW.datanumen.com