Outlook электрондық поштасын кескін файлы ретінде қалай жылдам экспорттауға болады

Кейбір пайдаланушылар Outlook электрондық поштасын jpg файлы сияқты кескін файлы ретінде экспорттағысы келеді. Сондықтан, осы мақалада біз оны Outlook VBA коды арқылы қалай алуға болатынын көрсетеміз.

Сіз электрондық поштаны мәтіндік файл, Word құжаты және т.б. ретінде экспорттаудың әртүрлі амалдарын үйренген болуыңыз керек. Содан кейін электрондық поштаны JPG файлы сияқты сурет ретінде экспорттау туралы не айтасыз? Outlook бағдарламасында бұл функция жоқ сияқты. Бірақ бұдан әрі біз сіздермен жылдам құралмен бөлісетін боламыз.

Outlook электрондық поштасын кескін файлы ретінде жылдам экспорттаңыз

1. Бастау үшін Outlook қолданбаңызды іске қосыңыз.
2. Содан кейін негізгі Outlook терезесінде мақалаға сәйкес VBA редакторына қол жеткізіңіз - «Outlook бағдарламасында VBA кодын қалай іске қосуға болады«.
3. Келесіде, «MS Word нысан кітапханасын» және «MS» қосыңыз PowerPoint «Нысан кітапханасы» мақаласына сілтеме жасау арқылы – «VBA бағдарламасында объект кітапханасына сілтемені қалай қосуға болады«.
4. Содан кейін келесі VBA кодын көшіріп, бос модульге қойыңыз.

Sub ExportEmailAsImage()
    Dim objMail As Outlook.MailItem
    Dim strFileName As String
    Dim strWordDocument As String
    Dim objWordApp As Word.Application
    Dim objWordDocument As Word.Document
    Dim objDocumentRange As Word.Range
    Dim objPowerPointApp As PowerPoint.Application
    Dim objPresentation As PowerPoint.Presentation
    Dim objShape As PowerPoint.Shape
 
    On Error Resume Next
    'Export the email as Word document
    Set objMail = Outlook.Application.ActiveExplorer.Selection(1)
    strFileName = Replace(objMail.Subject, "/", " ")
    strFileName = Replace(strFileName, "\", " ")
    strFileName = Replace(strFileName, ":", "")
    strFileName = Replace(strFileName, "?", " ")
    strFileName = Replace(strFileName, Chr(34), " ")
    strWordDocument = Environ("Temp") & "\" & strFileName & ".doc"
 
    objMail.SaveAs strWordDocument, olDoc

    Set objWordApp = CreateObject("Word.Application")
    Set objWordDocument = objWordApp.Documents.Open(strWordDocument)
    objWordApp.Visible = True
 
    objWordApp.Selection.Find.ClearFormatting
    objWordApp.Selection.Find.Replacement.ClearFormatting
 
    With objWordApp.Selection.Find
        .Text = "^p^p"
        .Replacement.Text = "^p"
        .Wrap = wdFindContinue
    End With
 
    'Insert the document into a PowerPoint Presentation slide as an object
    objWordApp.Selection.Find.Execute Replace:=wdReplaceAll
    Set objDocumentRange = objWordDocument.Range()
    objDocumentRange.Font.Name = "Calibri"
    objDocumentRange.Font.Size = 10
    objWordDocument.Close True
    objWordApp.Quit
 
    Set objPowerPointApp = CreateObject("PowerPoint.Application")
    Set objPresentation = objPowerPointApp.Presentations.Add
    objPowerPointApp.Visible = msoTrue
 
    With objPresentation
        .PageSetup.SlideHeight = 792
        .PageSetup.SlideWidth = 612
        .Slides.AddSlide 1, .SlideMaster.CustomLayouts(1)
    End With
 
    'Export the slide
    With objPresentation.Slides(1)
         Set objShape = .Shapes.AddOLEObject(0, 0, 612, 792, , strWordDocument)
        .Export "E:\Email_" & strFileName & ".jpg", "JPG"
    End With
 
    objPresentation.Saved = msoTrue
    objPresentation.Close
    objPowerPointApp.Quit
End Sub

5. Осыдан кейін макросты Жылдам кіру құралдар тақтасына қосу керек.
6. Кейіннен VBA өңдегішін жабуға болады.
7. Кейінірек электрондық поштаны таңдап, Жылдам кіру құралдар тақтасындағы макрос түймесін басыңыз.
8. Макрос аяқталған кезде, осы электрондық поштадан экспортталған кескін файлын табу үшін алдын ала анықталған жергілікті қалтаға өтуге болады.

Outlook деректерін бүлінген файлдан шығарып алыңыз

Outlook файлыңыз қатты зақымдалған жағдайда, сіз қатты ашулануыңыз мүмкін. Бұл жағдайда сіз бұзылған файлдан Outlook деректерін алуды жалғастырасыз. Кейбір пайдаланушылар кіріс жәшігін қалпына келтіру құралын пайдалануға бейім болады. Дегенмен, көп жағдайда бұл нәтиже бермейді. Сондықтан, сіз сенімді және сенімді файлды сақтағаныңыз жөн. PST түзету сияқты құрал DataNumen Outlook Repair. Ол бүлінген файлды сканерлей алады және ең көп деректерді еш кедергісіз қайтара алады.

Автордың кіріспесі:

Ширли Чжан - деректерді қалпына келтіру бойынша сарапшы DataNumen, Соның ішінде деректерді қалпына келтіру технологиялары бойынша әлемдік көшбасшы болып табылатын Inc. mdf түзету және бағдарламалық жасақтаманы жөндеу бағдарламалары. Қосымша ақпарат алу үшін кіріңіз WWW.datanumen.com