Kaip automatiškai suskaičiuoti dalyvius prieš išsiunčiant kvietimą į susitikimą „Outlook“.

Šiame straipsnyje sužinosite, kaip naudoti „Outlook VBA“, kad prieš išsiunčiant kvietimą į susitikimą būtų automatiškai apskaičiuotas dalyvių skaičius. 

Panašiai kaip suskaičiuojant gavėjus prieš siunčiant el. laišką, kai kurie vartotojai taip pat nori suskaičiuoti dalyvius prieš siųsdami kvietimą į susitikimą. Kaip įprasta, šio metodo tikslas – įvertinti bendrą siūlomo susitikimo kainą ir tada nuspręsti, ar siųsti tokį kvietimą į susitikimą dalyviams. Be to, kadangi „Outlook“ leidžia vartotojams nustatyti dalyvių skaičių kaip privalomą arba neprivalomą, kai kurie norėtų suskaičiuoti dalyvius pagal skirtingus tipus. Ir negalėtų būti geriau, jei būtų galima įtraukti susitikimo išteklius ir trukmę. Nors „Outlook“ neturi tokios tiesioginės funkcijos, vis tiek galite naudoti VBA kodą, kad tai įgyvendintumėte.

Prieš siųsdami kvietimą į susitikimą, automatiškai suskaičiuokite dalyvius

1. Norėdami pradėti, paleiskite „Outlook“ programą.
2. Tada pagrindiniame „Outlook“ lange paspauskite „Alt + F11“ sparčiuosius klavišus.
3. Tada sėkmingai įeisite į Outlook VBA redaktorių. Dabar jums reikia rasti ir atidaryti „ThisOutlookSession“ projektą.
4. Tada nukopijuokite ir įklijuokite šiuos VBA kodus į šį projektą.

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
    Dim objMeetingInvitation As Outlook.MeetingItem
    Dim objMeeting As Outlook.AppointmentItem
    Dim objAttendees As Outlook.Recipients
    Dim objAttendee As Outlook.recipient
    Dim lRequiredAttendeeCount, lOptionalAttendeeCount, lResourceCount As Long
    Dim strMsg As String
    Dim nPrompt As Integer
 
    If TypeOf Item Is MeetingItem Then
       Set objMeetingInvitation = Item
       Set objMeeting = objMeetingInvitation.GetAssociatedAppointment(True)
       Set objAttendees = objMeetingInvitation.Recipients
    End If
 
    lRequiredAttendeeCount = 0
    lOptionalAttendeeCount = 0
    lResourceCount = 0
 
    'Count the required & optional attendees and resources, etc.
    For Each objAttendee In objAttendees
         If objAttendee.Type = olRequired Then
            lRequiredAttendeeCount = lRequiredAttendeeCount + 1
         ElseIf objAttendee.Type = olOptional Then
            lOptionalAttendeeCount = lOptionalAttendeeCount + 1
         ElseIf objAttendee.Type = olResource Then
            lResourceCount = lResourceCount + 1
         End If
    Next
 
    'Double check the meeting invitation details
    strMsg = "Meeting Details:" & vbCrLf & vbCrLf & _
     "Required Attendees: " & lRequiredAttendeeCount & vbCrLf & _
     "Optional Attendees: " & lOptionalAttendeeCount & vbCrLf & _
     "Resources: " & lResourceCount & vbCrLf & _
     "Duration: " & GetDuration(objMeeting) & vbCrLf & vbCrLf & _
     "Are you sure to send this meeting invitation?"
 
    nPrompt = MsgBox(strMsg, vbExclamation + vbYesNo, "Double Check Meeting Invitation")
 
    If nPrompt = vbYes Then
       Cancel = False
    Else
       Cancel = True
    End If
End Sub

Function GetDuration(objCurMeeting As AppointmentItem) As String
    'Convert minute to hour
    If objCurMeeting.Duration > 60 Then
       GetDuration = Round(objCurMeeting.Duration / 60, 1) & " hours"
    ElseIf objCurMeeting.Duration = 60 Then
       GetDuration = Round(objCurMeeting.Duration / 60, 1) & " hour"
    ElseIf objCurMeeting.Duration < 60 Then
       GetDuration = objCurMeeting.Duration & " mins"
    End If
End Function

5. Po to turite pasirašyti šį kodą.
6. Vėliau įsitikinkite, kad jūsų „Outlook“ leidžia skaitmeniniu būdu pasirašytas makrokomandas.
7. Nuo šiol kiekvieną kartą, kai spustelėsite mygtuką „Siųsti“ susitikimo kvietimuose, gausite pranešimą, kuriame rodomas dalyvių skaičius, ištekliai ir trukmė, pvz., toliau pateiktame paveikslėlyje:

Lanksčiai susidorokite su varginančia „Outlook“ korupcija

Galbūt kada nors anksčiau susidūrėte su „Outlook“ problemomis, tokiomis kaip užšalimas, įvairūs klaidų pranešimai ir pan. Laimei, „Outlook“ yra iš anksto įdiegtas su gautųjų taisymo įrankiu, vadinamu kaip scanpst, kuris gali išspręsti nedidelius klausimus. Bet jei problema rimta, turėsite vėl naudoti specializuotą įrankį, pvz DataNumen Outlook Repair.

Autoriaus įvadas:

Shirley Zhang yra duomenų atkūrimo ekspertė DataNumen, Inc., kuri yra pasaulyje duomenų atkūrimo technologijų lyderė, įskaitant sugadintas mdf ir „Outlook“ taisymo programinės įrangos produktai. Norėdami gauti daugiau informacijos, apsilankykite WWW.datanumen.com