Kaip paketu eksportuoti visus pokalbio el. laiškus kaip tekstinius failus per „Outlook VBA“.

Kartais galbūt norėsite grupiniu būdu užfiksuoti visus konkretaus pokalbio el. laiškus ir eksportuoti juos į vietinį aplanką kaip tekstinius failus. Šis straipsnis išmokys jus greitai gauti.

Dėl tam tikrų priežasčių gali tekti eksportuoti visus tam tikro pokalbio el. laiškus į vietinį diską. Jei tai padarysite rankiniu būdu, ty po vieną surasti ir išsaugoti, tai bus varginanti ir varginanti užduotis. Todėl geriau ieškoti kito greitesnio metodo, pavyzdžiui, toliau pateikto. Jis naudos VBA kodo fragmentą, kad jį gautų be prakaito.

Paketas eksportuokite visus pokalbio laiškus kaip tekstinius failus

1. Pačioje pradžioje paleiskite „Outlook“ programą.
2. Tada paspauskite „Alt + F11“ klavišų mygtukus, kad pasiektumėte „Outlook VBA“ redaktorių.
3. Vėliau naujame lange turite atidaryti nenaudojamą modulį arba tiesiogiai įterpti naują modulį.
4. Tada turėtumėte nukopijuoti ir įklijuoti šiuos VBA kodus į šį modulį.

Public strFilePath, strFileName As String

Sub ExportMailsInConversationAsTXT()
    Dim objSelectedMail As Outlook.MailItem
    Dim objConversation As Outlook.Conversation
    Dim objMail As Outlook.MailItem

    Set objSelectedMail = ActiveExplorer.Selection.Item(1)
    Set objConversation = objSelectedMail.GetConversation
 
    If Not (objConversation Is Nothing) Then
       'Get all root items in this conversation
       For Each objMail In objConversation.GetRootItems
 
          strFileName = objMail.Subject
 
          'Remove the unsupported characters in email subject
          strFileName = Replace(strFileName, "/", " ")
          strFileName = Replace(strFileName, "\", " ")
          strFileName = Replace(strFileName, ":", "")
          strFileName = Replace(strFileName, "?", " ")
          strFileName = Replace(strFileName, Chr(34), " ")

          strFileName = Format(objMail.ReceivedTime, "YYYY-MM-DD") & "_" & strFileName & ".txt"
 
         'Export as Text files
         'Change "E:\" to other local folder path as per your needs
         strFilePath = "E:\" & strFileName
         objMail.SaveAs strFilePath, OLTXT

         'Process all children as well
         Call ProcessChildren(objMail, objConversation)
      Next
   End If

   MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessChildren(objCurMail As Outlook.MailItem, objCurConversation As Outlook.Conversation)
    Dim objItems As Outlook.SimpleItems
    Dim objItem As Outlook.MailItem
 
    Set objItems = objCurConversation.GetChildren(objCurMail)

    If objItems.Count > 0 Then
       For Each objItem In objItems
 
           strFileName = objItem.Subject
 
           strFileName = Replace(strFileName, "/", " ")
           strFileName = Replace(strFileName, "\", " ")
           strFileName = Replace(strFileName, ":", "")
           strFileName = Replace(strFileName, "?", " ")
           strFileName = Replace(strFileName, Chr(34), " ")
 
           strFileName = Format(objItem.ReceivedTime, "yyyy-mm-dd") & "_" & strFileName & ".txt"
 
           strFilePath = "E:\" & strFileName
           objItem.SaveAs strFilePath, OLTXT
 
           'Process all children recursively
           Call ProcessChildren(objItem, objCurConversation)
       Next
    End If
End Sub

5. Po to galite pridėti naują VBA projektą prie greitosios prieigos įrankių juostos, kaip įprasta.
6. Vėliau įsitikinkite, kad Outlook makrokomandos saugos lygis yra žemas.
7. Galiausiai galite pabandyti.

• Pirmiausia pasirinkite el.
• Tada greitosios prieigos įrankių juostoje spustelėkite naujos makrokomandos mygtuką.
• Kai gausite pranešimą „Complete“, galite atidaryti iš anksto nustatytą vietinį aplanką, kuriame matysite el. laiškus „TXT“ formatu.

Patarimai, kaip atkurti PST duomenis po korupcijos

Dažnai programoje „Outlook“ galite susidurti su įvairiomis „Outlook“ klaidomis, kai kurios iš jų gali būti labai rimtos, todėl jos gali tiesiogiai sukelti PST sugadinimą. Tuo metu reikia imtis veiksmų remontas PST failą, kad surastumėte vertingus duomenis. Tokiu atveju galite tiesiog grįžti prie patikimo ir gerai patikrinto įrankio, pvz DataNumen Outlook Repair.

Autoriaus įvadas:

Shirley Zhang yra duomenų atkūrimo ekspertė DataNumen, Inc., kuri yra pasaulyje duomenų atkūrimo technologijų lyderė, įskaitant atsigauti sql server ir „Outlook“ taisymo programinės įrangos produktai. Norėdami gauti daugiau informacijos, apsilankykite WWW.datanumen.com