2 būdai, kaip spausdinti „Outlook“ užduočių sąrašus su skirtingomis kategorijomis skirtinguose puslapiuose

Jei savo „Outlook“ užduotims priskyrėte įvairias spalvų kategorijas ir dabar norite spausdinti užduočių sąrašus su skirtingomis kategorijomis skirtinguose puslapiuose, galite peržiūrėti šį straipsnį. Čia pasidalinsime 2 būdais, kaip tai gauti.

Kad galėtumėte klasifikuoti ir gerai valdyti užduotis, galbūt savo užduotims pritaikėte spalvų kategorijas. Dabar, jei norite išspausdinti savo užduočių sąrašus su skirtingomis kategorijomis skirtinguose puslapiuose, skaitykite toliau. Toliau mes jums pristatysime 2 būdus, kaip tai gauti.

1 būdas: rankiniu būdu spausdinkite užduočių sąrašus po vieną

1. Pirmiausia programoje „Outlook“ pasiekite sritį „Užduotys“.
2. Tada atidarykite aplanką Užduotis.
3. Tada paspauskite „Ctrl + E“, kad suaktyvintumėte juostelę „Ieškoti“.
4. Po to skirtuke „Ieškoti“ spustelėkite mygtuką „Kategorizuoti“.
5. Išskleidžiamajame sąraše pasirinkite spalvų kategoriją.
6. Tada sąraše liks tik užduotys su pasirinkta kategorija.
7. Dabar eikite į „Failas“ > „Spausdinti“, kad išspausdintumėte šį užduočių sąrašą.
8. Vėliau tuo pačiu būdu rankiniu būdu po vieną išspausdinkite užduočių sąrašus su kitomis spalvų kategorijomis.

2 būdas: paketinis užduočių sąrašų spausdinimas naudojant VBA

1. Pačioje pradžioje suaktyvinkite VBA redaktorių pagal „Kaip paleisti VBA kodą „Outlook“.".
2. Tada pridėkite nuorodą į „MS Excel Object Library“ pagal „Kaip pridėti objekto library Nuoroda VBA".
3. Tada nukopijuokite šį VBA kodą į modulį.

Sub PrintTaskList_SpecificColorCategory()
    Dim objTasks As Outlook.Items
    Dim objTask As Outlook.TaskItem
    Dim objDictionary As Object
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varKey As Variant
    Dim strKey As String
    Dim i As Long
    Dim bSheetFound As Boolean
    Dim nLastRow As Integer
    Dim objSheet As Excel.Worksheet
 
    Set objTasks = Application.Session.GetDefaultFolder(olFolderTasks).Items
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
     'Get All Tasks' Categories
    For Each objTask In objTasks
        arrCategory = Split(objTask.Categories, ",")
        For Each varCategory In arrCategory
            If objDictionary.Exists(Trim(varCategory)) = False Then
               objDictionary.Add Trim(varCategory), 0
            End If
        Next
    Next
 
    'Export the Tasks with Different Categories into Different Sheet in an Excel Workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelApp.Visible = True
 
    i = 0
    For Each varKey In objDictionary.Keys
        strKey = CStr(varKey)

        On Error Resume Next
        objExcelWorkbook.Sheets(strKey).Select
        bSheetFound = (Err = 0)
        On Error GoTo 0
        If bSheetFound = False Then
           i = i + 1
           If i < 4 Then
              Set objExcelWorksheet = objExcelWorkbook.Sheets(i)
           Else
              Set objExcelWorksheet = objExcelWorkbook.Sheets.Add(After:=objExcelWorkbook.Sheets(objExcelWorkbook.Sheets.Count))
           End If
           objExcelWorksheet.Name = strKey
        End If
 
        With objExcelWorksheet
             .Cells(1, 1) = strKey
             .Cells(1, 1).Font.Bold = True
             .Cells(1, 1).Font.Size = 18
             .Cells(2, 1) = "Subject"
             .Cells(2, 1).Font.Bold = True
             .Cells(2, 2) = "Start Date"
             .Cells(2, 2).Font.Bold = True
             .Cells(2, 3) = "Due Date"
             .Cells(2, 3).Font.Bold = True
        End With
 
        For Each objTask In objTasks
            If InStr(objTask.Categories, strKey) > 0 Then
               nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
               With objExcelWorksheet
                    .Range("A" & nLastRow) = objTask.Subject
                    .Range("B" & nLastRow) = objTask.startDate
                    .Range("C" & nLastRow) = objTask.DueDate
               End With
            End If
        Next
 
        objExcelWorksheet.Columns("A:C").AutoFit
    Next
 
    'Print out All Sheets in this Excel Workbook
    For Each objSheet In objExcelWorkbook.Sheets
        objSheet.PrintOut
    Next
 
    objExcelWorkbook.Close False
    objExcelApp.Quit
End Sub

4. Po to paspauskite mygtuką „F5“, kad ši makrokomanda būtų paleista iš karto.
5. Pasibaigus makrokomandai, užduočių su skirtingomis kategorijomis sąrašai bus išspausdinti skirtinguose puslapiuose, kaip parodyta toliau esančioje ekrano kopijoje.

Grąžinkite vertingus duomenis iš pažeisto PST failo

Jei jums priklauso nepasiekiamas PST failas, kitas jūsų žingsnis neabejotinai yra PST remontas. Tokiu atveju pirmiausia galite išbandyti gautųjų taisymo įrankį. Jei nepavyks, galite išbandyti kitą išorinį įrankį, pvz., DataNumen Outlook Repair. Jis gali greitai atkurti PST duomenis.

Autoriaus įvadas:

Shirley Zhang yra duomenų atkūrimo ekspertė DataNumen, Inc., kuri yra pasaulyje duomenų atkūrimo technologijų lyderė, įskaitant atkurti mdf ir „Outlook“ taisymo programinės įrangos produktai. Norėdami gauti daugiau informacijos, apsilankykite WWW.datanumen.com