Kaip automatiškai nustatyti „Outlook“ prisijungus arba neprisijungus pagal jūsų darbo valandas

Kai kurie vartotojai norėtų, kad „Outlook“ automatiškai perjungtų būseną prisijungus ir neprisijungus pagal jų darbo valandas. Taigi, šiame straipsnyje mes pasidalinsime su jumis greitu metodu.

Tiesą sakant, labai lengva nustatyti „Outlook“ prisijungus arba neprisijungus. Norėdami paversti „Outlook“ būseną neprisijungus, galite tiesiog pereiti į skirtuką „Siųsti / gauti“ ir paspausti mygtuką „Dirbti neprisijungus“. Ir norėdami grįžti į prisijungimo būseną, tiesiog dar kartą paspauskite šį mygtuką. Tačiau kai kurie vartotojai tikisi, kad „Outlook“ gali automatiškai persijungti į neprisijungus būseną, kai baigsis darbo laikas, ir grįžti prie interneto darbo valandomis. Nors „Outlook“ neteikia tokios funkcijos, vis tiek galite naudoti šį VBA kodą, kad tai pasiektumėte.

Automatiškai nustatykite „Outlook“ prisijungus arba neprisijungus pagal savo darbo valandas

1. Pačioje pradžioje paleiskite „Outlook“ programą.
2. Tada, gavę prieigą prie „Outlook“, turėtumėte atidaryti aplanką „Tasks“.
3. Tada turėtumėte sukurti kasdien pasikartojantį užduoties elementą.

• Juostelėje spustelėkite mygtuką „Nauja užduotis“.
• Tada užduoties temos eilutėje įveskite „Neprisijungęs“.
• Tada spustelėkite mygtuką „Pakartojimas“, esantį skirtuke „Užduotis“.
• Iššokančiajame dialogo lange pasirinkite „Kasdienis“ pasikartojimo šablonas, įgalinkite „Nėra pabaigos datos“ ir paspauskite „Gerai“.
• Tada turėtumėte įjungti priminimą „5:00“.
• Galiausiai paspauskite mygtuką „Išsaugoti ir uždaryti“.

4. Vėliau turite sukurti kitą kasdien pasikartojančią užduotį, pavadintą „Online“ ir įjungti priminimą „8:00 AM“, parodytą toliau pateiktame paveikslėlyje:
5. Po to pagrindiniame „Outlook“ lange paspauskite klavišų kombinaciją „Alt + F11“.
6. Tada gausite prieigą prie „Outlook VBA“ rengyklės, kurioje turėsite rasti ir atidaryti projektą „ThisOutlookSession“.
7. Vėliau į šį projektą nukopijuokite šį VBA kodą.

Dim objNameSpace As Outlook.NameSpace

'Set Online/Offline Status on Outlook Startup
Private Sub Application_Startup()
    Set objNameSpace = Application.GetNamespace("MAPI")
 
    'If now is before 8:00 AM or after 5:00 PM on Outlook startup
    If Now() < DateSerial(Year(Now), Month(Now), Day(Now)) + #8:00:00 AM# Or Now() > DateSerial(Year(Now), Month(Now), Day(Now)) + #5:00:00 PM# Then
 
       'If Outlook is online
       If objNameSpace.Offline = False Then
          'set it offline
          ActiveExplorer().CommandBars.FindControl(, 5613).Execute
       End If
 
       'If now is between 8:00 AM and 5:00 PM
    Else
 
       'If Outlook is offline
       If objNameSpace.Offline = True Then
          'Set it online
          ActiveExplorer().CommandBars.FindControl(, 5613).Execute
       End If
    End If
End Sub

'Change Online/Offline Status at Specific Time
Private Sub Application_Reminder(ByVal Item As Object)
    Dim objOfflineTask As Outlook.TaskItem
    Dim objOnlineTask As Outlook.TaskItem
 
    Set objNameSpace = Application.GetNamespace("MAPI")
 
    If TypeOf Item Is TaskItem Then
       If Item.Subject = "Offline" Then
          Set objOfflineTask = Item
 
          'If Outlook is online when "Offline" task reminder alerts
          If objNameSpace.Offline = False Then
             'Set Outlook offline
             ActiveExplorer().CommandBars.FindControl(, 5613).Execute
          End If
 
          'Clear the reminder by marking task complete
          objOfflineTask.MarkComplete
 
       ElseIf Item.Subject = "Online" Then
          Set objOnlineTask = Item
 
          'If Outlook is offline when "Online" task reminder alerts
          If objNameSpace.Offline = True Then
             'Set Outlook online
             ActiveExplorer().CommandBars.FindControl(, 5613).Execute
          End If
 
          objOnlineTask.MarkComplete
 
       End If
    End If
End Sub

8. Galiausiai galite paleisti „Outlook“ iš naujo, kad suaktyvintumėte šią makrokomandą.
9. Nuo šiol jūsų „Outlook“ veiks darbo valandomis ir automatiškai persijungs į neprisijungus būseną ne darbo valandomis.

Jūsų paskutinė priemonė „Outlook“ gedimų atveju

Nors „Outlook“ gali pasigirti keliomis funkcijomis, „Outlook“ vis tiek negali apsisaugoti nuo klaidų ir žalos. Tačiau nepanikuokite. Jei imsitės pakankamai atsargumo priemonių, vis tiek galėsite veiksmingai apsaugoti savo „Outlook“ duomenis. Pavyzdžiui, turėtumėte reguliariai kurti atsargines PST failų kopijas, nes atsarginės kopijos leis jums susigrąžinti sugadintas PST duomenis. Be to, laikant galingą remonto įrankį, pvz DataNumen Outlook Repair, taip pat yra būtinybės reikalas.

Autoriaus įvadas:

Shirley Zhang yra duomenų atkūrimo ekspertė DataNumen, Inc., kuri yra pasaulyje duomenų atkūrimo technologijų lyderė, įskaitant pataisyti mdf ir „Outlook“ taisymo programinės įrangos produktai. Norėdami gauti daugiau informacijos, apsilankykite WWW.datanumen.com