매일받는 전자 메일의 총 수를 Excel 파일에 자동 기록하는 방법

Outlook 솔루션 2025 년 9 월 29 일

이 기사에서는 Outlook에서 매일받은 이메일 수를 자동으로 계산하고 그 수를 Excel 파일에 쓰는 방법을 설명합니다.

많은 사용자가 매일 수신되는 총 이메일 수를 계산해야합니다. 또한 향후보다 편리한 체크인을 위해 많은 사람들이 총 개수를 Excel 파일에 기록하는 데 익숙합니다. 이 경우에는 물론 매일 수동으로 계산하고 기록하도록 선택할 수 있습니다. 그러나 조금 번거 롭습니다. 그리고 때때로 그것을 잊을 수 있습니다. 따라서 Outlook이 자동으로 수행하도록 할 수있는 편리한 방법이 필요합니다. 이 요구 사항에 대한 응답으로 VBA를 사용하여이를 실현하는 방법을 다음과 같이 설명합니다.

매일받는 이메일의 총 개수를 Excel 파일에 자동 기록

처음에는 Outlook 응용 프로그램을 시작하십시오.
그런 다음 기본 Outlook 창에서 "Alt + F11"키 바로 가기를 누릅니다.
다음으로 팝업 VBA 편집기 창에서 "ThisOutlookSession"프로젝트를 엽니 다.
그런 다음이 프로젝트에 다음 VBA 코드를 복사하여 붙여 넣습니다.

Private Sub Application_Reminder(ByVal Item As Object)
    If Item.Class = olTask And Item.Subject = "Update Email Count" Then
       Call GetAllInboxFolders
    End If
End Sub

Private Sub GetAllInboxFolders()
    Dim objInboxFolder As Outlook.Folder
    Dim strExcelFile As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nNextEmptyRow As Integer
    Dim lEmailCount As Long
 
    lEmailCount = 0
    Set objInboxFolder = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
    Call UpdateEmailCount(objInboxFolder, lEmailCount)
 
    ‘Change the path to the Excel file
    strExcelFile = "E:\Email\Email Count.xlsx"
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Open(strExcelFile)
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
 
    nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
    'Add the values into the columns
    objExcelWorksheet.Range("A" & nNextEmptyRow) = nNextEmptyRow - 1
    objExcelWorksheet.Range("B" & nNextEmptyRow) = Year(Date - 1) & "-" & Month(Date - 1) & "-" & Day(Date - 1)
    objExcelWorksheet.Range("C" & nNextEmptyRow) = lEmailCount
 
    'Fit the columns from A to C
    objExcelWorksheet.Columns("A:C").AutoFit
   
    'Save the changes and close the Excel file
    objExcelWorkbook.Close SaveChanges:=True
End Sub

Private Sub UpdateEmailCount(objFolder As Outlook.Folder, ByRef lCurEmailCount As Long)
    Dim objItems As Outlook.Items
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim strDay As String
    Dim strReceivedDate As String
    Dim lEmailCount As Long
    Dim objSubFolder As Outlook.Folder
 
    Set objItems = objFolder.Items
 
    objItems.SetColumns ("ReceivedTime")
    strDay = Year(Date - 1) & "-" & Month(Date - 1) & "-" & Day(Date - 1)
 
    For Each objItem In objItems
        If objItem.Class = olMail Then
           Set objMail = objItem
           strReceivedDate = Year(objMail.ReceivedTime) & "-" & Month(objMail.ReceivedTime) & "-" & Day(objMail.ReceivedTime)
           If strReceivedDate = strDay Then
              lCurEmailCount = lCurEmailCount + 1
           End If
        End If
    Next
 
    'Process the subfolders in the folder recursively
    If (objFolder.Folders.Count > 0) Then
       For Each objSubFolder In objFolder.Folders
           Call UpdateEmailCount(objSubFolder, lCurEmailCount)
       Next
    End If
End Sub

다음으로이 코드에 서명하고 서명 된 매크로를 허용하도록 Outlook 매크로 설정을 변경합니다.
그런 다음 매일 반복되는 작업을 만들어야합니다.

먼저 작업 창에서 "새 작업"버튼을 클릭합니다.
팝업 새 작업 창에서 "반복"버튼을 클릭합니다.
그런 다음 후속 대화 상자에서 "매일", "매 1 일"및 "종료 날짜 없음"을 선택하고 마지막으로 "확인"을 누릅니다.
나중에 필요에 따라 작업 제목과 알림을 변경하십시오.
결국“저장 및 닫기”버튼을 클릭합니다.

이제부터는이 작업의 미리 알림 경고가 발생할 때마다 Outlook에서 어제받은 전자 메일을 자동으로 계산 한 다음 다음 스크린 샷과 같이 Excel 파일에 번호를 기록합니다.

영구적 인 PST 데이터 손실로부터 탈출

아무도 영구적 인 PST 데이터 손실을 기꺼이 받아들이지 않습니다. 그러나 Outlook PST 파일은 손상되기 쉽습니다. 따라서 일관되고 최신 PST 데이터 백업을 만들고 강력한 데이터를 유지하는 등 충분한 예방 조치를 취해야합니다. PST 복구 근처의 도구 DataNumen Outlook Repair.

저자 소개 :

Shirley Zhang은 데이터 복구 전문가입니다. DataNumen, Inc.는 다음과 같은 데이터 복구 기술 분야의 세계적 리더입니다. SQL 수리 및 전망 수리 소프트웨어 제품. 자세한 내용은 WWW.datanumen.COM