Windows қалтасындағы барлық файлдарды бөлек Outlook электрондық пошталары арқылы пакеттік жіберу жолы

Outlook шешімдері Қыркүйек 29, 2025

Windows қалтасындағы барлық файлдарды жеке Outlook электрондық пошталары арқылы біреуге жібергіңіз келсе, осы мақалада келтірілген әдісті пайдалана аласыз. Ол VBA кодын пайдаланады, бұл өте тиімді.

Менің алдыңғы мақаламды оқығаннан кейін - «Жергілікті қалтадағы барлық файлдарды Outlook электрондық поштасына қосудың 3 жылдам әдісі”, кейбір пайдаланушылар жергілікті қалтадағы барлық файлдарды бөлек электрондық пошта арқылы жібергісі келеді. Стандартты түрде электрондық поштаны жасап, файлдарды бір-бірлеп тіркеу керек. Бұл өте қиын. Сондықтан, келесіде біз сізге тиімдірек жолды таныстырамыз.

Windows қалтасындағы барлық файлдарды бөлек электрондық пошталар арқылы пакеттік жіберу

Алдымен Outlook бағдарламаңызды іске қосыңыз.
Содан кейін, Outlook бағдарламасында мақалаға сілтеме бойынша VBA өңдегішіне кіріңіз – «Outlook бағдарламасында VBA кодын қалай іске қосуға болады«.
Содан кейін келесі VBA кодын жобаға немесе модульге көшіріп, қойыңыз.

Sub SendAllFilesInSeparateEmails()
    Dim objShell As Object
    Dim objWindowsFolder As Object
    Dim objFile As Object
    Dim strWindowsFolder As String
    Dim objFileSystem As Object
    Dim objMail As Outlook.MailItem
 
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       strWindowsFolder = objWindowsFolder.self.Path & "\"
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
       Set objWindowsFolder = objFileSystem.GetFolder(strWindowsFolder)
 
       'Send each file in an email
       For Each objFile In objWindowsFolder.Files
 
           'Create a new mail
           Set objMail = Outlook.Application.CreateItem(olMailItem)
           'Change the details as per your needs
           With objMail
                .Subject = Left(objFile.Name, Len(objFile.Name) - (Len(objFileSystem.GetExtensionName(objFile.Name)) + 1))
                .Attachments.Add objFile.Path
                .Recipients.Add ("someone@datanumen.com")
                .Recipients.ResolveAll
                .Send
          End With
       Next
 
       'Prompt you when completing sending
       MsgBox "All done!", vbOKOnly + vbExclamation
    End If
End Sub

Осыдан кейін сіз бұл макросты бірден іске қоса аласыз. Тек «F5» пернесін басыңыз.
Содан кейін қалқымалы диалогтық терезеде бастапқы Windows қалтасын таңдау қажет болады.
Сайып келгенде, Outlook бағдарламасы осы Windows қалтасындағы барлық файлдарды бөлек электрондық пошталарға тіркейді және хаттарды алдын ала анықталған алушыға жібереді.
Аяқтаған кезде сіз «Барлығы дайын!» Деген хабарлама аласыз.

Outlook денсаулығына назар аударыңыз

Outlook нарықтағы ең танымал электрондық пошта клиенті ретінде танымал болғанымен, оның әлі де бір кемшілігі бар. Бұл оның осалдығы. Басқаша айтқанда, Outlook әртүрлі қателер мен бұзылуларға бейім. Сондықтан Outlook-тың жұмысына, оны зақымданудан қорғауға үлкен мән беруіңіз керек. Сонымен қатар, Outlook файлдарыңыздың сақтық көшірмесін үнемі жасап отыруыңыз керек. Сонымен қатар, PST түзету құралын, мысалы, ... алу ұсынылады. DataNumen Outlook Repair. Ол істей алады Outlook бағдарламасын жөндеу еш қиындықсыз мәселелер.

Автордың кіріспесі:

Ширли Чжан - деректерді қалпына келтіру бойынша сарапшы DataNumen, Соның ішінде деректерді қалпына келтіру технологиялары бойынша әлемдік көшбасшы болып табылатын Inc. sql түзету және бағдарламалық жасақтаманы жөндеу бағдарламалары. Қосымша ақпарат алу үшін кіріңіз WWW.datanumen.com