Outlook에서 이메일 주소없이 모든 연락처를 일괄 삭제하는 2 가지 방법

Outlook 솔루션 2025 년 9 월 29 일

일부 연락처에 Outlook에 전자 메일 주소가없는 경우 각 연락처 폴더를 처리하여 이러한 연락처를 모두 삭제할 수 있습니다. 이 post 당신과 2 개의 수단을 공유 할 것입니다.

Outlook에 많은 연락처가 있고 그중 일부에는 이메일 주소가 없을 수 있습니다. 더 이상 유용하지 않다고 생각되면 이메일 주소없이 모든 연락처를 삭제해야합니다. 표준적인 방법으로 "즉시 검색"을 사용하여 다음 방법 1과 같이 직접 찾은 다음 수동으로 삭제할 수 있습니다. 그러나 약간 지루합니다. 따라서 방법 2에서 우리는 다른 더 효율적인 방법을 가르 칠 것입니다.

방법 1 : 이메일 주소없이 연락처를 찾은 후 수동으로 삭제

로tart, "Ctrl + 3"키를 눌러 "연락처"창에 액세스합니다.
그런 다음 검색 창을 클릭합니다.
다음으로 나타나는 "검색"리본에서 "모든 연락처 항목"을 클릭합니다.
그런 다음 "주소 있음"> "이메일 주소 있음"을 클릭합니다.
그 후 "NOT emailaddresses : = []"기준이 검색 창에 추가됩니다. "NOT"을 제거해야합니다.
이후에는 이메일 주소가없는 모든 연락처가 나열됩니다.
이제 연락처 그룹도 목록에 있어야하므로 검색 결과에서 연락처를 수동으로 선택해야합니다.
마지막으로 "Del"키 버튼을 눌러 선택한 모든 연락처를 삭제합니다.

방법 2 : VBA를 사용하여 전자 메일 주소없이 모든 연락처 일괄 삭제

처음에는 "Alt + F11"을 눌러 Outlook에서 VBA 편집기를 시작합니다.
새 화면에서 다음 VBA 코드를 모듈에 복사합니다.

Sub BatchDeleteAllContactsWithoutEmailAddress()
    Dim objStore As Outlook.Store
    Dim lTotalCount As Long
 
    lTotalCount = 0
    'Process all stores in your Outlook
    For Each objStore In Application.Session.Stores
       Call ProcessContactFolders(objStore.GetRootFolder.Folders, lTotalCount)
    Next
 
    MsgBox lTotalCount & " contacts are deleted!", vbInformation + vbOKOnly, "Delete Contacts"
End Sub

Sub ProcessContactFolders(ByVal objFolders As Outlook.Folders, lCount As Long)
    Dim objFolder As Outlook.Folder
    Dim i As Long
    Dim objContact As Outlook.ContactItem
    Dim objSubfolder As Outlook.Folder

    For Each objFolder In objFolders
        If (objFolder.DefaultItemType = olContactItem) And (objFolder.Name <> "Skype Contacts") Then
           For i = objFolder.Items.Count To 1 Step -1
               If objFolder.Items(i).Class = olContact Then
                  Set objContact = objFolder.Items(i)
                  'Delete the contact w/o email address
                  If (objContact.Email1Address = "") And (objContact.Email2Address = "") And (objContact.Email3Address = "") Then
                     objContact.Delete
                     lCount = lCount + 1
                  End If
               End If
           Next
 
           'Process subfolders recursively
           If objFolder.Folders.Count > 0 Then
              Call ProcessContactFolders(objFolder.Folders, lCount)
           End If
       End If
    Next
End Sub

나중에 "BatchDeleteAllContactsWithoutEmailAddress"서브 루틴을 클릭하십시오.
결국 "F5"를 눌러이 매크로를 트리거합니다.
완료되면 아래 이미지와 같은 결과에 대한 메시지가 표시됩니다.
이메일 주소가없는 모든 연락처는 "지운 편지함"폴더로 이동되었습니다.

모든 잠재적 위험으로부터 멀리하십시오

Outlook은 바이러스, 사용자 오류, 소프트웨어 오류 및 하드웨어 오류와 같은 다양한 요인으로 인해 손상 될 수 있습니다. Outlook 손상을 경험하는 것을 꺼려해야하므로 이러한 모든 잠재적 위험을 막아야합니다. 예를 들어, 강력한 바이러스 백신 소프트웨어를 PC에 탑재해야합니다. 또한 정기적으로 Outlook 데이터를 백업해야합니다. 마지막으로 다음과 같은 견고하고 신뢰할 수있는 수리 도구를 준비하는 것이 좋습니다. DataNumen Outlook Repair. 그것은 당신의 손상된 PST 쉽게 파일.

저자 소개 :

Shirley Zhang은 데이터 복구 전문가입니다. DataNumen, Inc.는 다음과 같은 데이터 복구 기술 분야의 세계적 리더입니다. SQL Server 부패 및 전망 수리 소프트웨어 제품. 자세한 내용은 WWW.datanumen.COM