PST 파일의 모든 폴더 크기 정보를 Excel 파일로 빠르게 내보내는 방법

Outlook 솔루션 2025 년 9 월 29 일

PST 파일에서 각 폴더의 크기 정보를 확인하려면이 문서에 나와있는 방법을 사용할 수 있습니다. PST 파일에있는 모든 폴더의 크기 정보를 Excel 파일로 빠르게 내 보냅니다.

PST 파일이 너무 크면 각 폴더의 크기를 확인하는 것이 좋습니다. 어느 것이 더 큰지 쉽게 파악하고 크기에 따라 적절한 보관을 수행하는 데 도움이됩니다. 일반적으로 폴더 크기를 확인하려면 폴더를 마우스 오른쪽 버튼으로 클릭 한 다음 "속성"을 선택하면됩니다. 새 팝업 대화 상자에서 "폴더 크기"버튼을 클릭 할 수 있습니다. 그러나 폴더를 많이 만든 경우에는 크기 정보를 하나씩 수동으로 확인하는 것이 상당히 번거 롭습니다. 따라서 PST 파일에있는 모든 폴더의 크기 정보를 일괄 적으로 가져 오려면 다음 VBA 코드를 사용할 수 있습니다. 모든 폴더 이름과 크기 정보를 한 번에 Excel 파일로 내 보냅니다.

PST 파일의 모든 폴더 크기 정보를 Excel 파일로 내보내기

에tar함께 Outlook 응용 프로그램을 시작하십시오.
그런 다음 "개발자"탭으로 전환하고 "Visual Basic"버튼을 클릭하거나 "Alt + F11"키를 눌러 VBA 편집기에 액세스합니다.
다음으로“Microsoft Visual Basic for Applications”창에서 사용하지 않는 모듈을 엽니 다.
그런 다음 다음 VBA 코드를 복사하여이 모듈에 붙여 넣습니다.

Dim strExcelFile As String
Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportFodlerSizetoExcel()
    Dim objSourcePST As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
    objExcelWorksheet.Cells(1, 1) = "Folder"
    objExcelWorksheet.Cells(1, 2) = "Size"
 
    'Select a source PST file
    Set objSourcePST = Outlook.Application.Session.PickFolder

    For Each objFolder In objSourcePST.Folders
        Call ProcessFolders(objFolder)
    Next
 
    'Fit the columns from A to B
    objExcelWorksheet.Columns("A:B").AutoFit
 
    strExcelFile = "E:\Outlook\" & objSourcePST.Name & " Folder Size (" & Format(Now, "yyyy-mm-dd hh-mm-ss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim objItem As Object
    Dim lCurrentFolderSize As Long
    Dim nNextEmptyRow As Integer
 
    objCurrentFolder.Items.SetColumns ("Size")
    For Each objItem In objCurrentFolder.Items
        lCurrentFolderSize = lCurrentFolderSize + objItem.Size
    Next
 
    'Convert byte to kilobyte
    'To convert to megabyte, use:
    'lCurrentFolderSize = (lCurrentFolderSize / 1024) / 1024
    lCurrentFolderSize = lCurrentFolderSize / 1024
 
    nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1

    'Add the values into the columns
    objExcelWorksheet.Range("A" & nNextEmptyRow) = objCurrentFolder.FolderPath
    objExcelWorksheet.Range("B" & nNextEmptyRow) = lCurrentFolderSize & " KB"
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder)
       Next
    End If
End Sub

그런 다음 Outlook 매크로 보안 수준을 낮음으로 설정해야합니다.
결국 시도해 볼 수 있습니다.

현재 매크로 창에서 F5 키 버튼을 누릅니다.
그런 다음 다음 이미지와 같은 PST 파일을 선택해야합니다.
원본 파일을 선택하면 Outlook에서 크기 정보를 Excel로 내보내기 시작합니다.
매크로가 완료되면 아래 스크린 샷과 같은 메시지가 나타납니다.
마지막으로 미리 정의 된 로컬 폴더에서 Excel 파일을 찾을 수 있습니다. Excel 파일은 다음과 같습니다.

잦은 PST 오류 처리

Outlook은 오류가 발생하기 쉬우므로 Outlook에서 많은 문제가 발생했을 수 있습니다. 짜증나는 PST 문제에보다 유연하게 대처하려면 다음과 같이 경험이 풍부하고 평판이 좋은 수리 유틸리티를 근처에 두는 것이 좋습니다. DataNumen Outlook Repair. 할 수있다 PST 수정 산들 바람과 같은 문제.

저자 소개 :

Shirley Zhang은 데이터 복구 전문가입니다. DataNumen, Inc.는 다음과 같은 데이터 복구 기술 분야의 세계적 리더입니다. SQL Server 회복 및 전망 수리 소프트웨어 제품. 자세한 내용은 WWW.datanumen.COM