PST файлындағы барлық қалталардың көлемі туралы ақпаратты Excel файлына жылдам экспорттау әдісі

Outlook шешімдері Қыркүйек 29, 2025

Егер сіз PST файлындағы әр қалтаның өлшемі туралы ақпаратты тексергіңіз келсе, осы мақалада көрсетілген әдісті қолдануға болады. Ол PST файлындағы барлық қалталардың өлшемі туралы ақпаратты Excel файлына жылдам экспорттайды.

Егер сіздің PST файлыңыз өте үлкен болса, сіз әр қалтаның өлшемін тексергіңіз келуі мүмкін. Бұл сізге қайсысы үлкен екенін оңай анықтауға және өлшемі бойынша сәйкес архивтеуге көмектеседі. Жалпы, қалтаның өлшемін тексеру үшін қалтаны тінтуірдің оң жағымен басып, содан кейін «Сипаттар» тармағын таңдауға болады. Жаңа қалқымалы диалог терезесінде «Қапшық өлшемі» батырмасын басуға болады. Алайда, егер сіз көптеген қалталар жасаған болсаңыз, өлшем туралы ақпаратты бір-бірлеп тексеру өте қиынға соғады. Сонымен, егер сіз PST файлындағы барлық қалталардың өлшемі туралы ақпарат алғыңыз келсе, келесі VBA кодын пайдалануға болады. Ол барлық қалталардың атаулары мен өлшемдері туралы мәліметтерді бір уақытта Excel файлына экспорттайды.

PST файлындағы барлық қалталардың өлшемі туралы ақпаратты Excel файлына экспорттаңыз

Бастау үшін Outlook қолданбаңызды іске қосыңыз.
Содан кейін «Әзірлеуші» қойындысына өтіп, «Visual Basic» батырмасын басыңыз немесе VBA редакторына кіру үшін «Alt + F11» пернелерін басыңыз.
«Microsoft Visual Basic for Applications» терезесінде пайдаланылмаған модульді ашыңыз.
Осы модульге келесі VBA кодтарын көшіріңіз және қойыңыз.

Dim strExcelFile As String
Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportFodlerSizetoExcel()
    Dim objSourcePST As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
    objExcelWorksheet.Cells(1, 1) = "Folder"
    objExcelWorksheet.Cells(1, 2) = "Size"
 
    'Select a source PST file
    Set objSourcePST = Outlook.Application.Session.PickFolder

    For Each objFolder In objSourcePST.Folders
        Call ProcessFolders(objFolder)
    Next
 
    'Fit the columns from A to B
    objExcelWorksheet.Columns("A:B").AutoFit
 
    strExcelFile = "E:\Outlook\" & objSourcePST.Name & " Folder Size (" & Format(Now, "yyyy-mm-dd hh-mm-ss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim objItem As Object
    Dim lCurrentFolderSize As Long
    Dim nNextEmptyRow As Integer
 
    objCurrentFolder.Items.SetColumns ("Size")
    For Each objItem In objCurrentFolder.Items
        lCurrentFolderSize = lCurrentFolderSize + objItem.Size
    Next
 
    'Convert byte to kilobyte
    'To convert to megabyte, use:
    'lCurrentFolderSize = (lCurrentFolderSize / 1024) / 1024
    lCurrentFolderSize = lCurrentFolderSize / 1024
 
    nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1

    'Add the values into the columns
    objExcelWorksheet.Range("A" & nNextEmptyRow) = objCurrentFolder.FolderPath
    objExcelWorksheet.Range("B" & nNextEmptyRow) = lCurrentFolderSize & " KB"
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder)
       Next
    End If
End Sub

Осыдан кейін Outlook макроқауіпсіздік деңгейін төмен деңгейге қою керек.
Ақыр соңында, сіз көріңіз.

Ағымдағы макро терезеде F5 пернесін басыңыз.
Содан кейін сізге келесі сурет сияқты PST файлын таңдау сұралады:
Бастапқы файлды таңдағаннан кейін, Outlook бағдарламасы Excel-ге көлем туралы ақпаратты экспорттай бастайды.
Макро аяқталғаннан кейін сіз төмендегі скриншот сияқты хабарлама аласыз.
Соңында, Excel файлын алдын ала анықталған жергілікті қалтадан таба аласыз. Excel файлы келесідей болады:

PST жиі кездесетін қателіктермен күресу

Outlook қателіктерге бейім болғандықтан, сізде Outlook бағдарламасында көптеген мәселелер туындаған болуы мүмкін. Көңілсіз PST қиындықтарын жақсы және икемді жеңу үшін жақын жерде тәжірибелі және беделді жөндеу утилитасын сақтаған жөн. DataNumen Outlook Repair. Бұл қабілетті PST түзету самал сияқты проблемалар.

Автордың кіріспесі:

Ширли Чжан - деректерді қалпына келтіру бойынша сарапшы DataNumen, Соның ішінде деректерді қалпына келтіру технологиялары бойынша әлемдік көшбасшы болып табылатын Inc. SQL Server қалпына келтіру және бағдарламалық жасақтаманы жөндеу бағдарламалары. Қосымша ақпарат алу үшін кіріңіз WWW.datanumen.com