Kaip automatiškai sukurti naują susitikimą, kai el. laiškas pažymėtas „Outlook“.

Kai kurie žmonės nori automatiškai arba greitai sukurti naują "Outlook" susitikimą, kai pažymi el. laišką. Šiame straipsnyje bus pristatytas būdas tai įgyvendinti naudojant „Outlook VBA“.

Kartais galiu gauti el. laišką, kuriame minimas susitikimas ar susitikimas. Tačiau tai tik el. laiškas, o ne įprastas susitikimo elementas programoje „Outlook“. Tokiu atveju turiu sukurti naują susitikimą savo Outlook kalendoriuje rankiniu būdu. Tai šiek tiek varginantis. Taigi norėčiau, kad „Outlook“ galėtų automatiškai sukurti naują susitikimą. Nepaisant to, „Outlook“ neturi vietinio palaikymo, kad galėtume automatiškai sukurti naują susitikimą, kai pažymime el. laišką. Todėl, norėdamas tai pasiekti, renkuosi pasinaudoti Outlook VBA. Čia pateikiami išsamūs VBA kodai ir veiksmai.

Automatiškai sukurkite naują susitikimą, kai el. paštas pažymėtas

1. Visų pirma, pereikite į skirtuką „Kūrėjas“ ir paspauskite „Visual Basic“ mygtuką grupėje „Kodas“.
2. Tada naujame lange „Microsoft Visual Basic for Applications“ turite du kartus spustelėti „ThisOutlookSession“, kad atidarytumėte šį projektą.
3. Tada nukopijuokite ir įklijuokite į jį šiuos VBA kodus.

Public WithEvents olItems As Outlook.Items

Private Sub Application_Startup()
    Set olItems = Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub olItems_ItemChange(ByVal Item As Object)
    Dim oAppt As AppointmentItem
    Dim strMsg As String
    Dim nRes As Integer
 
    On Error Resume Next
 
    If TypeName(Item) = "MailItem" And Item.IsMarkedAsTask = True Then
       strMsg = "Do you want to create a new appointment"
       nRes = MsgBox(strMsg, vbYesNo + vbQuestion, "Confirm Creating Appointment")
       If nRes = vbYes Then
          Set oAppt = Application.CreateItem(olAppointmentItem)
          With oAppt
               .Subject = "New Appt: " & Item.Subject
               .Location = InputBox("Enter the Location, please.")
               'Type the concrete time, such as "12/29/2015 15:30"
               .Start = InputBox("Enter a specific time (format: MM/DD/YYYY hh:mm), please.")
               .Duration = 120
               .Body = "New Appointment: " & vbCrLf & vbCrLf & Item.Body
               .Attachments.Add Item
               .ReminderSet = True
               .ReminderMinutesBeforeStart = 30
               'Use ".Save" to directly save the new appointment
               .Display
          End With
       End If
 
      'To clear the flag on the email
      'If you want to keep email flagged, remove the following 4 lines
       With Item
            .ClearTaskFlag
            .Save
       End With
    End If
End Sub

4. Vėliau turėtumėte naudoti „Skaitmeninį VBA projektų sertifikatą“, kad sukurtumėte naują sertifikatą ir pasirašytumėte dabartinį „ThisOutlookSession“ projektą.
5. Po to galite išeiti iš „Visual Basic“ lango ir pakeisti makrokomandos nustatymus, kad būtų galima naudoti tik skaitmeniniu būdu pasirašytas makrokomandas.
6. Galų gale galite pabandyti.

• Pirmiausia pateikite el. laišką ir spustelėkite piktogramą „Vėliava“. Gausite raginimą, pavyzdžiui, šią ekrano kopiją:
• Pasirinkę „Taip“, turėsite nurodyti vietą ir paspausti mygtuką „Gerai“.
• Tada reikia nurodyti susitikimo laiką.
• Galiausiai, spustelėjus „Gerai“, atsidarys naujas susitikimas, parodytas toliau pateiktame paveikslėlyje:

Pastabos:

1. Šiuose VBA koduose priminimas pagal numatytuosius nustatymus nustatytas į 30 minučių. Jį galite pakeisti koduose savo nuožiūra.
2. Kodai nustato susitikimo trukmę iki 120 minučių, ty 2 valandas. Galite pakeisti eilutę „.Duration = 120“ pagal savo poreikius.
3. Jei nenurodėte konkretaus laiko, naujam susitikimui pagal numatytuosius nustatymus bus nustatyta dabartinė data ir laikas.
4. Galite pridėti eilutę „.Išsaugoti“, kad įrašytumėte susitikimą tiesiogiai.

Atsikratykite „Outlook“ problemų

Yra žinoma, kad „Outlook“ gali patirti įvairių problemų. Blogiausia situacija turi būti „Outlook“ pažeidimai. Jei jūsų „Outlook“ failas sugadintas ir turite atsarginę kopiją, galite lengvai atkurti sugadinti Outlook duomenys iš atsarginių kopijų. Bet jei neturite atsarginės kopijos, turėsite pataisyti sugadintą „Outlook“ failą. Tokiu atveju galite naudoti įtaisytąjį taisymo įrankį Scapst.exe arba labiau patyrusį įrankį, pvz., DataNumen Outlook Repair.

Autoriaus įvadas:

Shirley Zhang yra duomenų atkūrimo ekspertė DataNumen, Inc., kuri yra pasaulyje duomenų atkūrimo technologijų lyderė, įskaitant remontas SQL Server mdf duomenų bazės problema ir „Outlook“ taisymo programinės įrangos produktai. Norėdami gauti daugiau informacijos, apsilankykite WWW.datanumen.com