Kaip automatiškai išjungti hipersaitus gaunamuose Outlook el. laiškuose iš nežinomų siuntėjų

Norėdami blokuoti kenkėjiškas nuorodas, geriau sukonfigūruokite „Outlook“, kad automatiškai išjungtų hipersaitus gaunamuose el. laiškuose iš nežinomų siuntėjų. Šiame straipsnyje bus atskleista dalis VBA kodų, kurie gali padėti jums jį gauti kaip kamštelį.

Daugelis vartotojų skundėsi, kad el. paštu platinami virusai užpuolė jų Outlook failą. Dažniausiai taip yra todėl, kad jie lengvai pasitiki tais el. laiškais iš nežinomų siuntėjų. Taigi jie atsisiunčia arba spusteli laiškuose esančias hipersaitus. Dabar mes pasidalinsime metodu. Jis gali leisti „Outlook“ automatiškai išjungti gaunamų el. laiškų iš nežinomų siuntėjų nuorodas. Jei turite tokių poreikių, skaitykite toliau, kad gautumėte daugiau informacijos.

Automatiškai išjunkite hipersaitus gaunamuose el. laiškuose iš nežinomų siuntėjų

1. Norėdami pradėti, „Outlook“ programoje eikite į VBA redaktorių paspausdami „Alt + F11“.
2. Toliau naujame ekrane pridėkite objektą „MS VBScript Regular Expressions“, kaip nurodyta įraše „Kaip pridėti objektų bibliotekos nuorodą VBA".
3. Tada nukopijuokite ir įklijuokite šį kodą į projektą „ThisOutlookSession“.

Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

'Occurs when new mail arrives in your Inbox
Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objMail As MailItem
    Dim objContacts As Outlook.Items
    Dim strFilter As String
    Dim objFoundContact As Outlook.ContactItem
    Dim bUnknownSender As Boolean
    Dim objRegExp As Object
    Dim objFoundResults As Object
    Dim i, n As Long
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'Check if the sender is in your default Contact folder
       Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items
       For i = 1 To 3
           strFilter = "[Email" & i & "Address] = " & objMail.SenderEmailAddress
           Set objFoundContact = objContacts.Find(strFilter)
           If Not (objFoundContact Is Nothing) Then
              bUnknownSender = False
              Exit For
           End If
       Next
       If objFoundContact Is Nothing Then
          bUnknownSender = True
       End If
 
       'If the sender is unknown
       If bUnknownSender = True Then
          'Find the urls within "<a href=" tags in HTMLbody of Mail
          Set objRegExp = CreateObject("vbscript.RegExp")
          With objRegExp
               .Pattern = "<?href\s*=\s*[""'].+?[""'][^>]*?"
               .IgnoreCase = True
               .Global = True
          End With
 
          If objRegExp.Test(objMail.HTMLBody) Then
             Set objFoundResults = objRegExp.Execute(objMail.HTMLBody)
             For n = 1 To objFoundResults.Count
                 'Disable the hyperlinks in HTMLbody
                 objMail.HTMLBody = Replace(objMail.HTMLBody, objFoundResults.Item(n - 1).Value, "")
             Next
          End If
 
          'Save the mail
          objMail.Save
       End If
    End If
End Sub

4. Po to aktyvuokite šią makrokomandą paleisdami „Outlook“ iš naujo arba paspausdami „F5“ klavišą „Application_Startup“ subrutinoje.
5. Nuo tada kiekvieną kartą, kai iš siuntėjo gautas el. laiškas, kuris nėra saugomas numatytajame kontaktų aplanke, patenka į gautuosius, „Outlook“ automatiškai išjungs jame esančius hipersaitus.

Keli „Outlook“ apsaugos būtini dalykai

Kadangi „Outlook“ gali būti pažeista, „Outlook“ failą apsaugoti gana sunku. Čia išvardinsime keletą dalykų, kuriuos būtina turėti naudojant „Outlook“ duomenų apsaugą. Visų pirma, jūs turite reguliariai kurti atsargines „Outlook“ duomenų kopijas. Be to, labai svarbu saugotis visų galimų pavojų, pvz., kenkėjiškų priedų ar hipersaitų. Paskutinis, bet ne mažiau svarbus dalykas – iš anksto turėtumėte paruošti galingą „Outlook“ taisymo įrankį, pvz DataNumen Outlook Repair. Tai tikrai pravers, kai to prireiks remontas PST failą, bet gautųjų taisymo įrankis sugenda.

Autoriaus įvadas:

Shirley Zhang yra duomenų atkūrimo ekspertė DataNumen, Inc., kuri yra pasaulyje duomenų atkūrimo technologijų lyderė, įskaitant sugadintas mdf ir „Outlook“ taisymo programinės įrangos produktai. Norėdami gauti daugiau informacijos, apsilankykite WWW.datanumen.com