Әр түрлі түсті санаттардағы Outlook кездесулеріне әр түрлі еске салу уақытын автоматты түрде қалай орнатуға болады

Егер сіз Outlook жиналыстарын түс санаттары бойынша жіктесеңіз және түрлі түсті санаттардағы кездесулер үшін әр түрлі еске салу уақытын орнатқыңыз келсе, осы мақалаға сілтеме жасай аласыз. Мұнда біз оны Outlook VBA көмегімен жүзеге асыруға үйретеміз.

Мысалы, сіз кездесулерді екі топқа бөліп жатырсыз. Біреуі кездесу орны тым алыс болғандықтан «Сыртқы» түс санатында, ал екіншісі «Сыртқы» түс санатында, себебі орын дәл осы жерде. Енді сіз Outlook бағдарламасының «сыртқы» кездесудің еске салу уақытын басталудан 1 сағат бұрын және «орнындағы» кездесудің басталудан 15 минут бұрын автоматты түрде орнатуын қалайсыз. Осы талапты ескере отырып, бұдан әрі жылдам әдісті бөлісеміз.

Автоматты түрде түрлі түсті санаттардағы кездесулер үшін әр түрлі еске салғышты орнатыңыз

1. Бастау үшін Outlook бағдарламасын іске қосыңыз.
2. VBA редакторының терезесіне кіру үшін «Alt + F11» батырмаларын басыңыз.
3. Келесі терезеде төмендегі VBA кодын көшіріп, «ThisOutlookSession» жобасына салыңыз.

Public WithEvents objCalendar As Outlook.Folder
Public WithEvents objCalendarItems As Outlook.Items

Private Sub Application_Startup()
    Set objCalendar = Outlook.Application.Session.GetDefaultFolder(olFolderCalendar)
    Set objCalendarItems = objCalendar.Items
End Sub

Private Sub objCalendarItems_ItemAdd(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub objCalendarItems_ItemChange(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub SetReminder_BasedOnCategories(ByVal objCalendarItem As Object)
    Dim objMeeting As Outlook.AppointmentItem
    Dim strCategories As String
 
    If objCalendarItem.Class = olAppointment Then
       'Check if the item is a meeting
       If objCalendarItem.MeetingStatus = olMeeting Then
          Set objMeeting = objCalendarItem
          strCategories = objMeeting.Categories
 
          'Set Reminder as 60 min before start for offsite appointments
          If InStr(strCategories, "Offsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 60
                 .Save
             End With
             'Set Reminder as 15 min before start for onsite appointments
          ElseIf InStr(strCategories, "Onsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 15
                 .Save
             End With
          End If
       End If
    End If
End Sub

4. Кейінірек, осы макросты іске қосу үшін «Application_Startup» кіші бағдарламасын басып, «F5» пернесін басу керек.
5. Содан бері, әдепкі күнтізбеге жаңа жиналыс қосылған сайын немесе сіз бар жиналысты өзгерткен сайын, Outlook жиналыс санаттарын автоматты түрде тексеріп, әр түрлі еске салу уақытын автоматты түрде қояды.

Outlook қателерін жою

Outlook бағдарламасында мезгіл-мезгіл әртүрлі мәселелер туындауы мүмкін. Сондықтан пайдаланушылар үшін Outlook мәселелерімен қалай күресу керектігін үйрену өте маңызды. Алдымен, Outlook деректерінің сақтық көшірмелерін үнемі жасап тұрғаныңыз жөн. Сонымен қатар, егер қолжетімді болса, күшті сақтау ұсынылады Перспективаны жөндеу сияқты құрал DataNumen Outlook Repair. Ол сіздің PST файлыңызды сканерлеп, Outlook мәселелерін анықтап, оларды оңай шеше алады.

Автордың кіріспесі:

Ширли Чжан - деректерді қалпына келтіру бойынша сарапшы DataNumen, Соның ішінде деректерді қалпына келтіру технологиялары бойынша әлемдік көшбасшы болып табылатын Inc. SQL қалпына келтіру және бағдарламалық жасақтаманы жөндеу бағдарламалары. Қосымша ақпарат алу үшін кіріңіз WWW.datanumen.com