Кіріс хаттар туралы ақпаратты Excel файлына Outlook VBA көмегімен автоматты түрде қалай экспорттауға болады

Outlook шешімдері Қыркүйек 29, 2025
Қазір бөлісу:

Көптеген пайдаланушылар Outlook бағдарламасы электрондық пошта хабарламаларын Excel файлына автоматты түрде экспорттай алады деп үміттенеді. Бұл мақала осы талапты қарастырады және Outlook VBA арқылы жылдам әдісті енгізеді.

Кейде, мысалы, пошта статистикасы сияқты кейбір себептермен электрондық поштаны Excel файлына экспорттау қажет болуы мүмкін. Әдетте, бар электрондық пошта хабарлары үшін Excel бағдарламасына бір рет жіберу үшін «Импорттау және Экспорттау» функциясын қолдануға болады. Алайда, мүмкін сіз Outlook бағдарламасында электрондық поштаңызға пошта жәшігіне келген бойда Excel-ге автоматты түрде экспорттауды қалайсыз. Күдіксіз Outlook бағдарламасында мұндай жергілікті мүмкіндік жоқ. Сондықтан сізге үшінші тарап қондырмасы немесе Outlook VBA сияқты басқа тәсілдерді қолдану қажет. Мұнда біз оны Outlook VBA көмегімен автоматты етуді үйретеміз. Қадамдар мен кодтарды алу үшін оқыңыз.

Кіріс хаттар туралы ақпаратты Excel файлына автоматты түрде экспорттау

  1. Бірінші кезекте сіз Excel файлын жасауыңыз керек.
  • Жаңа Excel файлын ашыңыз.
  • Содан кейін «Жоқ» деп жазу керек A1 ұяшығында, B1 ұяшығындағы «Жіберушінің аты», C1 ұяшығындағы «Жіберушінің электрондық адресі» және D1 ұяшығындағы «Электрондық пошта тақырыбы» және E1 ұяшығындағы «Алынған уақыт» келесі сурет сияқты.Excel файлын жасаңыз
  • Соңында оны өзіңіз қалаған атта және қалтада сақтаңыз.
  1. Осыдан кейін Outlook бағдарламасын іске қосу керек.
  2. Содан кейін «Alt + F11» батырмаларын басыңыз, бұл сізді VBA редакторына әкеледі.
  3. Келесіде қалқымалы терезеде сол жақтағы «ThisOutlookSession» батырмасын екі рет басу керек.
  4. Кейін, «ThisOutlookSession» жобасының терезесінде сіз оған келесі VBA кодтарын көшіріп, қоюыңыз керек.
Public WithEvents objMails As Outlook.Items

Private Sub Application_Startup()
    Set objMails = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub objMails_ItemAdd(ByVal Item As Object)
    Dim objMail As Outlook.MailItem
    Dim strExcelFile As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim nNextEmptyRow As Integer
    Dim strColumnB As String
    Dim strColumnC As String
    Dim strColumnD As String
    Dim strColumnE As String

    If Item.Class = olMail Then
       Set objMail = Item
    End If
 
    'Specify the Excel file which you want to auto export the email list
    'You can change it as per your case
    strExcelFile = "E:\Email\Email Statistics.xlsx"
 
    'Get Access to the Excel file
    On Error Resume Next
    Set objExcelApp = GetObject(, "Excel.Application")
    If Error <> 0 Then
       Set objExcelApp = CreateObject("Excel.Application")
    End If
    Set objExcelWorkBook = objExcelApp.Workbooks.Open(strExcelFile)
    Set objExcelWorkSheet = objExcelWorkBook.Sheets("Sheet1")
 
    'Get the next empty row in the Excel worksheet
    nNextEmptyRow = objExcelWorkSheet.Range("B" & objExcelWorkSheet.Rows.Count).End(xlUp).Row + 1
 
    'Specify the corresponding values in the different columns
    strColumnB = objMail.SenderName
    strColumnC = objMail.SenderEmailAddress
    strColumnD = objMail.Subject
    strColumnE = objMail.ReceivedTime
 
    'Add the vaules into the columns
    objExcelWorkSheet.Range("A" & nNextEmptyRow) = nNextEmptyRow - 1
    objExcelWorkSheet.Range("B" & nNextEmptyRow) = strColumnB
    objExcelWorkSheet.Range("C" & nNextEmptyRow) = strColumnC
    objExcelWorkSheet.Range("D" & nNextEmptyRow) = strColumnD
    objExcelWorkSheet.Range("E" & nNextEmptyRow) = strColumnE
 
    'Fit the columns from A to E
    objExcelWorkSheet.Columns("A:E").AutoFit
 
    'Save the changes and close the Excel file
    objExcelWorkBook.Close SaveChanges:=True
End Sub

VBA кодтары - Excel файлына кіріс хаттар туралы ақпаратты автоматты түрде экспорттау

  1. Кейінірек сіз бұл кодқа қол қоюыңыз керек.
  2. Кейіннен, резtart Жаңа VBA жобасын іске қосу үшін Outlook.
  3. Сайып келгенде, бұдан былай барлық кіріс хаттар сіздің кіріс қалтаңызға түскеннен кейін алдын-ала орнатылған Excel файлына автоматты түрде экспортталатын болады. Excel файлы келесі кескінге ұқсайды:Кіріс хаттар туралы ақпаратты қамтитын Excel файлы

PST деректерінің бүлінуін болдырмаңыз

Outlook әртүрлі ерекшеліктерінің арқасында көптеген құдалықтарға ие болды. Алайда, бұл ақымақ дегенді білдірмейді. Бұл кез келген уақытта бұзылуы мүмкін. Мысалы, егер сіз Outlook бағдарламасын жиі жабатын болсаңыз, онда сіздің PST деректеріңізге қауіп төнуі мүмкін. Бұл жағдайда, егер сіз қаласаңыз жөндеу PST сияқты тәжірибелі құралға жүгіну керек, мысалы DataNumen Outlook Repair.

Автордың кіріспесі:

Ширли Чжан - деректерді қалпына келтіру бойынша сарапшы DataNumen, Соның ішінде деректерді қалпына келтіру технологиялары бойынша әлемдік көшбасшы болып табылатын Inc. mdf қалпына келтіру және бағдарламалық жасақтаманы жөндеу бағдарламалары. Қосымша ақпарат алу үшін кіріңіз WWW.datanumen.com

Қазір бөлісу:

Пікірлер жабылды.