Outlook連絡先グループのすべてのメンバーをExcelにエクスポートする2つの方法

Outlookソリューション 2025 年 9 月 29 日

特定のOutlook連絡先グループのメンバーをエクスポートしたい場合があります。したがって、この記事では、グループメンバーをExcelに抽出する2つの方法を紹介します。

Outlookは、特定の連絡先フォルダーのすべての連絡先をエクスポートできるネイティブ機能を提供します。ただし、連絡先グループのメンバーを抽出することは言うまでもなく、連絡先グループをエクスポートすることはできません。したがって、選択した連絡先グループのメンバーを抽出する場合は、さらに努力する必要があります。ここにあなたが参照できるXNUMXつのヒントがあります。

方法1：名前を付けて保存してグループメンバーを抽出する

最初に、Outlookを起動します。
次に、メンバーを抽出する必要がある連絡先グループを見つけて選択します。
次に、「ファイル」メニューに移動し、「名前を付けて保存」をクリックする必要があります。
続いて、ポップアップの[名前を付けて保存]ダイアログボックスで、保存する保存先フォルダを選択し、[ファイルの種類]のドロップダウンリストから[テキストのみ]を選択します。
そして、「保存」をクリックします。
その後、Excelを開き、新しいExcelファイルを作成します。
後で「ファイル」に移動し、「開く」ボタンをクリックする必要があります。
その後の[開く]ダイアログボックスで、最初に連絡先グループを保存したフォルダにアクセスする必要があります。
次に、「ファイル名」行のXNUMX番目のボックスをクリックし、ドロップダウンリストから「すべてのファイル」を選択します。
その後、連絡先グループのテキストファイルを売り込み、「開く」をクリックします。
ポップアップの「テキストインポートウィザード」ダイアログボックスで、「区切り」が選択されていることを確認し、「完了」ボタンをクリックします。
最後に、次のスクリーンショットのようにメンバーを取得します。

方法2：OutlookVBAを介してグループメンバーを抽出する

まず、Outlookの「Alt + F11」キーボタンを押します。
次に、VBAエディタウィンドウで新しいモジュールを開きます。
続いて、次のVBAコードをコピーします。

Sub ExtractContactGroupMembersToExcel()
    Dim objContactGroup As Outlook.DistListItem
    Dim objMember As Outlook.recipient
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim i As Integer
    Dim nRow As Integer
    Dim strPath As String
    Dim strFilename As String
 
    Select Case Application.ActiveWindow.Class
           Case olExplorer
                Set objContactGroup = Application.ActiveExplorer.Selection(1)
           Case olInspector
                Set objContactGroup = Application.ActiveInspector.CurrentItem
    End Select
 
    If TypeOf objContactGroup Is DistListItem Then
       'Create a new Excel workbook
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkBook = objExcelApp.Workbooks.Add
       Set objExcelWorkSheet = objExcelWorkBook.Worksheets(1)
 
       'Set the two column headers
       objExcelWorkSheet.Cells(1, 1) = "Contact Name"
       objExcelWorkSheet.Cells(1, 2) = "Email Address"

       nRow = 2
 
       'Extract the contact group members' names and email addresses
       For i = 1 To objContactGroup.MemberCount
           Set objMember = objContactGroup.GetMember(i)
           objExcelWorkSheet.Cells(nRow, 1) = objMember.Name
           objExcelWorkSheet.Cells(nRow, 2) = objMember.Address
           nRow = nRow + 1
       Next
 
       'AutoFit the columns in the new Excel worksheet
       objExcelWorkSheet.Columns("A:B").AutoFit
 
       'Change the strPath to your actual case
       strPath = "C:\Contact Groups\"
       strFilename = strPath & objContactGroup.DLName & ".xlsx"
 
       'Save the Excel workbook
       objExcelWorkBook.Close True, strFilename
 
       'Notify you of the export complete
       MsgBox ("Export Complete!")
    End If
End Sub

その後、通常どおりマクロをクイックアクセスツールバー（QAT）に追加できます。
後で、連絡先グループを選択して、QATのマクロボタンをクリックできます。
エクスポート後、「エクスポートが完了しました！」というメッセージが表示されます。
最終的には、VBAコードで事前に定義されているフォルダーにExcelファイルがあります。それを開くと、下の画像のようにグループメンバーが表示されます。

以前のPSTデータを取り戻す

Outlookはクラッシュする可能性があるため、PSTデータは前兆なしに破損する可能性があります。したがって、PSTファイルの定期的なバックアップを作成する必要があります。また、次のような強力なツールを準備することをお勧めします DataNumen Outlook Repair、そのことができます Outlookを修復するタイムリーにデータ。

著者紹介：

Shirley Zhangは、のデータ復旧の専門家です。 DataNumen、Inc。は、以下を含むデータ復旧技術の世界的リーダーです。 SQLを修正と見通し修理ソフトウェア製品。詳細については、次のWebサイトをご覧ください。 WWW。datanumen.com