Kaip automatiškai įrašyti bendrą gaunamų el. laiškų skaičių kiekvieną dieną į „Excel“ failą

Šiame straipsnyje sužinosite, kaip leisti „Outlook“ automatiškai suskaičiuoti, kiek el. laiškų gavote kiekvieną dieną, ir įrašyti skaičių į „Excel“ failą.

Daugelis vartotojų turi skaičiuoti bendrą kiekvieną dieną gautų el. laiškų skaičių. Be to, kad ateityje būtų patogiau patikrinti, daugelis yra įpratę įrašyti bendrą skaičių į „Excel“ failą. Tokiu atveju, žinoma, galite pasirinkti skaičiuoti ir įrašyti rankiniu būdu kiekvieną dieną. Tačiau tai šiek tiek vargina. Ir kartais galite pamiršti tai padaryti. Todėl turite norėti patogaus metodo, kuris gali priversti „Outlook“ tai padaryti automatiškai. Atsižvelgdami į šį reikalavimą, mes išmokysime jus naudoti VBA, kad jį įgyvendintumėte toliau.

Kiekvieną dieną automatiškai įrašykite bendrą gaunamų el. laiškų skaičių į „Excel“ failą

1. Pačioje pradžioje paleiskite „Outlook“ programą.
2. Tada pagrindiniame „Outlook“ lange paspauskite sparčiuosius klavišus „Alt + F11“.
3. Tada iššokančiajame VBA redaktoriaus lange atidarykite projektą „ThisOutlookSession“.
4. Tada nukopijuokite ir įklijuokite šiuos VBA kodus į šį projektą.

Private Sub Application_Reminder(ByVal Item As Object)
    If Item.Class = olTask And Item.Subject = "Update Email Count" Then
       Call GetAllInboxFolders
    End If
End Sub

Private Sub GetAllInboxFolders()
    Dim objInboxFolder As Outlook.Folder
    Dim strExcelFile As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nNextEmptyRow As Integer
    Dim lEmailCount As Long
 
    lEmailCount = 0
    Set objInboxFolder = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
    Call UpdateEmailCount(objInboxFolder, lEmailCount)
 
    ‘Change the path to the Excel file
    strExcelFile = "E:\Email\Email Count.xlsx"
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Open(strExcelFile)
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
 
    nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
    'Add the values into the columns
    objExcelWorksheet.Range("A" & nNextEmptyRow) = nNextEmptyRow - 1
    objExcelWorksheet.Range("B" & nNextEmptyRow) = Year(Date - 1) & "-" & Month(Date - 1) & "-" & Day(Date - 1)
    objExcelWorksheet.Range("C" & nNextEmptyRow) = lEmailCount
 
    'Fit the columns from A to C
    objExcelWorksheet.Columns("A:C").AutoFit
   
    'Save the changes and close the Excel file
    objExcelWorkbook.Close SaveChanges:=True
End Sub

Private Sub UpdateEmailCount(objFolder As Outlook.Folder, ByRef lCurEmailCount As Long)
    Dim objItems As Outlook.Items
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim strDay As String
    Dim strReceivedDate As String
    Dim lEmailCount As Long
    Dim objSubFolder As Outlook.Folder
 
    Set objItems = objFolder.Items
 
    objItems.SetColumns ("ReceivedTime")
    strDay = Year(Date - 1) & "-" & Month(Date - 1) & "-" & Day(Date - 1)
 
    For Each objItem In objItems
        If objItem.Class = olMail Then
           Set objMail = objItem
           strReceivedDate = Year(objMail.ReceivedTime) & "-" & Month(objMail.ReceivedTime) & "-" & Day(objMail.ReceivedTime)
           If strReceivedDate = strDay Then
              lCurEmailCount = lCurEmailCount + 1
           End If
        End If
    Next
 
    'Process the subfolders in the folder recursively
    If (objFolder.Folders.Count > 0) Then
       For Each objSubFolder In objFolder.Folders
           Call UpdateEmailCount(objSubFolder, lCurEmailCount)
       Next
    End If
End Sub

5. Tada pasirašykite šį kodą ir pakeiskite „Outlook“ makrokomandos nustatymus, kad leistų pasirašyti makrokomandas.
6. Po to turite sukurti kasdien pasikartojančią užduotį.

• Pirmiausia užduočių srityje spustelėkite mygtuką „Nauja užduotis“.
• Atsidariusiame lange Nauja užduotis spustelėkite mygtuką „Pakartojimas“.
• Tada kitame dialogo lange pasirinkite „Kasdien“, „Kas 1 dieną“ ir „Nėra pabaigos datos“ ir galiausiai paspauskite „Gerai“.
• Vėliau pakeiskite užduoties temą ir priminimą pagal savo poreikius.
• Galiausiai spustelėkite mygtuką „Išsaugoti ir uždaryti“.

7. Nuo šiol kiekvieną kartą, kai gausite šios užduoties priminimo įspėjimus, „Outlook“ automatiškai skaičiuos vakar gautus el. laiškus ir įrašys numerį į „Excel“ failą, kaip parodyta toliau pateiktoje ekrano kopijoje:

Pabėgkite nuo nuolatinio PST duomenų praradimo

Niekas nenori susitaikyti su nuolatiniu PST duomenų praradimu. Tačiau „Outlook PST“ failas gali būti sugadintas. Todėl turėtumėte imtis pakankamai atsargumo priemonių, pvz., sukurti nuoseklią ir naujausią PST duomenų atsarginę kopiją ir išlaikyti galingą PST atkūrimas įrankis šalia, pvz DataNumen Outlook Repair.

Autoriaus įvadas:

Shirley Zhang yra duomenų atkūrimo ekspertė DataNumen, Inc., kuri yra pasaulyje duomenų atkūrimo technologijų lyderė, įskaitant sql remontas ir „Outlook“ taisymo programinės įrangos produktai. Norėdami gauti daugiau informacijos, apsilankykite WWW.datanumen.com