Word 문서를 빠르게 변환하는 3 가지 매크로 방법 PDF 파일

워드 솔루션 2025 년 9 월 28 일
지금 공유 :

이 기사에서는 Word 문서를 빠르게 변환하는 데 사용할 수있는 3 개의 매크로를 제공하는 데 중점을 둘 것입니다. pdf 파일.

Word 2003에서는 메뉴 모음에 아이콘이 있습니다. 한 번의 클릭으로 사용자는 "다른 이름으로 저장"창을 즉시 실행하고 문서를 pdf 형식입니다.다른 이름으로 저장 PDF 아이콘

그러나 아시다시피 Word 2010의 레이아웃은 많이 변경됩니다. 그리고 사용자는 "파일"탭을 클릭 한 다음 "다른 이름으로 저장"명령을 클릭하여 "다른 이름으로 저장"창을 실행해야합니다. 또한 "저장"버튼을 누르기 전에 수동으로 저장 유형을 선택해야합니다.저장 유형 선택

이렇게 여러 번 클릭하는 것은 속도가 충분히 빠르지 않습니다. 따라서 이번 글에서는 훨씬 효율적인 매크로 방식을 보여드리겠습니다.

매크로 1 : "다른 이름으로 저장"창을 빠르게 트리거

  1. 먼저 "개발자" 탭을 클릭한 다음 "Visual Basic" 명령을 클릭하여 VBA 편집기를 엽니다. 물론 이 두 클릭은 "개발자" 탭이 이미 표시된 상태에서 수행해야 합니다. 또는 "Alt + F11" 키를 눌러도 됩니다."개발자"-> "Visual Basic"을 클릭합니다.
  2. 둘째,“일반”프로젝트를 클릭합니다.
  3. 셋째, "삽입"을 클릭 한 다음 목록 메뉴에서 "모듈"을 선택합니다.
  4. 이제 모듈을 두 번 클릭하여 편집 영역을 표시합니다."일반"클릭-> "삽입"클릭-> "모듈"클릭
  5. 다음으로 다음 코드를 붙여 넣습니다.
Sub TriggerSaveAsWindow()
  Dim dlgSaveAs As Dialog
 
  Set dlgSaveAs = Dialogs(wdDialogFileSaveAs)
  With dlgSaveAs
    .Format = wdFormatPDF
    .Show
    .Execute
  End With
End Sub
  1. 그런 다음 "실행"을 클릭합니다.TriggerSaveAsWindow 매크로 붙여 넣기-> "실행"클릭

이제 "다른 이름으로 저장" 창이 나타납니다. 저장 형식은 이미 PDF로 설정되어 있습니다. 이제 "저장" 버튼을 클릭하기만 하면 됩니다. 이 매크로는 필요에 따라 파일 이름을 변경할 수 있도록 해줍니다.

매크로 2: 워드 파일을 PDF로 직접 저장

어떤 사람들은 파일을 직접 저장하려는 경우 pdf 파일 이름을 수정하지 않고 필요한 매크로는 다음과 같습니다.

  1. 먼저 위의 처음 4 단계를 반복합니다.
  2. 그런 다음 대신 다음 코드를 붙여 넣으십시오.
'Directly save Word file as Pdf and aumatically open it.
Sub DirectlySaveDocxToPdf()
  Dim objDoc As Document
 
  Set objDoc = ActiveDocument
  objDoc.ExportAsFixedFormat _
    OutputFileName:=Replace(objDoc.FullName, ".docx", ".pdf"), _
    ExportFormat:=wdExportFormatPDF, OpenAfterExport:=True, OptimizeFor:=wdExportOptimizeForPrint, _
    Range:=wdExportAllDocument, Item:=wdExportDocumentContent
End Sub
  1. 마찬가지로 "실행"을 클릭합니다.

매크로 3: Word Docx 파일을 PDF로 일괄 변환

  1. 먼저 모든 docx 파일을 하나의 폴더에 넣으십시오.
  2. 위의 단계에 따라 편집 영역을 엽니 다.
  3. 그런 다음 다음 매크로를 붙여 넣습니다.
Sub BatchConvertDocxToPDF()
  Dim objDoc As Document
  Dim strFile As String, strFolder As String
 
  'Initialization
  strFolder = "C:\Users\Test\Desktop\Test Files\"
  strFile = Dir(strFolder & "*.docx", vbNormal)
 
  'Precess each file in the file folder and convert them to pdf.
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=strFolder & strFile)
 
    objDoc.ExportAsFixedFormat _
      OutputFileName:=Replace(objDoc.FullName, ".docx", ".pdf"), _
      ExportFormat:=wdExportFormatPDF, OpenAfterExport:=False, OptimizeFor:=wdExportOptimizeForPrint, _
      Range:=wdExportAllDocument, Item:=wdExportDocumentContent
 
    objDoc.Close
    strFile = Dir()
  Wend
End Sub
  1. "실행"버튼을 클릭하는 것을 잊지 마십시오.

주의 사항: 코드에서 "strFolder = "C : \ Users \ Test \ Desktop \ Test Files \"",""C : \ Users \ Test \ Desktop \ Test Files \" " 폴더의 파일 경로입니다. 그에 따라 변경하는 것을 잊지 마십시오.

이 매크로를 실행하면 PDF 파일이 Word 문서가 저장되는 동일한 폴더에 저장됩니다.효과

가능한 한 파일 보안

손상된 파일을 복구하기 위한 예방 조치와 재해 발생 후 조치가 있습니다. 정기적으로 파일을 백업해 두면 원본 파일을 되찾는 것은 매우 간단합니다. 하지만 실제로 백업 계획을 꾸준히 지키는 사람은 드물기 때문에 소중한 데이터를 잃을 위험이 커집니다. 이러한 상황에서는 고급 백업 솔루션을 고려해야 할 때입니다. Word 문서 손상 수정 도구.

저자 소개 :

Vera Chen은 데이터 복구 전문가입니다. DataNumen, Inc.는 다음과 같은 데이터 복구 기술 분야의 세계적 리더입니다. 손상된 Excel xlsx 수정 pdf 수리 소프트웨어 제품. 자세한 내용은 WWW.datanumen.COM

지금 공유 :

댓글이 닫혀있다.