Word кестесіндегі бос жолдар мен бағандарды жоюдың 3 жылдам әдісі

Бұл жазбада біз сізге Word кестесіндегі бос жолдар мен бағандарды жоюдың 3 жылдам жолын түсіндіреміз.

Кестелер құжат үшін өте маңызды, әсіресе әртүрлі деректер түрлерін сақтауда. Кейде ұзын кесте бір беттен асып, бірнеше бетке созылуы мүмкін. Сондықтан кесте ұзақ және күрделі болғаннан кейін, оны жеңілдету үшін жасай алатын шаралар бар. Мысалы, қажетсіз бос жолдар мен бағандарды жоюға болады.

Төменде сіз қолдануға болатын 3 әдіс берілген.

1-әдіс: бос жолдар мен бағандарды қолмен жою

1. Алдымен бос жолды немесе бағанды ​​таңдаңыз.
2. Содан кейін контекстік мәзірді алу үшін тінтуірдің оң жақ түймешігімен басыңыз. Мәзірде сәйкесінше «Жолдарды жою» немесе «Бағандарды жою» тармағын таңдаңыз.

Өкінішке орай, бірнеше қатарынан емес жолдарды немесе бағандарды таңдап, оларды осы жолмен бірге жою мүмкін емес. Бұл сұраныс үшін сіз біздің алдыңғы мақаламызға жүгіне аласыз: Word кестесінде бірнеше жолдарды немесе бағандарды топтамамен жоюдың 5 жылдам әдісі

2-әдіс: Топтама кестедегі барлық бос жолдар мен бағандарды жою

1-әдістің шектеулері бар. Сонымен, біз сізге VBA кодтары арқылы кестедегі жолдар мен бағандарды пакеттік жою әдісін ұсынамыз.

1. Бастау үшін, курсорды мақсатты кестенің ішіне орналастырыңыз.
2. Екіншіден, «Alt+ F11» пернесін басу арқылы VBA редакторын іске қосыңыз.
3. Редакторда алдымен «Қалыпты» жобаны басыңыз.
4. Содан кейін мәзір жолағындағы «Кірістіру» қойындысын нұқыңыз.
5. Ашылмалы мәзірден «Модуль» таңдаңыз.
6. Модульді ашу үшін оны екі рет басыңыз және оған келесі кодтарды қойыңыз:

Sub DeleteBlankRowsAndTablesInATable()
  Dim objCell As Cell
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  If Selection.Information(wdWithInTable) = False Then
    MsgBox ("Put cursor inside a table first!")
    Exit Sub
  Else
    With Selection.Tables(1)
      nRows = .Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Rows(nRowIndex).Delete
          End If
      Next nRowIndex
 
      nColumns = .Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    End With
  End If

  Set objCell = Nothing

  Application.ScreenUpdating = True
End Sub

7. Соңында мәзір жолағындағы «Іске қосу» түймесін басыңыз немесе «F5» түймесін басыңыз.

Бірнеше секундтан кейін сіз осы кестедегі барлық бос жолдар мен бағандарды алып тастайсыз.

3-әдіс: Құжаттағы барлық кестелердегі барлық бос жолдар мен бағандарды пакеттік жою

1. Алдымен макросты орнату және іске қосу үшін 2-әдістегі қадамдарды қайталаңыз.
2. Тек осы жолы сол макросты келесімен ауыстырыңыз:

Sub DeleteBlankRowsAndColumnsInAllTables()
  Dim objCell As Cell
  Dim objTable As Table
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  With ActiveDocument
    For Each objTable In .Tables
      nRows = objTable.Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Rows(nRowIndex).Delete
          End If
      Next nRowIndex
    Next objTable
 
    For Each objTable In .Tables
      nColumns = objTable.Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    Next objTable
  End With

  Set objCell = Nothing
  Set objTable = Nothing

  Application.ScreenUpdating = True
End Sub

Бұзылған құжатты қалпына келтіру

Қазіргі уақытта жоғалған деректерді қалпына келтірудің бірнеше жолы бар. Мысалы, сақтық көшірмелерді жасау әрқашан сіздің басты басымдығыңыз болып қала береді. Егер бұл сіздің соңғы ақпаратты қалпына келтіру қажеттілігіңізді қанағаттандырмаса, сіз ... әрекетін орындап көре аласыз. құжаттарды жөндеу құрал.

Автордың кіріспесі:

Вера Чен - деректерді қалпына келтіру бойынша сарапшы DataNumen, Соның ішінде деректерді қалпына келтіру технологиялары бойынша әлемдік көшбасшы болып табылатын Inc. xlsx жөндеу және pdf бағдарламалық жасақтама өнімдерін жөндеу. Қосымша ақпарат алу үшін кіріңіз WWW.datanumen.com