Windows 폴더의 모든 Outlook 메시지 파일에서 첨부 파일을 빠르게 추출하는 방법

Outlook 솔루션 2025 년 9 월 29 일

Windows 폴더에 .msg 형식으로 여러 Outlook 이메일을 저장했을 수 있습니다. 나중에 이러한 파일에서 첨부 파일을 추출하려면이 문서에서 공유하는 방법을 사용할 수 있습니다.

Outlook의 이메일에서 첨부 파일을 추출하는 것은 매우 쉽습니다. 그러나 Windows 폴더에서 .msg 파일로 내 보낸 이메일은 어떻습니까? 일반적으로 Outlook에서 이러한 .msg 파일을 먼저 연 다음 첨부 파일을 하나씩 저장해야합니다. 아마도 당신은 너무 번거로울 것입니다. 따라서 이하에서는 훨씬 더 빠른 또 다른 솔루션을 알려 드리겠습니다.

Windows 폴더의 모든 Outlook 메시지 파일에서 첨부 파일 추출

우선, starOutlook 응용 프로그램을 열고 VBA 편집기를 실행하십시오.
그런 다음 "Microsoft Visual Basic for Applications"창에서 아래의 VBA 코드를 사용하지 않는 모듈에 복사합니다.

Dim strAttachmentFolder As String

Sub ExtractAttachmentsFromEmailsStoredinWindowsFolder()
    Dim objShell, objWindowsFolder As Object
 
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       'Create a new folder for saving extracted attachments
       strAttachmentFolder = "E:\Attachments-" & Format(Now, "MMDDHHMMSS") & "\"
       MkDir (strAttachmentFolder)
       Call ProcessFolders(objWindowsFolder.self.Path & "\")
       MsgBox "Completed!", vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessFolders(strFolderPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFiles As Object
    Dim objFile As Object
    Dim objItem As Object
    Dim i As Long
    Dim objSubFolder As Object

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strFolderPath)
    Set objFiles = objFolder.Files
 
    For Each objFile In objFiles
        If objFileSystem.GetExtensionName(objFile) = "msg" Then
           'Open the Outlook emails stored in Windows folder
           Set objItem = Session.OpenSharedItem(objFile.Path)

           If TypeName(objItem) = "MailItem" Then
              If objItem.Attachments.Count > 0 Then
                 'Extract attachments
                 For i = objItem.Attachments.Count To 1 Step -1
                     objItem.Attachments(i).SaveAsFile strAttachmentFolder & objItem.Attachments(i).FileName
                 Next
              End If
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubFolder In objFolder.SubFolders
           If ((objSubFolder.Attributes And 2) = 0) And ((objSubFolder.Attributes And 4) = 0) Then
              Call ProcessFolders(objSubFolder.Path)
           End If
       Next
    End If
End Sub

그 후 커서를 첫 번째 서브 루틴으로 이동하고“F5”키 버튼을 누르십시오.
그 후에 팝업 대화 상자에서 소스 Windows 폴더를 선택해야합니다.
"확인"을 클릭하면 매크로가 계속 작동합니다.
완료되면 "완료 됨"메시지가 표시됩니다.
이제 추출 된 첨부 파일을 저장하기 위해 미리 정의 된 로컬 폴더에 액세스 할 수 있습니다.

Outlook 문제를 효율적으로 해결

Outlook은 오류가 발생하기 쉬우므로 알 수없는 전자 메일에 포함 된 파일이나 링크를 절대로 신뢰하지 않는 등 Outlook 개체를 처리 할 때주의해야합니다. 그렇지 않으면 Outlook 파일이 쉽게 손상 될 수 있습니다. 이러한 상황에서는 내부 수정 도구조차도 많은 도움이되지 않습니다. 의지 할 수있는 것은 경험이 풍부한 외부 유틸리티입니다. DataNumen Outlook Repair. 그것은 수 PST 수정 쉽게 파일을 작성하십시오.

저자 소개 :

Shirley Zhang은 데이터 복구 전문가입니다. DataNumen, Inc.는 다음과 같은 데이터 복구 기술 분야의 세계적 리더입니다. 손상된 SQL 및 전망 수리 소프트웨어 제품. 자세한 내용은 WWW.datanumen.COM