Outlook VBA арқылы арнайы кіріс электрондық пошталарынан ендірілген кескіндерді қалай автоматты түрде шығаруға болады

Outlook бағдарламасының кірістірілген кескіндерді белгілі бір кіріс электрондық хаттардан автоматты түрде шығарып алуын және сақтауын қаласаңыз, осы мақаланы қараңыз. Мұнда біз оны VBA кодымен қалай жүзеге асыру керектігін үйретеміз.

Кейбір пайдаланушылар ендірілген кескіндерді белгілі бір кіріс электрондық хаттардан шығарып, оларды белгілі бір Windows қалтасына сақтауы керек. Мұны әр уақытта қолмен жасау өте қиын. Сондықтан көпшілігі Outlook бағдарламасына мұны автоматты түрде орындауға мүмкіндік беретін жылдам және ыңғайлы тәсілді үйренуді асыға күтеді. Енді біз сіздермен осындай әдісті бөлісеміз.

Енгізілген кескіндерді белгілі бір кіріс электрондық хаттардан автоматты түрде шығарып алу

1. Алдымен Outlook бағдарламасын әдеттегідей іске қосыңыз.
2. Содан кейін Outlook VBA редакторын әдеттегідей t сілтемесі арқылы іске қосыңыз.Outlook бағдарламасында VBA кодын қалай іске қосуға болады«.
3. Кейінірек келесі VBA кодын көшіріп, «ThisOutlookSession» жобасына қойыңыз.

Public WithEvents objInbox As Outlook.Folder
Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInbox = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
    Set objInboxItems = objInbox.Items
End Sub

Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objMail As Outlook.MailItem
    Dim objAttachments As Outlook.Attachments
    Dim objAttachment As Outlook.Attachment
    Dim strWindowsFolder As String
    Dim i As Long
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'Specify the emails as per your needs
       If objMail.Importance = olImportanceHigh Then
          Set objAttachments = objMail.Attachments
 
          'Specify the windows folder
          strWindowsFolder = "E:\" & objMail.Subject & Format(Now, "yymmddhhmmss")
          MkDir (strWindowsFolder)
 
          'Save all embedded images to the folder
          For i = 1 To objAttachments.Count
              Set objAttachment = objAttachments.Item(i)
              If IsEmbedded(objAttachment) = True Then
                 objAttachment.SaveAsFile strWindowsFolder & "\" & objAttachment.FileName
              End If
          Next
      End If
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.PropertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.PropertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

4. Осыдан кейін, «Application_Startup» кіші бағдарламасын басыңыз.
5. Соңында, осы макросты іске қосу үшін «F5» пернесін басыңыз.
6. Енді Кіріс қалтасына белгілі бір жаңа электрондық пошта келген сайын, ендірілген кескіндер келесі скриншотта көрсетілгендей арнайы Windows қалтасына сақталады.

Үлкен қосымшаларды жүйелі түрде тазалаңыз

Outlook бағдарламасындағы үлкен қосымшаларды үнемі тазалап отыру ұсынылады. Бұл Outlook файлыңызды тиісті өлшемде сақтауға бағытталған. Үлкен Outlook файлы бұзылуға бейім. Сіз білетіндей, PST зақымдануын жақсы шешу өте қиын. Алдымен оны кіріс жәшігін жөндеу құралы арқылы түзетуге тырысуыңыз мүмкін. Дегенмен, көп жағдайда бұл жұмыс істемейді. Сіздің жалғыз көмекшіңіз - мамандандырылған. PST жөндеу сияқты құрал DataNumen Outlook Repair, немесе тиісті кәсіби қалпына келтіру қызметтері.

Автордың кіріспесі:

Ширли Чжан - деректерді қалпына келтіру бойынша сарапшы DataNumen, Соның ішінде деректерді қалпына келтіру технологиялары бойынша әлемдік көшбасшы болып табылатын Inc. mdf түзету және бағдарламалық жасақтаманы жөндеу бағдарламалары. Қосымша ақпарат алу үшін кіріңіз WWW.datanumen.com