하나의 Excel 통합 문서에있는 모든 워크 시트를 별도의 Outlook 전자 메일로 일괄 보내는 방법

Outlook 솔루션 2025 년 9 월 29 일

Excel 통합 문서의 모든 워크 시트를 별도의 Outlook 전자 메일로 보내려면이 문서에 소개 된 방법을 사용할 수 있습니다. 하나 하나 번거 로움없이 일괄 실감 할 수 있도록 안내 할 수 있습니다.

내 이전 p에서ost "2 Excel 워크 시트를 Outlook 이메일로 보내는 빠른 방법”, Excel 워크 시트 하나를 이메일로 보내는 두 가지 방법을 배울 수 있습니다. 한 통합 문서의 모든 워크 시트를 개별 이메일로 일괄 전송하려면 해당 페이지에 언급 된 두 가지 방법 중 하나를 사용하십시오.ost 매우 지루하고 번거로울 것입니다. 따라서 여기서는 이러한 "일괄 전송"을 빠르게 실현할 수있는 다른 방법을 소개합니다.

하나의 Excel 통합 문서에있는 모든 워크 시트를 별도의 이메일로 일괄 전송

먼저 원본 Excel 통합 문서를 열어야합니다.
그런 다음 Excel 창에 들어간 후 "Alt + F11"키 단축키를 눌러야합니다.
다음으로 "Microsoft Visual Basic for Applications"라는 다른 창이 표시됩니다.
그 안에 사용하지 않는 모듈을 열거 나 새 모듈을 삽입해야합니다.
이후에 다음 VBA 코드를이 모듈에 복사 할 수 있습니다.

Sub SendEachWorksheet_inOutlookEmail()
    Dim objWorksheet As Excel.Worksheet
    Dim objRange As Excel.Range
    Dim objTempWorkbook As Excel.Workbook
    Dim objTempWorksheet As Excel.Worksheet
    Dim strTempFolder As String
    Dim strHTMLFile As String
    Dim objHTMLFile As Object
    Dim objFileSystem As Object
    Dim objTextStream As Object
    Dim objOutlookApp As Outlook.Application
    Dim objMail As Outlook.MailItem
 
    For Each objWorksheet In ActiveWorkbook.Sheets
        Set objRange = objWorksheet.UsedRange
        objRange.Copy
 
        Set objTempWorkbook = Excel.Application.Workbooks.Add(1)
        Set objTempWorksheet = objTempWorkbook.Sheets(1)
        With objTempWorksheet.Cells(1)
             .PasteSpecial xlPasteValues
             .PasteSpecial xlPasteColumnWidths
             .PasteSpecial xlPasteFormats
        End With
 
        strTempFolder = CStr(Environ("USERPROFILE")) & "\AppData\Local\Temp"
        strHTMLFile = strTempFolder & "\Temp" & Format(Now, "yyyymmddhhmmss") & ".htm"
        Set objHTMLFile = objTempWorkbook.PublishObjects.Add(xlSourceRange, strHTMLFile, objTempWorksheet.Name, objTempWorksheet.UsedRange.Address)
        objHTMLFile.Publish (True)
 
        Set objOutlookApp = CreateObject("Outlook.Application")
        Set objMail = objOutlookApp.CreateItem(olMailItem)
 
        Set objFileSystem = CreateObject("Scripting.FileSystemObject")
        Set objTextStream = objFileSystem.OpenTextFile(strHTMLFile)
        objMail.HTMLBody = objTextStream.ReadAll
 
        'Change the email details as per your needs
        With objMail
             .To = "test@datanumen.com"
             .Subject = objWorksheet.Name
             .Display
        End With
 
        objTextStream.Close
        objTempWorkbook.Close False
        Kill strHTMLFile
    Next
End Sub

그 후 F5 키 버튼을 누르거나 도구 모음에서 "실행"아이콘을 클릭하여이 매크로를 트리거 할 수 있습니다.
이 Excel 통합 문서의 모든 워크 시트에 해당하는 전자 메일이 Outlook에 즉시 표시됩니다.
마지막으로 모든 이메일의 세부 사항을 다시 확인하고 마지막으로 "보내기"버튼을 클릭하여 이메일을 보낼 수 있습니다.

백업이없는 경우 강력한 복구 도구 적용

점점 더 많은 사용자가 데이터 백업의 중요성을 이해하고 있습니다. PST 파일을 백업했다면 PST 복구 손상 후 매우 간단합니다. 그러나 효과적이고 최신 PST 백업이없는 경우 다음과 같은 외부 PST 복구 도구를 사용할 수밖에 없습니다. DataNumen Outlook Repair. 산들 바람처럼 손상된 PST 파일을 복구 할 수 있습니다.

저자 소개 :

Shirley Zhang은 데이터 복구 전문가입니다. DataNumen, Inc.는 다음과 같은 데이터 복구 기술 분야의 세계적 리더입니다. SQL 복구 및 전망 수리 소프트웨어 제품. 자세한 내용은 WWW.datanumen.COM