Outlook에서 여러 Excel 통합 문서 첨부 파일을 하나의 통합 문서로 빠르게 병합하고 내보내는 방법

Outlook 솔루션 2025 년 9 월 29 일

여러 Excel 통합 문서가 첨부 된 전자 메일을 받았을 때 단일 통합 문서에있는 모든 통합 문서의 내용을 확인하려면이 문서의 방법을 사용할 수 있습니다. 여러 Excel 통합 문서 첨부 파일을 하나의 통합 문서로 내 보냅니다.

이메일에 첨부된 모든 Excel 파일을 하나의 Excel 통합 문서에서 보려면 먼저 이러한 첨부 파일을 하나의 통합 문서로 병합하고 내보내야 합니다. 하지만 수동으로 작업하는 대신 다음 방법을 사용하면 훨씬 쉽게 이 작업을 수행할 수 있습니다. 이 방법은 VBA 코드를 사용하여 이 작업을 수행하는 방법을 알려줍니다. VBA 사용 방법에 대한 자세한 내용은 "VBA 사용법" 게시글을 참조하세요.Outlook에서 VBA 코드를 실행하는 방법".

여러 Excel 통합 문서 첨부 파일을 하나의 통합 문서로 병합 및 내보내기

먼저 Outlook 애플리케이션을 실행하세요.
그런 다음 Outlook VBA 편집기에 액세스하십시오.
다음으로, 새 "Microsoft Visual Basic for Applications" 창에서 "MS Excel Object Library"를 활성화해야 합니다. 이에 대한 자세한 내용은 다음 문서를 참조하십시오.VBA에서 개체 라이브러리 참조를 추가하는 방법".
그런 다음 다음 VBA 코드를 프로젝트 또는 모듈에 복사합니다.

Sub CombineMultipleExcelWorkbookAttachmensIntoOne()
    Dim objSelectedAttachments As Outlook.AttachmentSelection
    Dim objAttachment As Outlook.Attachment
    Dim strTempFolder As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim strFile As String
    Dim objCurrentSheet As Excel.Worksheet
    Dim objCurrentBook As Excel.Workbook
    Dim objSheet As Excel.Worksheet
    Dim objFileSystem As Object
 
    On Error Resume Next
    'Create a new temp folder
    strTempFolder = "E:\Temp" & Format(Now, "yyymmddhhmmss") & "\"
    MkDir (strTempFolder)
 
    'Save selected attachments
    Set objSelectedAttachments = Outlook.Application.ActiveExplorer.AttachmentSelection
    For Each objAttachment In objSelectedAttachments
        objAttachment.SaveAsFile (strTempFolder & objAttachment.FileName)
    Next
 
    'Copy all the workbooks into a new file
    Set objExcelApp = CreateObject("Excel.Application")
    objExcelApp.Visible = True
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelWorkbook.Activate
 
    strFile = Dir(strTempFolder)
    Do While strFile <> ""
       Set objCurrentBook = objExcelApp.Workbooks.Open(strTempFolder & strFile)
       For Each objCurrentSheet In objCurrentBook.Sheets
           objCurrentSheet.Copy Before:=objExcelWorkbook.Sheets(1)
       Next
 
       objExcelApp.Workbooks(strFile).Close
       strFile = Dir()
    Loop
 
    'Remove empty sheets
    objExcelApp.DisplayAlerts = False
    For Each objSheet In objExcelWorkbook.Worksheets
        If objExcelApp.WorksheetFunction.CountA(objSheet.Cells) = 0 Then
           objSheet.Delete
        End If
    Next
    objExcelApp.DisplayAlerts = True
 
    'Delete the temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

그런 다음 창을 닫고 빠른 실행 도구 모음에 새 매크로를 추가 할 수 있습니다.
나중에 메일 목록에서 원본 이메일에 대해 설명합니다.
그런 다음 "Ctrl"을 누른 상태로 내보내려는 Excel 통합 문서 첨부 파일을 선택합니다.
다음으로 빠른 실행 도구 모음에서 매크로 버튼을 클릭합니다.
매크로가 완료되면 새 Excel 통합 문서가 표시됩니다. 이전에 선택한 Excel 통합 문서의 내용이 포함됩니다.

더 강력한 외부 복구 도구로 대체

Outlook 오류 발생 시 대부분의 사용자는 다음 방법을 사용하는 경향이 있습니다. 받은 편지함 수리 도구 애초에 시도해보십시오. 그러나 심각한 손상의 경우 많은 도움이되지 않습니다. 이 시점에서 다음과 같이 신뢰할 수 있고 경험이 풍부한 외부 도구를 사용할 수밖에 없습니다. DataNumen Outlook Repair.

저자 소개 :

Shirley Zhang은 데이터 복구 전문가입니다. DataNumen, Inc.는 다음과 같은 데이터 복구 기술 분야의 세계적 리더입니다. mdf 복구 및 전망 수리 소프트웨어 제품. 자세한 내용은 WWW.datanumen.COM