VBA арқылы қалтадағы қайталанатын Outlook элементтерін қалай тез жоюға болады

Outlook шешімдері Қыркүйек 29, 2025
Қазір бөлісу:

Егер сіз Outlook бағдарламасындағы қайталанатын элементтерді жойғыңыз келсе, оларды бір-бірлеп іздеу және жою өте қиын болады. Бұл жазба сізге Outlook VBA көмегімен оны қалай тез аяқтау керектігін үйретеді.

Менің алдыңғы мақаламда - «Outlook бағдарламасында электрондық пошта көшірмелерін қалай тез жоюға және жоюға болады», Сіз қайталанатын электрондық пошталарды табу және жою тәсілдерін біле аласыз, олар бірінші кезекте электрондық поштаны тақырыптар бойынша, содан кейін алынған уақыт бойынша, содан кейін қосымшалар бойынша қайталанатын элементтерді табу үшін сұрыптайды, содан кейін көшірмелерді таңдап,« Жою »пернесін басыңыз. Бұл әдіс біршама ыңғайлы болып көрінгенімен, Outlook VBA-мен салыстырғанда әлдеқайда қиын. Келесі VBA кодтары бойынша сіз электрондық поштаға, тапсырмаға, контактілерге немесе кездесулерге қарамастан, қайталанатын элементтерді бір рет басу арқылы тез алып тастай аласыз. Енді кодтарды егжей-тегжейлі алу үшін оқыңыз.

Қалтадағы Outlook элементтерінің көшірмесін VBA арқылы тез алып тастаңыз

Қалтадағы қайталанатын Outlook элементтерін алып тастаңыз

  1. Бастау үшін Outlook бағдарламаңызды іске қосыңыз.
  2. Содан кейін «Alt + F11» батырмаларын басыңыз.
  3. Келесі VBA редакторы терезесінде қолданыстағы модульді ашу үшін екі рет нұқыңыз немесе «Кірістіру»> «Модуль» арқылы жаңа модульді салыңыз.
  4. Келесі модульге келесі VBA кодтарын көшіріңіз және қойыңыз.
Sub RemoveDuplicateItems()
    Dim objFolder As Folder
    Dim objDictionary As Object
    Dim i As Long
    Dim objItem As Object
    Dim strKey As String

    Set objDictionary = CreateObject("scripting.dictionary")
    'Select a source folder
    Set objFolder = Outlook.Application.Session.PickFolder

    If Not (objFolder Is Nothing) Then
       For i = objFolder.Items.Count To 1 Step -1
           Set objItem = objFolder.Items.Item(i)
 
           Select Case objFolder.DefaultItemType
                  'Check email subject, body and sent time
                  Case olMailItem
                       strKey = objItem.Subject & "," & objItem.Body & "," & objItem.SentOn
                  'Check appointment subject, start time, duration, location and body
                  Case olAppointmentItem
                       strKey = objItem.Subject & "," & objItem.Start & "," & objItem.Duration & "," & objItem.Location & "," & objItem.Body
                  'Check contact full name and email address
                  Case olContactItem
                       strKey = objItem.FullName & "," & objItem.Email1Address & "," & objItem.Email2Address & "," & objItem.Email3Address
                  'Check task subject, start date, due date and body
                  Case olTaskItem
                       strKey = objItem.Subject & "," & objItem.StartDate & "," & objItem.DueDate & "," & objItem.Body
           End Select
 
           strKey = Replace(strKey, ", ", Chr(32))
 
           'Remove the duplicate items
           If objDictionary.Exists(strKey) = True Then
              objItem.Delete
           Else
              objDictionary.Add strKey, True
           End If
       Next i
    End If
End Sub

VBA кодтары - қалтадағы қайталанатын Outlook элементтерін тез алып тастаңыз

  1. Осыдан кейін осы макросқа сандық қолтаңба қойып, Outlook макро қауіпсіздік деңгейіңізді төмен деңгейге өзгертіңіз.
  2. Кейінірек сіз бұл жаңа VBA жобасын басқара аласыз. Құралдар тақтасындағы «Іске қосу» белгішесін тікелей басыңыз.осы макросты іске қосыңыз
  3. Кейіннен сізден қайталанатын элементтерді алып тастайтын қалтаны таңдау қажет болады.Қалтаны таңдаңыз
  4. Соңында, таңдалған қалтадағы қайталанатын элементтер бірден жойылады.

PST осал деректерін қорғаңыз

PST файлының сыбайлас жемқорлыққа ұшырауына байланысты, сіз PST файлыңызды қорғау үшін көп күш жұмсауыңыз керек. Мысалы, Outlook бағдарламасының дұрыс жабылуына жол бермеуіңіз керек. Сонымен қатар, сізге мықты дайындық қажет Outlook түзетуі сияқты құрал DataNumen Outlook Repair бұл сіздің PST-ні уақытында құтқаруға мүмкіндік береді.

Автордың кіріспесі:

Ширли Чжан - деректерді қалпына келтіру бойынша сарапшы DataNumen, Соның ішінде деректерді қалпына келтіру технологиялары бойынша әлемдік көшбасшы болып табылатын Inc. қалпына келтіру SQL Server және бағдарламалық жасақтаманы жөндеу бағдарламалары. Қосымша ақпарат алу үшін кіріңіз WWW.datanumen.com

Қазір бөлісу:

Пікірлер жабылды.