Word 표에서 빈 행과 열을 삭제하는 3 가지 빠른 방법

워드 솔루션 2025 년 9 월 28 일

이 글에서는 워드 표에서 빈 행과 열을 빠르게 삭제하는 세 가지 방법을 설명합니다.

테이블은 특히 다양한 유형의 데이터를 보관할 때 문서에 필수적입니다. 경우에 따라 긴 테이블이 페이지를 초과하고 여러 페이지에 걸쳐 확장될 수 있습니다. 따라서 테이블이 길어지고 복잡해지면 테이블을 단순화하기 위해 수행할 수 있는 조치가 있습니다. 예를 들어 불필요한 빈 행과 열을 삭제할 수 있습니다.

다음은 사용할 수 있는 3가지 방법입니다.

방법 1: 빈 행과 열을 수동으로 삭제

먼저 빈 칸에 있는 행이나 열을 선택합니다.
그런 다음 상황에 맞는 메뉴를 얻으려면 마우스 오른쪽 버튼을 클릭하십시오. 메뉴에서 그에 따라 "행 삭제" 또는 "열 삭제"를 선택합니다.

아쉽게도 연속되지 않은 여러 행이나 열을 선택하여 이 방법으로 함께 삭제할 수는 없습니다. 이 요구 사항에 대해서는 이전 기사를 참조하십시오. Word 표에서 여러 행 또는 열을 일괄 삭제하는 5 가지 빠른 방법

방법 2: 테이블의 모든 빈 행과 열 일괄 삭제

방법 1에는 한계가 있습니다. 따라서 VBA 코드를 통해 테이블의 행과 열을 일괄 제거하는 방법을 제공합니다.

먼저, 대상 테이블 안에 커서를 놓습니다.
둘째, "Alt+ F11"을 눌러 VBA 편집기를 시작합니다.
편집기에서 먼저 "일반" 프로젝트를 클릭합니다.
그런 다음 메뉴 모음에서 "삽입"탭을 클릭합니다.
드롭 다운 메뉴에서 "Module"을 선택합니다.
모듈을 두 번 클릭하여 열고 다음 코드를 붙여넣습니다.

Sub DeleteBlankRowsAndTablesInATable()
  Dim objCell As Cell
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  If Selection.Information(wdWithInTable) = False Then
    MsgBox ("Put cursor inside a table first!")
    Exit Sub
  Else
    With Selection.Tables(1)
      nRows = .Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Rows(nRowIndex).Delete
          End If
      Next nRowIndex
 
      nColumns = .Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    End With
  End If

  Set objCell = Nothing

  Application.ScreenUpdating = True
End Sub

마지막으로 메뉴 표시줄에서 "실행" 버튼을 클릭하거나 "F5"를 누르십시오.

몇 초 안에 해당 테이블의 모든 빈 행과 열이 제거됩니다.

방법 3: 문서의 모든 테이블에서 모든 빈 행과 열 일괄 삭제

먼저 방법 2의 단계를 반복하여 매크로를 설치하고 실행합니다.
이번에만 해당 매크로를 다음으로 바꿉니다.

Sub DeleteBlankRowsAndColumnsInAllTables()
  Dim objCell As Cell
  Dim objTable As Table
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  With ActiveDocument
    For Each objTable In .Tables
      nRows = objTable.Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Rows(nRowIndex).Delete
          End If
      Next nRowIndex
    Next objTable
 
    For Each objTable In .Tables
      nColumns = objTable.Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    Next objTable
  End With

  Set objCell = Nothing
  Set objTable = Nothing

  Application.ScreenUpdating = True
End Sub

깨진 문서 복구

요즘에는 손실된 데이터를 복구하는 방법이 여러 가지 있습니다. 예를 들어, 백업을 활용하는 것이 항상 최우선 순위입니다. 하지만 백업으로도 최신 정보를 복구할 수 없다면 다른 방법을 시도해 볼 수 있습니다. 문서 수리 도구입니다.

저자 소개 :

Vera Chen은 데이터 복구 전문가입니다. DataNumen, Inc.는 다음과 같은 데이터 복구 기술 분야의 세계적 리더입니다. xlsx 수리 pdf 수리 소프트웨어 제품. 자세한 내용은 WWW.datanumen.COM