Outlook бағдарламасында жалауша қойылған элементтердің әртүрлі түрлері үшін әртүрлі әдепкі еске салғыш уақытын қалай орнатуға болады

Әдепкі бойынша, Outlook барлық белгіленген элементтер түрлеріне тапсырмалардың әдепкі еске салу уақытын автоматты түрде пайдаланады. Дегенмен, элемент түріне байланысты белгі қойылған элементтер үшін әртүрлі еске салу уақытын пайдаланғыңыз келсе, осы мақалада енгізілген әдіске жүгінуіңізге болады.

Outlook бағдарламасы элемент түріне қарамастан барлық белгіленген элементтер үшін әдепкі еске салғыш уақытын орнатуға мүмкіндік береді. Сіз «Файл» мәзіріне өтіп, «Параметрлер» түймесін басуға болады. Содан кейін, «Outlook параметрлері» терезесінде келесі скриншотта көрсетілгендей, «Тапсырмалар» қойындысында «Әдепкі еске салғыш уақыты» опциясын көре аласыз.

Дегенмен, көптеген пайдаланушылар әртүрлі белгіленген элементтер үшін әртүрлі еске салу уақытын пайдалануды жоспарлайды, мысалы, белгіленген пошталар үшін «9:00» және белгіленген контактілер үшін «17:30». Енді, төменде біз әдісті енгізу үшін осы мысалға тоқталамыз.

Белгіленген элементтердің әртүрлі түрлері үшін әртүрлі әдепкі еске салғыш уақытын орнату

1. Бастау үшін Outlook қолданбасын іске қосыңыз.
2. Содан кейін Outlook VBA редакторына «сілтеме жасай отырып кіріңіз.Outlook бағдарламасында VBA кодын қалай іске қосуға болады«.
3. Келесі «Қолданбаларға арналған Microsoft Visual Basic» терезесінде келесі кодты «ThisOutlookSession» жобасына көшіріңіз.

Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objMail As Outlook.MailItem
Public WithEvents objContact As Outlook.ContactItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
    ElseIf TypeOf objExplorer.Selection.Item(1) Is ContactItem Then
       Set objContact = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
    ElseIf Inspector.CurrentItem.Class = olContact Then
       Set objContact = Inspector.CurrentItem
    End If
End Sub

Private Sub objMail_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objMail.IsMarkedAsTask = True Then
          If objMail.TaskDueDate <> "1/1/4501" Then
             With objMail
                  .ReminderSet = True
                  'Change the reminder time for flagged emails
                  .ReminderTime = objMail.TaskDueDate & " 10:00"
                  .Save
             End With
          End If
       End If
    End If
End Sub

Private Sub objContact_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objContact.IsMarkedAsTask = True Then
          If objContact.TaskDueDate <> "1/1/4501" Then
             With objContact
                  .ReminderSet = True
                  'Change the reminder time for flagged contacts
                  .ReminderTime = objContact.TaskDueDate & " 17:30"
                  .Save
             End With
          End If
       End If
    End If
End Sub

4. Осыдан кейін, осы макросты белсендіру үшін Outlook бағдарламасын қайта іске қосыңыз.
5. Бұдан былай электрондық поштаны жалаушалаған сайын еске салғыш уақыты жалаудың аяқталу күні «10:00» болып орнатылады.
6. Контактіні белгілеген кезде, жалаушаның аяқталу күні еске салу уақыты «17:30» мәніне орнатылады.

Outlook мәселелерін икемді түрде шешіңіз

Outlook бағдарламасында барлық мәселелерге тап болуыңыз мүмкін. Сондықтан, оларды алдын ала шешу үшін кейбір шараларды үйренуіңіз керек. Мысалы, егер Outlook бағдарламасы жиі қайта іске қосылса, Office бағдарламасын жөндеу немесе үшінші тарап қондырмаларын өшіру қажет болады. Немесе Outlook PST бағдарламасы бұзылса, алдымен ... әрекетін орындап көруге болады. кіріс жәшігін жөндеу құралы. Ол сәтсіз болғанда, қуатты сыртқы құралға жүгінуді жалғастыра аласыз, мысалы DataNumen Outlook Repair.

Автордың кіріспесі:

Ширли Чжан - деректерді қалпына келтіру бойынша сарапшы DataNumen, Соның ішінде деректерді қалпына келтіру технологиялары бойынша әлемдік көшбасшы болып табылатын Inc. mdf қалпына келтіру және бағдарламалық жасақтаманы жөндеу бағдарламалары. Қосымша ақпарат алу үшін кіріңіз WWW.datanumen.com