Cara Cepat Menghapus Item Outlook Duplikat di Folder melalui VBA

Jika Anda ingin menghapus item duplikat di Outlook, mencari dan menghapus satu per satu akan cukup merepotkan. Ini post akan mengajari Anda cara menyelesaikannya dengan cepat menggunakan Outlook VBA.

Di artikel saya sebelumnya - “Cara Cepat Menemukan dan Menghapus Email Duplikat di Outlook”, Anda dapat mempelajari trik untuk menemukan dan menghapus email duplikat, yang pertama mengurutkan email berdasarkan subjek, kemudian berdasarkan waktu penerimaan dan kemudian dengan lampiran untuk menemukan item duplikat dan terakhir memilih yang duplikat dan tekan tombol" Hapus ". Meskipun metode ini tampaknya sedikit lebih nyaman, tetapi jauh lebih merepotkan dibandingkan dengan menggunakan Outlook VBA. Dengan kode VBA berikut, Anda dapat dengan cepat menghapus item duplikat hanya dengan satu klik, apa pun email, tugas, kontak, atau janji temu. Sekarang baca terus untuk mendapatkan kode secara detail.

Hapus Item Outlook Duplikat dalam Folder

1. Untuk start dengan, luncurkan program Outlook Anda.
2. Kemudian tekan tombol "Alt + F11".
3. Di jendela editor VBA berikutnya, klik dua kali untuk membuka modul yang sedang digunakan atau langsung menyisipkan modul baru dengan "Sisipkan"> "Modul".
4. Selanjutnya salin dan tempel kode VBA berikut ke dalam modul.

Sub RemoveDuplicateItems()
    Dim objFolder As Folder
    Dim objDictionary As Object
    Dim i As Long
    Dim objItem As Object
    Dim strKey As String

    Set objDictionary = CreateObject("scripting.dictionary")
    'Select a source folder
    Set objFolder = Outlook.Application.Session.PickFolder

    If Not (objFolder Is Nothing) Then
       For i = objFolder.Items.Count To 1 Step -1
           Set objItem = objFolder.Items.Item(i)
 
           Select Case objFolder.DefaultItemType
                  'Check email subject, body and sent time
                  Case olMailItem
                       strKey = objItem.Subject & "," & objItem.Body & "," & objItem.SentOn
                  'Check appointment subject, start time, duration, location and body
                  Case olAppointmentItem
                       strKey = objItem.Subject & "," & objItem.Start & "," & objItem.Duration & "," & objItem.Location & "," & objItem.Body
                  'Check contact full name and email address
                  Case olContactItem
                       strKey = objItem.FullName & "," & objItem.Email1Address & "," & objItem.Email2Address & "," & objItem.Email3Address
                  'Check task subject, start date, due date and body
                  Case olTaskItem
                       strKey = objItem.Subject & "," & objItem.StartDate & "," & objItem.DueDate & "," & objItem.Body
           End Select
 
           strKey = Replace(strKey, ", ", Chr(32))
 
           'Remove the duplicate items
           If objDictionary.Exists(strKey) = True Then
              objItem.Delete
           Else
              objDictionary.Add strKey, True
           End If
       Next i
    End If
End Sub

5. Setelah itu, tanda tangani makro ini secara digital dan ubah tingkat keamanan makro Outlook Anda ke rendah.
6. Nanti, Anda bisa menjalankan proyek VBA baru ini. Klik langsung ikon "Jalankan" di bilah alat.
7. Selanjutnya, Anda akan diminta untuk memilih folder tempat Anda ingin menghapus item duplikat.
8. Terakhir, item duplikat di folder yang dipilih akan segera dihapus.

Lindungi Data PST yang Rentan

Karena fakta bahwa file PST rentan terhadap korupsi, maka Anda harus melakukan banyak upaya untuk melindungi file PST Anda. Misalnya, Anda harus mencegah Outlook ditutup secara tidak benar. Selanjutnya, Anda perlu menyiapkan yang tangguh Perbaikan Outlook alat, seperti DataNumen Outlook Repair yang akan dapat menyelamatkan PST Anda tepat waktu.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk memulihkan SQL Server dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com