Outlook에서 근무 시간까지 특정 전자 메일 보내기를 빠르게 지연하는 방법

Outlook 솔루션 2025 년 9 월 29 일

근무 시간 외에 특정 이메일을 보내지 못하도록해야하는 경우이 문서에 표시된 방법을 사용할 수 있습니다. 특정 이메일을 보낼 때 Outlook이 근무 시간인지 자동으로 확인하고 근무 시간까지 지연시킬 수 있습니다.

때로는 메일을 작성하고 보내는 시간이 근무 시간 내에 있지 않습니다. 이 경우 다음 근무 시간까지이 이메일 발송을 연기 할 수 있습니다. 일반적으로 기본 기능인 "Delay Delivery"를 사용하여 이러한 이메일을 지연시킬 수 있습니다. 그러나 매번 배송 시간을 지정해야합니다. 너무 귀찮습니다. 이후에는 특정 이메일을 보낼 때 근무 시간 이내인지 자동으로 확인하고 근무 시간까지 신속하게 발송을 지연시킬 수있는 VBA 코드를 공유합니다.

근무 시간까지 특정 이메일 전송을 빠르게 지연

처음에 Outlook 프로그램을 시작하십시오.
그런 다음 나타나는 Outlook 기본 화면에서 "Alt + F11"키를 누를 수 있습니다.
다음으로 Outlook VBA 편집기에 성공적으로 액세스 할 수 있습니다.
그런 다음 "ThisOutlookSession"프로젝트를 찾아서 열어야합니다.
그런 다음이 프로젝트 창에 다음 VBA 코드를 복사합니다.

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
    Dim objMail As MailItem
    Dim NewSendTime As String
    Dim bDelayMail As Boolean
    Dim nPrompt As Integer
 
    bDelayMail = True
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'Work on specific emails only
       'You can change the conditions as per your needs
       If objMail.Recipients.Item(1).Address = "boss@datanumen.com" Then
 
          Select Case Weekday(Date, vbMonday)
                 'Delay 2 days if today is Saturday
                 Case 6
                      NewSendTime = (Date + 2) & " 09:00:00"
                 'Delay 1 days if today is Saturday
                 Case 7
                      NewSendTime = (Date + 1) & " 09:00:00"
                 Case Else
                      If DatePart("h", Now) < 9 Then
                         'Delay to 9 o'clock if now is too early
                         NewSendTime = Date & " 09:00:00"
                      ElseIf DatePart("h", Now) > 18 Then
                         Select Case Weekday(Date, vbMonday)
                                'Delay 3 days if today is Friday and now is over 6 PM
                                Case 5
                                     NewSendTime = (Date + 3) & " 09:00:00"
                                'Delay to 9 o'clock if now is before 6 PM
                                Case Else
                                     NewSendTime = (Date + 1) & " 09:00:00"
                         End Select
                      Else
                         bDelayMail = False
                      End If
            End Select
 
            If bDelayMail = True And objMail.DeferredDeliveryTime = "1/1/4501" Then
               'Ask if to delay sending this email
               nPrompt = MsgBox("Outside Working Hours:" & vbCrLf & "Do you want to delay this email until " & NewSendTime & "?", vbYesNo + vbExclamation, "Delay Email")
 
               If nPrompt = vbYes Then
                  objMail.DeferredDeliveryTime = NewSendTime
               Else
                  objMail.DeferredDeliveryTime = "1/1/4501"
               End If
           End If
       End If
    End If
End Sub

나중에이 이메일에 디지털 인증서를 할당해야합니다.
그런 다음 서명 된 매크로를 허용하도록 Outlook 매크로 설정을 변경합니다.
이제부터 미리 정의 된 기준을 충족하는 이메일을 보낼 때마다 근무 시간이 아닌 경우 다음 이미지와 같은 메시지가 표시됩니다.
"예"를 선택하면 Outlook에서 근무 시간까지 발송되도록 예약합니다.

손상된 Outlook 파일 구출

Outlook은 수많은 기능으로 인해 많은 찬사를 받았습니다. 그러나 여전히 치명적인 결함이 있습니다. 즉, Outlook은 오류와 손상이 발생하기 쉽습니다. 따라서 정기적으로 Outlook 파일을 백업해야합니다. 고통스러운 Outlook 데이터 손실을 방지 할 수 있습니다. 또한 다음과 같은 강력한 수리 도구를 사용하는 것이 좋습니다. DataNumen Outlook Repair, 이는 수 수리 Outlook 몇 초 안에 문제.

저자 소개 :

Shirley Zhang은 데이터 복구 전문가입니다. DataNumen, Inc.는 다음과 같은 데이터 복구 기술 분야의 세계적 리더입니다. mdf 복구 및 전망 수리 소프트웨어 제품. 자세한 내용은 WWW.datanumen.COM