Outlook бағдарламасында кездесуге шақыру жібермес бұрын қатысушыларды қалай автоматты түрде санауға болады

Бұл мақала жиналысқа шақыру жібермес бұрын қатысушылардың санын автоматты түрде алу үшін Outlook VBA бағдарламасын қалай пайдалану керектігін үйретеді. 

Электрондық пошта жібермес бұрын алушыларды санау сияқты, кейбір пайдаланушылар кездесуге шақыру жібермес бұрын қатысушыларды да санағысы келеді. Әдеттегідей, бұл ұсынылған кездесудің жалпы құнын бағалауға және қатысушыларға осындай кездесуге шақыру жіберу керек пе, жоқ па, соны шешуге бағытталған. Сонымен қатар, Outlook пайдаланушыларға қатысушыларды қажетінше немесе міндетті емес түрде орнатуға мүмкіндік беретіндіктен, кейбіреулер қатысушыларды әртүрлі түрде санағысы келеді. Ал кездесу ресурстары мен ұзақтығын қосуға болатын болса, одан да жақсы болар еді. Outlook-та мұндай тікелей мүмкіндік болмаса да, сіз оны жүзеге асыру үшін VBA кодын пайдалана аласыз.

Жиналысқа шақыру жібермес бұрын қатысушыларды автоматты түрде санаңыз

1. Бастау үшін Outlook бағдарламаңызды іске қосыңыз.
2. Содан кейін Outlook негізгі терезесінде «Alt + F11» пернелер тіркесімін басыңыз.
3. Содан кейін сіз Outlook VBA редакторына сәтті кіресіз. Енді сізге «ThisOutlookSession» жобасын тауып, ашу керек.
4. Осы жобаға келесі VBA кодтарын көшіріңіз және қойыңыз.

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
    Dim objMeetingInvitation As Outlook.MeetingItem
    Dim objMeeting As Outlook.AppointmentItem
    Dim objAttendees As Outlook.Recipients
    Dim objAttendee As Outlook.recipient
    Dim lRequiredAttendeeCount, lOptionalAttendeeCount, lResourceCount As Long
    Dim strMsg As String
    Dim nPrompt As Integer
 
    If TypeOf Item Is MeetingItem Then
       Set objMeetingInvitation = Item
       Set objMeeting = objMeetingInvitation.GetAssociatedAppointment(True)
       Set objAttendees = objMeetingInvitation.Recipients
    End If
 
    lRequiredAttendeeCount = 0
    lOptionalAttendeeCount = 0
    lResourceCount = 0
 
    'Count the required & optional attendees and resources, etc.
    For Each objAttendee In objAttendees
         If objAttendee.Type = olRequired Then
            lRequiredAttendeeCount = lRequiredAttendeeCount + 1
         ElseIf objAttendee.Type = olOptional Then
            lOptionalAttendeeCount = lOptionalAttendeeCount + 1
         ElseIf objAttendee.Type = olResource Then
            lResourceCount = lResourceCount + 1
         End If
    Next
 
    'Double check the meeting invitation details
    strMsg = "Meeting Details:" & vbCrLf & vbCrLf & _
     "Required Attendees: " & lRequiredAttendeeCount & vbCrLf & _
     "Optional Attendees: " & lOptionalAttendeeCount & vbCrLf & _
     "Resources: " & lResourceCount & vbCrLf & _
     "Duration: " & GetDuration(objMeeting) & vbCrLf & vbCrLf & _
     "Are you sure to send this meeting invitation?"
 
    nPrompt = MsgBox(strMsg, vbExclamation + vbYesNo, "Double Check Meeting Invitation")
 
    If nPrompt = vbYes Then
       Cancel = False
    Else
       Cancel = True
    End If
End Sub

Function GetDuration(objCurMeeting As AppointmentItem) As String
    'Convert minute to hour
    If objCurMeeting.Duration > 60 Then
       GetDuration = Round(objCurMeeting.Duration / 60, 1) & " hours"
    ElseIf objCurMeeting.Duration = 60 Then
       GetDuration = Round(objCurMeeting.Duration / 60, 1) & " hour"
    ElseIf objCurMeeting.Duration < 60 Then
       GetDuration = objCurMeeting.Duration & " mins"
    End If
End Function

5. Осыдан кейін сізге осы кодқа қол қою керек.
6. Кейінірек сіздің Outlook цифрлық қол қойылған макростарға рұқсат беретініне көз жеткізіңіз.
7. Бұдан былай жиналысқа шақырулардағы «Жіберу» түймесін басқан сайын келесі суреттегідей қатысушылардың саны, ресурстар мен ұзақтығы көрсетілген хабарды аласыз:

Көңілсіз Outlook сыбайлас жемқорлықпен икемді түрде күресіңіз

Мүмкін сіз бұрын мұздату, түрлі қате туралы хабарлар және т.б. сияқты Outlook мәселелерімен кездескен боларсыз. Бақытымызға орай, Outlook кіріс жәшігін жөндеу құралымен бірге алдын ала орнатылған Сканерлеу, ол шағын мәселелерді шешуге қабілетті. Бірақ егер мәселе маңызды болса, сізден неғұрлым мамандандырылған құралға жүгіну қажет болады, мысалы DataNumen Outlook Repair.

Автордың кіріспесі:

Ширли Чжан - деректерді қалпына келтіру бойынша сарапшы DataNumen, Соның ішінде деректерді қалпына келтіру технологиялары бойынша әлемдік көшбасшы болып табылатын Inc. сыбайлас MDF және бағдарламалық жасақтаманы жөндеу бағдарламалары. Қосымша ақпарат алу үшін кіріңіз WWW.datanumen.com