특정 슬라이드를 빠르게 첨부하는 방법 PowerPoint Outlook 이메일에 프레젠테이션

Outlook 솔루션 2025 년 9 월 29 일

특정 슬라이드를 추출하려는 경우 PowerPoint 프레젠테이션을 별도의 새 프레젠테이션에 추가하고 Outlook 이메일에 첨부하면이 문서에서 공유하는 방법을 활용할 수 있습니다.

전체를 첨부하는 대신 PowerPoint 프레젠테이션의 특정 슬라이드를 첨부하려면 일반적으로 먼저 특정 슬라이드를 새 프레젠테이션에 복사해야합니다. 너무 귀찮습니다. 따라서 여기서는 한 번에 실현할 수있는 방법을 보여 드리겠습니다.

의 특정 슬라이드 첨부 PowerPoint 이메일로 프레젠테이션

먼저 특정 항목을 엽니 다. PowerPoint 표시.
그런 다음 PowerPoint 응용 프로그램 창에서 "Alt + F11"키를 눌러 VBA 편집기에 액세스합니다.
다음으로 새 창에서 "삽입"> "모듈"을 눌러 새 모듈을 만듭니다.
그런 다음 다음 VBA 코드를 복사하여이 모듈에 붙여 넣습니다.

Sub AttachSpecificSlidesToOutlookEmail()
    Dim objActivePresetation As Presentation
    Dim objSlide As Slide
    Dim n As Long
    Dim strName As String
    Dim strTempPresetation As String
    Dim objTempPresetation As Presentation
    Dim objOutlookApp As Object
    Dim objMail As Object
 
    Set objActivePresetation = ActivePresentation
 
    For Each objSlide In objActivePresetation.Slides
        objSlide.Tags.Delete ("Selected")
    Next
 
    'Add a tag "Selected" to the selected slides
    For n = 1 To ActiveWindow.Selection.SlideRange.Count
        ActiveWindow.Selection.SlideRange(n).Tags.Add "Selected", "YES"
    Next n
 
    strName = objActivePresetation.Name
    strName = Left(strName, InStrRev(strName, ".") - 1)
    strTempPresetation = Environ("TEMP") & "\" & strName & ".pptx"
 
    'Copy the active presentation to a temp presentation
    objActivePresetation.SaveCopyAs strTempPresetation
    Set objTempPresetation = Presentations.Open(strTempPresetation)
 
    'Remove the untagged slides
    For n = objTempPresetation.Slides.Count To 1 Step -1
        If objTempPresetation.Slides(n).Tags("Selected") <> "YES" Then
           objTempPresetation.Slides(n).Delete
        End If
    Next n
 
    objTempPresetation.Save
    objTempPresetation.Close
 
    'Attach the temp presentation to a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objMail = objOutlookApp.CreateItem(olMailItem)
 
    'Change the email details as per your needs
    With objMail
         .To = "test@datanumen.com"
         .Subject = strName
         .Body = "Dear," & vbCr & vbCr & vbTab & "Specific slides are extracted and attached."
         .Attachments.Add strTempPresetation
         .Display
    End With
End Sub

그 후에 현재 창을 닫을 수 있습니다.
나중에 "파일"> "옵션"> "빠른 실행 도구 모음"으로 이동하여 빠른 실행 도구 모음에 새 매크로를 추가합니다.
마지막으로이 매크로를 시도해 볼 수 있습니다.

로tart, 추출하려는 특정 슬라이드를 선택하십시오.
그런 다음 빠른 실행 도구 모음에서 매크로 버튼을 클릭합니다.
즉시 Outlook 이메일이 표시됩니다. PowerPoint 소스 프레젠테이션에서 추출 된 프레젠테이션입니다.

효과적인 복구 도구 활용

우리 모두 알고 있듯이 Outlook에는 기본 제공 복구 유틸리티가 제공됩니다. 스캔프스트. 그러나 Outlook의 작은 결함에 간단히 대처할 수 있습니다. 당신이 직면 한 것이 심각한 피해라면 효과가 없을 것입니다. 그 시점에서 당신은 다른 강력하고 신뢰할 수있는 복구 도구로 되풀이 할 수밖에 없습니다. DataNumen Outlook Repair. 그것으로, 당신은 손상된 Outlook 파일을 구할 수 있습니다.

저자 소개 :

Shirley Zhang은 데이터 복구 전문가입니다. DataNumen, Inc.는 다음과 같은 데이터 복구 기술 분야의 세계적 리더입니다. 손상된 mdf 및 전망 수리 소프트웨어 제품. 자세한 내용은 WWW.datanumen.COM