の特定のスライドをすばやく添付する方法 PowerPoint Outlookの電子メールへのプレゼンテーション

Outlookソリューション 2025 年 9 月 29 日

の特定のスライドを抽出したい場合 PowerPoint 別の新しいプレゼンテーションへのプレゼンテーションとそれをOutlookの電子メールに添付すると、この記事で共有されている方法を利用できます。

全体を取り付ける代わりに PowerPoint 電子メールへのプレゼンテーション。プレゼンテーションの特定のスライドを添付する場合は、通常、最初に特定のスライドを新しいプレゼンテーションにコピーする必要があります。面倒すぎる。そこで、一度に実現できる方法をご紹介します。

の特定のスライドを添付します PowerPoint 電子メールへのプレゼンテーション

まず、特定のを開きます PowerPoint プレゼンテーション。
そして、 PowerPoint アプリケーションウィンドウで、「Alt + F11」キーを押してVBAエディタにアクセスします。
次に、新しいウィンドウで、[挿入]> [モジュール]をクリックして新しいモジュールを作成します。
続いて、次のVBAコードをコピーしてこのモジュールに貼り付けます。

Sub AttachSpecificSlidesToOutlookEmail()
    Dim objActivePresetation As Presentation
    Dim objSlide As Slide
    Dim n As Long
    Dim strName As String
    Dim strTempPresetation As String
    Dim objTempPresetation As Presentation
    Dim objOutlookApp As Object
    Dim objMail As Object
 
    Set objActivePresetation = ActivePresentation
 
    For Each objSlide In objActivePresetation.Slides
        objSlide.Tags.Delete ("Selected")
    Next
 
    'Add a tag "Selected" to the selected slides
    For n = 1 To ActiveWindow.Selection.SlideRange.Count
        ActiveWindow.Selection.SlideRange(n).Tags.Add "Selected", "YES"
    Next n
 
    strName = objActivePresetation.Name
    strName = Left(strName, InStrRev(strName, ".") - 1)
    strTempPresetation = Environ("TEMP") & "\" & strName & ".pptx"
 
    'Copy the active presentation to a temp presentation
    objActivePresetation.SaveCopyAs strTempPresetation
    Set objTempPresetation = Presentations.Open(strTempPresetation)
 
    'Remove the untagged slides
    For n = objTempPresetation.Slides.Count To 1 Step -1
        If objTempPresetation.Slides(n).Tags("Selected") <> "YES" Then
           objTempPresetation.Slides(n).Delete
        End If
    Next n
 
    objTempPresetation.Save
    objTempPresetation.Close
 
    'Attach the temp presentation to a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objMail = objOutlookApp.CreateItem(olMailItem)
 
    'Change the email details as per your needs
    With objMail
         .To = "test@datanumen.com"
         .Subject = strName
         .Body = "Dear," & vbCr & vbCr & vbTab & "Specific slides are extracted and attached."
         .Attachments.Add strTempPresetation
         .Display
    End With
End Sub

その後、現在のウィンドウを閉じることができます。
後で、[ファイル]> [オプション]> [クイックアクセスツールバー]に移動して、新しいマクロをクイックアクセスツールバーに追加します。
最後に、このマクロを試すことができます。

まず、抽出したいスライドを選択してください。
次に、クイックアクセスツールバーのマクロボタンをクリックします。
すぐに、Outlookの電子メールが表示されます。 PowerPoint ソースプレゼンテーションから抽出されたプレゼンテーション。

効果的な回復ツールを利用する

ご存知のとおり、Outlookには組み込みの修復ユーティリティが備わっています– スキャンプスト。それでも、Outlookの小さな不具合に簡単に対処できます。あなたが直面しているものが深刻なダメージである場合、それは効果を発揮しません。その時点で、次のような別の強力で信頼できる修復ツールに戻る以外に選択肢はありません。 DataNumen Outlook Repair。これを使用すると、破損したOutlookファイルを救出することができます。

著者紹介：

Shirley Zhangは、のデータ復旧の専門家です。 DataNumen、Inc。は、以下を含むデータ復旧技術の世界的リーダーです。破損したmdf と見通し修理ソフトウェア製品。詳細については、次のWebサイトをご覧ください。 WWW。datanumen.com