Сіздің Outlook бағдарламаңызда оқылған түбіртектерді топтамамен қалай жоюға болады

Алушылардың электрондық поштаңызды оқығанын растау үшін электрондық поштаны жазу кезінде оқылғаны туралы хабарламаны сұрай аласыз. Бұл жағдайда пошта жәшігіңіз осындай оқылғаны туралы хабарламалармен толып кетуі мүмкін. Енді бұл жазбада оларды біржолата жоюдың жолдары көрсетіледі.

Мақаланы оқығаннан кейін «Сіздің Outlook бағдарламаңызда жеткізілім түбіртектерін топтамамен қалай жоюға болады«, Сіз оқылған түбіртектерді жаппай жою тәсілін ойластыруыңыз мүмкін. Түбіртектердің екі түрінің айқын айырмашылығы олардың субъектілері болып табылады. Жеткізу түбіртегінде тақырып бойынша «Жеткізілген», ал оқылған түбіртектің орнына «Оқылған» жазбасы бар. Сондықтан, барлық оқылған түбіртектерді пакеттік жою әдісін қолдануға болады. Келесіде біз сізге нақты қадамдарды егжей-тегжейлі үйретеміз.

Топтамамен барлық оқылған түбіртектерді жою

1. Бастапқыда, Outlook бағдарламасын бастаңыз.
2. Содан кейін, «Alt + F11» арқылы Outlook VBA редакторына өтіңіз:Outlook бағдарламасында VBA кодын қалай іске қосуға болады«.
3. Содан кейін, жаңа терезеде бос модульді ашып, оған келесі кодты салыңыз.

Dim objOutlookFile As Outlook.Folder

Sub BatchDeleteAllReadReceipts()
    Dim objStore As Outlook.Store
    Dim objFolder As Outlook.Folder
    Dim lTotalCount As Long
 
    lTotalCount = 0
   'Process all Outlook files
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olMailItem Then
               Call ProcessFolders(objFolder, lTotalCount)
            End If
        Next
    Next
 
    'Prompt you of the results
    MsgBox lTotalCount & " read receipts are deleted!", vbInformation + vbOKOnly
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder, lCount As Long)
    Dim i As Long
    Dim objDeliveryReceipt As Outlook.ReportItem
    Dim objSubfolder As Outlook.Folder
    Dim objDeletedItems As Outlook.Items
    Dim objItem As Object
 
    For i = objCurrentFolder.Items.Count To 1 Step -1
        'Find read receipts
        If (TypeOf objCurrentFolder.Items(i) Is ReportItem) And (Left(objCurrentFolder.Items(i).Subject, 5) = "Read:") Then
           Set objDeliveryReceipt = objCurrentFolder.Items.Item(i)
           objDeliveryReceipt.Delete
 
           lCount = lCount + 1
 
           'Permanently delete them
           Set objDeletedItems = objOutlookFile.Folders("Deleted Items").Items
           For Each objItem In objDeletedItems
               If (TypeOf objItem Is ReportItem) And (Left(objItem.Subject, 5) = "Read:") Then
                  objItem.Delete
               End If
           Next
         End If
    Next
 
    'Loop subfolders recursively
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder, lCount)
       Next
    End If
End Sub

4. Осыдан кейін бірінші ішкі бағдарламаны нұқыңыз.
5. Соңында «F5» батырмасын басыңыз.
6. Бірден макро сіздің Outlook бағдарламаңыздан барлық оқылған түбіртектерді жою үшін жұмыс істейді.
7. Аяқтағаннан кейін, нәтиже туралы жедел хабар аласыз, мысалы, төмендегі скриншот.
8. Қазіргі уақытта сіз пошта қалталарын тексере аласыз. Барлық оқылған түбіртектер жойылды.

Outlook деректерін қорғаңыз

Outlook файлы сыбайлас жемқорлыққа ұшырағанымен, біз оны қорғау үшін шаралар қолдана аламыз. Мысалы, біз Outlook файлын кішігірім мөлшерде ұстап, зиянды факторлардан сақтап, оның сақтық көшірмесін үнемі жасауымыз керек. Сонымен, PST жөндеу сияқты күшті сыртқы құралды дайындағаныңыз жөн DataNumen Outlook Repair. Бұл жөндеуге үлкен әсер етеді бүлінген Outlook файл.

Автордың кіріспесі:

Ширли Чжан - деректерді қалпына келтіру бойынша сарапшы DataNumen, Соның ішінде деректерді қалпына келтіру технологиялары бойынша әлемдік көшбасшы болып табылатын Inc. квадрат жөндеу және бағдарламалық жасақтаманы жөндеу бағдарламалары. Қосымша ақпарат алу үшін кіріңіз WWW.datanumen.com