Әр түсті санаттағы Outlook кездесулеріне жұмсалған жалпы уақытты қалай жылдам экспорттауға болады

Егер сіз әр түсті санаттағы кездесулерге кеткен жалпы уақыт туралы есеп жасағыңыз келсе, осы мақалада енгізілген әдісті қолдануға болады. Мұны қолмен санаудың қажеті жоқ тез арада жасауға болады.

Көптеген пайдаланушылар өздерінің әрекеттерінің көпшілігін Outlook күнтізбесінде тіркеуге үйренген. Сондай-ақ, оларды оңай басқару және ажырату үшін олар әрқайсысына санаттар тағайындайды. Бұл жағдайда кейбір пайдаланушылар әр түс санатындағы күнтізбе элементтеріне жұмсалған жалпы уақытты көрсететін есеп жасағысы келеді. Әрине, қолмен санау және енгізу қиын. Сондықтан, біз бұл тапсырманы қарапайым басу арқылы қалай орындауға болатынын бөлісеміз.

Әр түсті санаттағы кездесулерге жұмсалған жалпы уақытты экспорттау

1. Біріншіден, Outlook қосымшасын іске қосыңыз.
2. Одан кейін, Outlook терезесіне кіргеннен кейін «Alt + F11» батырмаларын түртуге болады.
3. Содан кейін сіз «Microsoft Visual Basic for Applications» терезесіне кіре аласыз.
4. Келесіде сізге «Microsoft Excel нысан кітапханасын» қосу қажет болады. Ол үшін «Құралдар» > «Сілтеме» тармақтарын басуға болады.
5. Содан кейін, сіз қолданылмаған модульді тауып, ашыңыз.
6. Осыдан кейін сізге келесі VBA кодын осы модульге көшіру керек.

Sub ExportTimeSpentOnAppointmentsInEachColorCategory()
    Dim objDictionary As Object
    Dim objAppointments As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim strCategory As String
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim arrKey As Variant
    Dim arrItem As Variant
    Dim i As Long
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objAppointments = Application.Session.PickFolder.Items
  
    For Each objAppointment In objAppointments
        arrCategory = Split(objAppointment.Categories, ",")
        For Each varCategory In arrCategory
            strCategory = Trim(varCategory)
            If objDictionary.Exists(strCategory) Then
               objDictionary.Item(strCategory) = objDictionary.Item(strCategory) + objAppointment.Duration
            Else
               objDictionary.Add strCategory, objAppointment.Duration
            End If
        Next
    Next
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
    objExcelApp.Visible = True
    objExcelWorkbook.Activate
 
    With objExcelWorksheet
         .Cells(1, 1) = "Color Category"
         .Cells(1, 1).Font.Bold = True
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 2) = "Total Time (min)"
         .Cells(1, 2).Font.Bold = True
         .Cells(1, 2).Font.Size = 14
    End With
 
    arrKey = objDictionary.Keys
    arrItem = objDictionary.Items
 
    For i = LBound(arrKey) To UBound(arrKey)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.count).End(xlUp).Row + 1
 
        objExcelWorksheet.Cells(nLastRow, 1) = arrKey(i)
        objExcelWorksheet.Cells(nLastRow, 2) = arrItem(i)
    Next

    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

7. Сонымен, сіз бұл макросты кез-келген жағдайда, құралдар тақтасындағы «Іске қосу» белгішесін басу арқылы немесе «F5» батырмасын басу арқылы бастауға болады.
8. Содан кейін сізден нақты күнтізбені таңдауыңыз талап етіледі.
9. «OK» параметрін таңдап, соққы бергеннен кейін макростың жұмысы жалғасады. Аяқтағаннан кейін фонда көрсетілетін жаңа Excel файлы болады.
10. Сіз оған қол жеткізе аласыз. Ол келесі скриншотқа ұқсайды:

Сіздің Outlook айналаңыздағы ықтимал қауіп-қатерлерге көз салыңыз

Outlook пайдаланушылары барлық ықтимал тәуекелдерді, соның ішінде белгісіз электрондық пошта тіркемелерін, ендірілген сілтемелерді және адам қателіктерін ескеруі керек. Әйтпесе, кез-келген уақытта Outlook бағдарламаңыз бүлінуі мүмкін. Сонымен қатар, Outlook деректерінің сақтық көшірмелерін жасау және жөндеудің мамандандырылған құралын ұстау қажеттілік болып табылады. DataNumen Outlook Repair ең ұсынылатын түзету құралдарының бірі. Ол жасай алады Outlook бағдарламасын жөндеу проблемалар

Автордың кіріспесі:

Ширли Чжан - деректерді қалпына келтіру бойынша сарапшы DataNumen, Соның ішінде деректерді қалпына келтіру технологиялары бойынша әлемдік көшбасшы болып табылатын Inc. mdf бүлінген және бағдарламалық жасақтаманы жөндеу бағдарламалары. Қосымша ақпарат алу үшін кіріңіз WWW.datanumen.com