VBA를 통해 Word 문서의 모든 하이퍼 링크를 일괄 적으로 유효성 검사하는 방법

워드 솔루션 2025 년 9 월 28 일

이 기사에서는 VBA를 통해 Word 문서의 모든 하이퍼링크를 신속하게 일괄 검증하는 자동 방법을 보여줍니다.

Word 문서에는 많은 하이퍼링크, 심지어 수백 개가 포함될 수 있습니다. 그중 일부는 올바른 웹페이지로 연결되지 않는 잘못된 링크입니다. 따라서 VBA를 통해 문서의 모든 링크를 빠르게 확인할 수 있는 방법을 제공하고자 합니다.

Word 매크로 설치 및 저장

먼저 "Alt+ F11"로 VBA 편집기를 엽니다.
그런 다음 "일반"프로젝트를 클릭합니다.
그런 다음 도구 모음 메뉴에서 "삽입" 탭을 클릭합니다.
그리고 메뉴에서“Module”을 선택합니다.
모듈을 두 번 클릭하여 편집 공간을 열고 다음 코드를 붙여넣습니다.

Function CheckURL(strURL As String) As Boolean
  Dim objDemand As Object
  Dim varResult As Variant
 
  On Error GoTo ErrorHandler
  Set objDemand = CreateObject("WinHttp.WinHttpRequest.5.1")
 
  With objDemand
    .Open "GET", strURL, False
    .Send
    varResult = .StatusText
  End With
 
  Set objDemand = Nothing
 
  If varResult = "OK" Then
    CheckURL = True
  Else
    CheckURL = False
  End If
 
ErrorHandler:
End Function

Sub ReturnURLCheck()
  Dim objLink As Hyperlink
  Dim strLinkText As String
  Dim strLinkAddress As String
  Dim strResult As String
  Dim nInvalidLink As Integer, nTotalLinks As Integer
  Dim objDoc As Document
 
  Application.ScreenUpdating = False
 
  Set objDoc = ActiveDocument
  nTotalLinks = objDoc.Hyperlinks.Count
  nInvalidLink = 0
 
  With objDoc
    For Each objLink In .Hyperlinks
      strLinkText = objLink.Range.Text
      strLinkAddress = objLink.Address
 
      If Not CheckURL(strLinkAddress) Then
        nInvalidLink = nInvalidLink + 1
        strResult = frmCheckURLs.txtShowResult.Text
        frmCheckURLs.txtShowResult.Text = strResult & nInvalidLink & ". Invalid Link Information:" & vbNewLine & _
                                          "Displayed Text: " & strLinkText & vbNewLine & _
                                           "Address: " & strLinkAddress & vbNewLine & vbNewLine
      End If
    Next objLink
 
    frmCheckURLs.txtTotalLinks.Text = nTotalLinks 
    frmCheckURLs.txtNumberOfInvalidLinks.Text = nInvalidLink
    frmCheckURLs.Show Modal
 
  End With
  Application.ScreenUpdating = True
End Sub

Sub HighlightInvalidLinks()
  Dim objLink As Hyperlink
  Dim strLinkAddress As String
  Dim strResult As String
  Dim objDoc As Document
 
  Set objDoc = ActiveDocument
 
  With objDoc
    For Each objLink In .Hyperlinks
      strLinkAddress = objLink.Address
 
      If Not CheckURL(strLinkAddress) Then
        objLink.Range.HighlightColorIndex = wdYellow
      End If
    Next objLink
  End With
End Sub

다음으로 "저장"을 클릭합니다.
그런 다음 매크로에 대한 버튼을 할당합니다. 자세한 내용은 다음 문서를 참조하십시오.

Word에서 매크로 및 VBA를 사용하여 붙여 넣은 텍스트의 서식을 제거하는 방법

사용자 양식 만들기

사용자 양식을 사용하면 현재 문서의 총 링크 수, 유효하지 않은 링크 수 및 자세한 내용을 명확하게 볼 수 있습니다.

먼저 도구 모음에서 "삽입"을 다시 클릭합니다. 그러나 이번에는 "UserForm"을 선택하십시오.
그런 다음 "F4"를 눌러 왼쪽 아래 모서리에 있는 "속성 창"을 엽니다. 창 크기는 조정 가능합니다.
이제 사용자 양식의 이름을 "frmCheckURLs"로 지정하십시오.
캡션을 "URL 확인"으로 설정합니다.
그런 다음 글꼴을 올바르게 설정하십시오.
다음 도구 모음에서 "도구 상자" 버튼을 클릭합니다.
이제 도구 상자에서 "레이블"을 클릭합니다. 마우스를 사용하여 사용자 양식에서 사각형 레이블을 끕니다.
레이블을 클릭하여 속성 창을 활성화합니다. 레이블 이름을 "lblInvalidURLs"로 설정하고 레이블 캡션을 "잘못된 URL:"로 설정합니다.
다음으로 레이블 캡션 텍스트에 적절한 글꼴과 전경색을 선택합니다.
도구 상자에서 "텍스트 상자"를 선택하고 사용자 양식에 텍스트 상자를 삽입합니다. 크기를 조정하십시오.
그런 다음 텍스트 상자 이름을 "txtShowResult"로 설정합니다.
글꼴과 전경색을 원하는 대로 설정합니다.
"MultiLine"을 찾아 "True"로 설정합니다.
"Scrollbars"를 찾아 세로 막대를 선택합니다.
다음으로 레이블과 텍스트 상자를 두 개 더 만듭니다.
그런 다음 첫 번째 레이블의 이름을 "lblTotalLinks"로 지정하고 캡션을 "이 문서의 총 링크 수"로 설정합니다.
두 번째 레이블 이름을 "lblNumberOfInvalidLinks"로 지정하고 캡션을 "유효하지 않은 링크 수"로 설정합니다.
첫 번째 텍스트 상자의 이름을 "txtTotalLinks"로 지정하고 두 번째 텍스트 상자의 이름을 "txtNumberOfInvalidLinks"로 지정합니다.
그런 다음 도구 상자에서 명령 단추 컨트롤을 찾습니다. 다음과 같은 두 개의 명령 버튼을 만듭니다.
첫 번째 버튼의 이름을 "cmdbtnClose"로 지정하고 캡션 텍스트를 "Close"로 지정합니다.
두 번째 버튼의 이름을 "btnCloseAndHighlightInvalidURLs"로 지정하고 캡션 텍스트를 "Close & Highlight Invalid URLs"로 지정합니다.
그런 다음 "닫기" 버튼과 "잘못된 URL 닫기 및 강조 표시" 버튼을 각각 두 번 클릭합니다. 다음과 같이 코드를 입력합니다.