2 greiti būdai ištraukti dalis iš Word dokumento

Šiame straipsnyje mes jums pasiūlysime 2 greitus ir paprastus būdus, kaip iš „Word“ dokumento ištraukti skyrius į kitą ar kelis.

Gana dažnai nutinka ištraukti turinį iš vieno dokumento į kitą. O ankstesniame straipsnyje aptarėme, kaip iš dokumento ištraukti puslapius. Išsamios informacijos rasite šiame straipsnyje: 2 greiti būdai ištraukti atskirus puslapius iš „Word“ dokumento

Šiandien parodysime, kaip išgauti pagal skyrių.    

1 būdas: ištraukite dabartinį skyrių į naują dokumentą

1. Pirmiausia, perkelkite žymeklį į tikslinę sekciją.
2. Tada paspauskite „Alt + F11“, kad iškviestumėte VBA redaktorių „Word“.
3. Tada kairiajame stulpelyje spustelėkite „Įprastas“.
4. Ir meniu juostoje spustelėkite „Įterpti“.
5. Tada išskleidžiamajame meniu pasirinkite „Modulis“.
6. Dukart spustelėkite, kad atidarytumėte naują modulį ir įklijuokite šiuos kodus:

Sub SaveCurrentSectionAsNewDoc()
  Dim strFolder As String
  Dim dlgFile As FileDialog
  Dim strNewFileName As String
  Dim objDocAdded As Document
  Dim objDoc As Document
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  ' Pick a place to store the new file.
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  strNewFileName = InputBox("Enter new file name here: ", "File Name")
 
  ' Select and copy current section range.
  objDoc.Bookmarks("\Section").Range.Select
  Selection.Copy
 
  ' Open a new document to paste the above selection.
  Set objDocAdded = Documents.Add
  Selection.Paste
 
  ' Save and close the new document.
  objDocAdded.SaveAs FileName:=strFolder & strNewFileName & ".docx"
  objDocAdded.Close
End Sub

7. Tada meniu juostoje spustelėkite „Vykdyti“ arba paspauskite „F5“.
8. Tada pasirodys langas „Naršyti“. Pasirinkite vietą, kurioje bus saugomas naujas dokumentas, ir spustelėkite „Gerai“.
9. Lauke „Failo pavadinimas“ įveskite naujo failo pavadinimą ir spustelėkite „Gerai“.

Dabar ištraukėte skyrių į naują dokumentą.

2 būdas: ištraukite kiekvieną dokumento skyrių, kad galėtumėte atskirti naujus

Tokiu būdu galite paketiniu būdu apdoroti visus dokumento skyrius. Žinoma, mums reikės ir makrokomandos.

1. Pirmiausia atidarykite tikslinį dokumentą.
2. Tada atlikite 1 metodo veiksmus, kad įdiegtumėte ir paleistumėte makrokomandą.
3. Tik šį kartą pakeiskite šią makrokomandą šia:

Sub SaveEachSectionAsADoc()
  Dim objDocAdded As Document
  Dim objDoc As Document
  Dim nSectionNum As Integer
  Dim strFolder As String

  Dim dlgFile As FileDialog
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  ' Pick a location to keep new files.
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  ' Step through each section in current document, copy and paste each to a new one.
  For nSectionNum = 1 To ActiveDocument.Sections.Count
    Selection.GoTo What:=wdGoToSection, Which:=wdGoToNext, Name:=nSectionNum
    ActiveDocument.Sections(nSectionNum).Range.Copy
 
    Set objDocAdded = Documents.Add
    Selection.Paste
 
    ' Save and close new documents.
    objDocAdded.SaveAs FileName:=strFolder & "Section " & nSectionNum & ".docx"
    objDocAdded.Close
  Next nSectionNum
End Sub

4. Vis dėlto lange „Naršyti“ pasirinkite saugyklos kelią ir spustelėkite „Gerai“.

Ištaisykite erzinančias žodžio klaidas

Naudodamiesi programa dažnai susiduriate su kai kuriomis „Word“ klaidomis. Tai gali erzinti, turime tam skirti laiko atgauti žodį kuo greičiau. Nes kuo ilgiau atidėliosime, tuo didesnis duomenų praradimas gali būti. Todėl rekomenduojama iš anksto pasirūpinti remonto įmone.

Autoriaus įvadas:

Vera Chen yra duomenų atkūrimo ekspertė DataNumen, Inc., kuri yra pasaulyje duomenų atkūrimo technologijų lyderė, įskaitant sugadintas xls bei pdf programinės įrangos gaminių taisymas. Norėdami gauti daugiau informacijos, apsilankykite WWW.datanumen.com