Cara Cepat Menyisipkan Nama Penerima ke Badan Email di Outlook Anda

Jika Anda ingin memasukkan nama penerima dengan cepat ke badan saat menulis email, Anda dapat membaca artikel ini. Di sini kami akan memperkenalkan Anda metode yang nyaman.

Terkadang, Anda mungkin perlu memasukkan nama semua penerima ke badan saat Anda menulis email. Tidak diragukan lagi, sangat membosankan dan tidak praktis untuk mengekstrak dan memasukkan nama ke badan satu per satu secara manual. Oleh karena itu, untuk membantu Anda mencapainya dengan cepat, di sini kami akan membagikan kepada Anda cara yang efisien. Baca terus untuk mendapatkan langkah-langkah detailnya.

Masukkan Nama Penerima ke Badan Email

1. Sebagai langkah awal, akses editor VBA melalui “Alt + F11”.
2. Kemudian, di jendela “Microsoft Visual Basic for Applications”, aktifkan “MS Word Object Library” sesuai dengan “Cara Menambahkan Referensi Pustaka Objek di VBA".
3. Selanjutnya, salin kode VBA di bawah ini ke dalam modul kosong.

Sub CopyRecipientNamesToBody()
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.Recipient
    Dim strRecipAddress As String
    Dim strRecipName As String
    Dim objContacts As Outlook.Items
    Dim i As Integer
    Dim strFilter As String
    Dim objFoundContact As Outlook.ContactItem
    Dim strRecipNames As String
    Dim objMailDocument As Word.Document
 
    'Get the current email
    Set objMail = Application.ActiveInspector.CurrentItem
    objMail.Recipients.ResolveAll
 
    For Each objRecipient In objMail.Recipients
        strRecipAddress = objRecipient.Address
 
        'Get the corresponding contact name
        Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items
        For i = 1 To 3
            strFilter = "[Email" & i & "Address] = " & strRecipAddress
            Set objFoundContact = objContacts.Find(strFilter)
            If Not (objFoundContact Is Nothing) Then
               strRecipNames = strRecipNames & objFoundContact.FullName & vbCr
               Exit For
            End If
        Next
 
        'If there isn't associated contact
        'Extract name from email address
        If objFoundContact Is Nothing Then
           strRecipName = Split(strRecipAddress, "@")(0)
           strRecipName = UCase(Left(strRecipName, 1)) & Right(strRecipName, Len(strRecipName) - 1)
           strRecipNames = strRecipNames & strRecipName & vbCr
        End If
    Next
 
    'Insert the names at the beginning of email
    Set objMailDocument = objMail.GetInspector.WordEditor
    objMailDocument.Range(0, 0).InsertAfter strRecipNames
End Sub

3. Selanjutnya, tambahkan makro ini ke Bilah Alat Akses Cepat dari jendela Pesan sesuai dengan langkah opsional di “Cara Menjalankan Kode VBA di Outlook Anda".
4. Setelah itu, keluar dari jendela.
5. Akhirnya, ambil gambar.

• Pertama, buat email dan isi penerima.
• Kemudian, tekan tombol makro di Bilah Alat Akses Cepat.
• Ketika makro selesai, nama penerima telah dimasukkan ke dalam badan email, seperti yang ditunjukkan pada gambar di bawah ini.

Waspada terhadap Kerusakan Outlook

Karena Outlook rentan, sulit untuk melindungi Outlook dari kerusakan. Tanpa ragu, Anda pasti enggan bertemu Korupsi PST. Oleh karena itu, Anda sebaiknya mengambil beberapa tindakan pencegahan yang efektif. Misalnya, Anda perlu membuat cadangan data yang konsisten untuk Outlook, terbiasa dengan cara menggunakan alat perbaikan kotak masuk serta menyimpan alat eksternal yang kuat di sekitarnya, seperti DataNumen Outlook Repair.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk SQL Server memperbaiki dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com