Outlook VBA로 이메일 회신 및 전달을 위해 다른 글꼴 색상을 자동으로 사용하는 방법

Outlook 솔루션 2025 년 9 월 29 일

기본적으로 Outlook에서는 답장과 전달 이메일에 서로 다른 글꼴 색상을 자동으로 적용하도록 설정할 수 없습니다. 따라서 이러한 기능이 필요한 경우, 이 글을 참고하여 효율적인 해결 방법을 알아보세요.

Outlook에서는 회신 및 전자 메일 전달에 사용되는 글꼴 만 지정할 수 있습니다. "파일"> "옵션"으로 이동할 수 있습니다. 그런 다음 "Outlook 옵션"에서 "메일"탭으로 이동하여 "편지지 및 글꼴…"버튼을 클릭합니다. 다음 창에서 "메시지 회신 또는 전달"에서 "글꼴"버튼을 볼 수 있습니다. 그것을 클릭하면 이메일 회신 및 전달을위한 특정 글꼴 색상을 설정할 수 있습니다.

그러나 많은 사용자가 이메일 회신 또는 전달에 다른 글꼴 색상을 사용하기를 원합니다. Outlook은 이에 대한 직접적인 기능을 제공하지 않지만 VBA 코드로 구현할 수 있습니다. 이제 이러한 VBA 코드를 얻으려면 계속 읽으십시오.

이메일 회신 및 전달에 다른 글꼴 색상 자동 사용

먼저 Outlook 애플리케이션을 실행하세요.
그런 다음 ""를 참조하여 VBA 편집기를 트리거합니다.Outlook에서 VBA 코드를 실행하는 방법".
다음으로“VBA에서 개체 라이브러리 참조를 추가하는 방법"MS Word 개체 라이브러리"에 대한 참조를 추가하십시오.
그런 다음 "ThisOutlookSession"프로젝트에 다음 코드를 복사합니다.

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Dim objReply As Outlook.MailItem
    Dim objReplyDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReply = objMail.Reply
    objReply.Display
    Set objReplyDoc = objReply.GetInspector.WordEditor
    objReplyDoc.Range(0, 0).Select
    Set objDocSelection = objReplyDoc.Application.Selection
    'Use "Pink" font in "Reply"
    objDocSelection.Font.ColorIndex = wdPink
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objReplyAll As Outlook.MailItem
    Dim objReplyAllDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReplyAll = objMail.ReplyAll
    objReplyAll.Display
    Set objReplyAllDoc = objReplyAll.GetInspector.WordEditor
    objReplyAllDoc.Range(0, 0).Select
    Set objDocSelection = objReplyAllDoc.Application.Selection
    'Use "Green" font in "Reply All"
    objDocSelection.Font.ColorIndex = wdGreen
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Dim objForward As Outlook.MailItem
    Dim objForwardDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objForward = objMail.Forward
    objForward.Display
    Set objForwardDoc = objForward.GetInspector.WordEditor
    objForwardDoc.Range(0, 0).Select
    Set objDocSelection = objForwardDoc.Application.Selection
    'Use "Blue" font in Forward
    objDocSelection.Font.ColorIndex = wdBlue
End Sub

그 후 Outlook을 다시 시작하여 이 매크로를 활성화하십시오.
마지막으로 시도해 볼 수 있습니다.

이메일을 선택하거나 엽니 다.
그런 다음“답장”버튼을 클릭합니다. 회신 이메일에서 본문에 몇 가지 단어를 입력 할 수 있습니다. 글꼴 색상은 분홍색이어야합니다.
또는“전체 답장”버튼을 클릭합니다. 새로운 "전체 답장"메일에서 본문에 단어를 입력합니다. 글꼴 색상은 확실히 녹색입니다.
마찬가지로 "Forward"버튼을 클릭합니다. 전달 메일에서 새 단어는 파란색으로 표시됩니다.

신뢰할 수있는 소프트웨어에 의존

이벤트의 경우 Outlook 손상대부분의 사용자는 Outlook 복구 소프트웨어를 사용하는 경향이 있습니다. 시중에는 이러한 프로그램이 많이 있으며, 무료로 제공되는 프로그램도 있습니다. 그러나 출처를 알 수 없는 프로그램은 오히려 상황을 악화시킬 수 있으므로 주의해야 합니다. 신뢰할 수 있고 경험이 풍부한 도구를 사용하는 것이 좋습니다. DataNumen Outlook Repair.

저자 소개 :

Shirley Zhang은 데이터 복구 전문가입니다. DataNumen, Inc.는 다음과 같은 데이터 복구 기술 분야의 세계적 리더입니다. 손상된 SQL 및 전망 수리 소프트웨어 제품. 자세한 내용은 WWW.datanumen.COM