Cara Cepat Mengekspor Informasi Ukuran Semua Folder dalam File PST ke File Excel

Jika Anda ingin memeriksa informasi ukuran setiap folder dalam file PST, Anda dapat menggunakan metode yang diekspos dalam artikel ini. Ini akan dengan cepat mengekspor informasi ukuran semua folder dalam file PST ke file Excel.

Ketika file PST Anda terlalu besar, Anda mungkin ingin memeriksa ukuran setiap folder. Ini akan membantu Anda dengan mudah mengetahui mana yang lebih besar dan melakukan pengarsipan yang sesuai berdasarkan ukurannya. Secara umum, untuk memeriksa ukuran folder, Anda cukup mengklik kanan pada folder dan kemudian memilih "Properties". Di kotak dialog sembulan baru, Anda dapat mengklik tombol "Ukuran Folder". Namun, jika Anda telah membuat banyak folder, memeriksa informasi ukuran satu per satu secara manual cukup merepotkan. Jadi, jika Anda ingin batch mendapatkan informasi ukuran semua folder dalam file PST, Anda dapat menggunakan kode VBA berikut. Ini akan mengekspor semua nama folder dan informasi ukuran ke file Excel sekaligus.

Ekspor Informasi Ukuran Semua Folder dalam File PST ke File Excel

1. Pertama-tama, buka aplikasi Outlook Anda.
2. Kemudian beralih ke tab "Pengembang" dan klik tombol "Visual Basic" atau tekan tombol "Alt + F11" untuk mengakses editor VBA.
3. Selanjutnya di jendela "Microsoft Visual Basic for Applications", buka modul yang tidak digunakan.
4. Selanjutnya, salin dan tempel kode VBA berikut ke dalam modul ini.

Dim strExcelFile As String
Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportFodlerSizetoExcel()
    Dim objSourcePST As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
    objExcelWorksheet.Cells(1, 1) = "Folder"
    objExcelWorksheet.Cells(1, 2) = "Size"
 
    'Select a source PST file
    Set objSourcePST = Outlook.Application.Session.PickFolder

    For Each objFolder In objSourcePST.Folders
        Call ProcessFolders(objFolder)
    Next
 
    'Fit the columns from A to B
    objExcelWorksheet.Columns("A:B").AutoFit
 
    strExcelFile = "E:\Outlook\" & objSourcePST.Name & " Folder Size (" & Format(Now, "yyyy-mm-dd hh-mm-ss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim objItem As Object
    Dim lCurrentFolderSize As Long
    Dim nNextEmptyRow As Integer
 
    objCurrentFolder.Items.SetColumns ("Size")
    For Each objItem In objCurrentFolder.Items
        lCurrentFolderSize = lCurrentFolderSize + objItem.Size
    Next
 
    'Convert byte to kilobyte
    'To convert to megabyte, use:
    'lCurrentFolderSize = (lCurrentFolderSize / 1024) / 1024
    lCurrentFolderSize = lCurrentFolderSize / 1024
 
    nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1

    'Add the values into the columns
    objExcelWorksheet.Range("A" & nNextEmptyRow) = objCurrentFolder.FolderPath
    objExcelWorksheet.Range("B" & nNextEmptyRow) = lCurrentFolderSize & " KB"
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder)
       Next
    End If
End Sub

5. Setelah itu, Anda harus mengatur tingkat keamanan makro Outlook Anda ke rendah.
6. Akhirnya, Anda bisa mencobanya.

• Tekan tombol tombol F5 di jendela makro saat ini.
• Kemudian Anda akan diminta untuk memilih file PST, seperti gambar berikut:
• Setelah memilih file sumber, Outlook akan mulai mengekspor informasi ukuran ke Excel.
• Setelah makro selesai, Anda menerima pesan seperti gambar di bawah.
• Terakhir, Anda akan dapat menemukan file Excel di folder lokal yang telah ditentukan. File Excel akan terlihat seperti berikut:

Menangani Kesalahan PST yang Sering Terjadi

Karena Outlook rentan terhadap kesalahan, Anda mungkin pernah mengalami banyak masalah di Outlook Anda. Untuk mengatasi masalah PST yang membuat frustrasi dengan lebih baik dan lebih fleksibel, disarankan untuk menyimpan utilitas perbaikan yang berpengalaman dan bereputasi baik di sekitarnya, seperti DataNumen Outlook Repair. Itu bisa perbaiki PST masalah seperti angin sepoi-sepoi.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk SQL Server pemulihan dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com