Excel файлында күн сайын келетін электрондық хаттардың жалпы санын қалай автоматты түрде жазуға болады

Бұл мақала Outlook бағдарламасына күн сайын қанша хат алғаныңызды автоматты түрде санауға және нөмірді Excel файлына жазуға қалай мүмкіндік беру керектігін үйретеді.

Көптеген пайдаланушылар күн сайын алынған электрондық хаттардың жалпы санын санауды талап етеді. Сонымен қатар, болашақта ыңғайлырақ тексеру үшін көптеген адамдар жалпы санды Excel файлына жазуға дағдыланған. Бұл жағдайда, әрине, күн сайын қолмен санауды және жазуды таңдауға болады. Дегенмен, бұл біраз қиындық тудырады. Ал сіз мұны кейде ұмытып кетуіңіз мүмкін. Сондықтан Outlook-ті автоматты түрде жасауға мүмкіндік беретін ыңғайлы әдісті қалауыңыз керек. Осы талапқа жауап ретінде біз сізге VBA-ны оны жүзеге асыру үшін қалай пайдалану керектігін келесіде үйретеміз.

Excel файлында күн сайын келетін электрондық хаттардың жалпы санын автоматты түрде жазу

1. Ең басында Outlook қосымшасын іске қосыңыз.
2. Содан кейін негізгі Outlook терезесінде «Alt + F11» пернелер тіркесімін басыңыз.
3. Келесі қалқымалы VBA редакторы терезесінде «ThisOutlookSession» жобасын ашыңыз.
4. Осы жобаға келесі VBA кодтарын көшіріңіз және қойыңыз.

Private Sub Application_Reminder(ByVal Item As Object)
    If Item.Class = olTask And Item.Subject = "Update Email Count" Then
       Call GetAllInboxFolders
    End If
End Sub

Private Sub GetAllInboxFolders()
    Dim objInboxFolder As Outlook.Folder
    Dim strExcelFile As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nNextEmptyRow As Integer
    Dim lEmailCount As Long
 
    lEmailCount = 0
    Set objInboxFolder = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
    Call UpdateEmailCount(objInboxFolder, lEmailCount)
 
    ‘Change the path to the Excel file
    strExcelFile = "E:\Email\Email Count.xlsx"
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Open(strExcelFile)
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
 
    nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
    'Add the values into the columns
    objExcelWorksheet.Range("A" & nNextEmptyRow) = nNextEmptyRow - 1
    objExcelWorksheet.Range("B" & nNextEmptyRow) = Year(Date - 1) & "-" & Month(Date - 1) & "-" & Day(Date - 1)
    objExcelWorksheet.Range("C" & nNextEmptyRow) = lEmailCount
 
    'Fit the columns from A to C
    objExcelWorksheet.Columns("A:C").AutoFit
   
    'Save the changes and close the Excel file
    objExcelWorkbook.Close SaveChanges:=True
End Sub

Private Sub UpdateEmailCount(objFolder As Outlook.Folder, ByRef lCurEmailCount As Long)
    Dim objItems As Outlook.Items
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim strDay As String
    Dim strReceivedDate As String
    Dim lEmailCount As Long
    Dim objSubFolder As Outlook.Folder
 
    Set objItems = objFolder.Items
 
    objItems.SetColumns ("ReceivedTime")
    strDay = Year(Date - 1) & "-" & Month(Date - 1) & "-" & Day(Date - 1)
 
    For Each objItem In objItems
        If objItem.Class = olMail Then
           Set objMail = objItem
           strReceivedDate = Year(objMail.ReceivedTime) & "-" & Month(objMail.ReceivedTime) & "-" & Day(objMail.ReceivedTime)
           If strReceivedDate = strDay Then
              lCurEmailCount = lCurEmailCount + 1
           End If
        End If
    Next
 
    'Process the subfolders in the folder recursively
    If (objFolder.Folders.Count > 0) Then
       For Each objSubFolder In objFolder.Folders
           Call UpdateEmailCount(objSubFolder, lCurEmailCount)
       Next
    End If
End Sub

5. Содан кейін осы кодқа қол қойып, қол қойылған макростарға рұқсат беру үшін Outlook макрос параметрлерін өзгертіңіз.
6. Осыдан кейін күнделікті қайталанатын тапсырма жасау керек.

• Біріншіден, Тапсырмалар тақтасындағы «Жаңа тапсырма» түймесін басыңыз.
• Қалқымалы Жаңа тапсырма терезесінде «Қайталану» түймесін басыңыз.
• Содан кейін келесі тілқатысу терезесінде «Күнделікті», «Әрбір 1 күнде» және «Аяқтау күні жоқ» опциясын таңдап, «OK» түймесін басыңыз.
• Кейінірек тапсырма тақырыбын және еске салғышты қажеттіліктеріңізге қарай өзгертіңіз.
• Соңында «Сақтау және жабу» түймесін басыңыз.

7. Бұдан былай бұл тапсырманың еске салғышы ескертулері келген сайын, Outlook кеше алынған электрондық пошталарды автоматты түрде санайды, содан кейін келесі скриншот сияқты нөмірді Excel файлына жазады:

Тұрақты PST деректерінің жоғалуынан құтылу

Ешкім тұрақты PST деректерінің жоғалуын қабылдамайды. Дегенмен, Outlook PST файлы бүлінуге бейім. Сондықтан, жүйелі және жаңартылған PST деректерінің сақтық көшірмесін жасау және қуатты сақтау сияқты жеткілікті сақтық шараларын жасау керек. PST қалпына келтіру сияқты құрал DataNumen Outlook Repair.

Автордың кіріспесі:

Ширли Чжан - деректерді қалпына келтіру бойынша сарапшы DataNumen, Соның ішінде деректерді қалпына келтіру технологиялары бойынша әлемдік көшбасшы болып табылатын Inc. квадрат жөндеу және бағдарламалық жасақтаманы жөндеу бағдарламалары. Қосымша ақпарат алу үшін кіріңіз WWW.datanumen.com